build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.kotlin_version = '1.1.60'
    ext.versions = [
            'compileSdk': 26,
            'buildTools': '26.0.2',
            'minSdk': 16,
            'targetSdk': 26,
            'supportLibrary': '26.1.0',
            'firebase': '10.0.1',
            'retrofit': '2.0.0-beta4',
            'okhttp': '3.6.0',
            'ion': '2.1.7',
            'videoAndroid': '1.3.9'
    ]
    ext.getSecretProperty = { key, defaultValue ->
        def value = System.getenv(key);

        if (value == null) {
            Properties properties = new Properties()
            if (project.rootProject.file('local.properties').exists()) {
                properties.load(project.rootProject.file('local.properties').newDataInputStream())
                value = properties.getProperty(key)
            }
        }

        if (value == null) {
            value = defaultValue
        }

        return value;
    }
    repositories {
        google()
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.0.0'
        classpath 'com.google.gms:google-services:3.1.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        mavenCentral()
    }
}