-
Notifications
You must be signed in to change notification settings - Fork 85
/
ErrorValidationScript.sml
2870 lines (2833 loc) · 135 KB
/
ErrorValidationScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(**
This file contains the HOL4 implementation of the error bound validator as well
as its soundness proof. The function validErrorbound is the Error bound
validator from the certificate checking process. Under the assumption that a
valid range arithmetic result has been computed, it can validate error bounds
encoded in the analysis result. The validator is used in the file
CertificateChecker.v to build the complete checker.
**)
open simpLib realTheory realLib RealArith pred_setTheory;
open AbbrevsTheory ExpressionsTheory ExpressionSemanticsTheory RealSimpsTheory
RealRangeArithTheory FloverTactics MachineTypeTheory
ExpressionAbbrevsTheory ErrorBoundsTheory IntervalArithTheory
TypeValidatorTheory IntervalValidationTheory EnvironmentsTheory
CommandsTheory ssaPrgsTheory FloverMapTheory sqrtApproxTheory;
open preambleFloVer;
val _ = new_theory "ErrorValidation";
val _ = temp_delsimps ["fromAList_def", "domain_union",
"domain_inter", "domain_difference",
"domain_map", "sptree.map_def", "sptree.lookup_rwts",
"sptree.insert_notEmpty", "sptree.isEmpty_union"]
val _ = Parse.hide "delta"; (* so that it can be used as a variable *)
Overload abs[local] = “realax$abs”
val _ = realLib.prefer_real();
val triangle_tac =
irule triangle_trans \\ fs[REAL_ABS_TRIANGLE];
fun real_rewrite t =
rewrite_tac [REAL_ARITH (Parse.Term t)];
val real_prove =
rpt (qpat_x_assum `!x. _` kall_tac)
\\ rpt (qpat_x_assum `_ ==> ! x. _` kall_tac)
\\ REAL_ASM_ARITH_TAC;
Definition validErrorbound_def:
validErrorbound e (typeMap: typeMap) (A:analysisResult) (dVars:num_set)=
case FloverMapTree_find e A, FloverMapTree_find e typeMap of
| NONE, _ => F
| _, NONE => F
| SOME (intv, err), SOME m =>
(if (0 <= err) then
case e of
| Var v =>
if (lookup v dVars = SOME ()) then T
else computeError (maxAbs intv) m <= err
| Const _ n => (computeError (maxAbs intv) m <= err)
| Unop Neg e1 =>
if (validErrorbound e1 typeMap A dVars) then
case (FloverMapTree_find e1 A) of
| SOME (_, err1) => err = err1
| _ => F
else F
| Unop Sqrt e1 =>
if (validErrorbound e1 typeMap A dVars) then
case (FloverMapTree_find e1 A) of
| SOME (iv1, err1) =>
let errIve1 = widenInterval iv1 err1;
sqrtRealLo = newton ITERCOUNT (IVlo iv1 * 0.99) (IVlo iv1 * 0.99);
sqrtRealHi = newton ITERCOUNT (IVhi iv1 * 1.01) (IVhi iv1 * 1.01);
sqrtRealIv = (sqrtRealLo, sqrtRealHi);
sqrtFinLo= newton ITERCOUNT (IVlo errIve1 * 0.99) (IVlo errIve1 * 0.99);
sqrtFinHi = newton ITERCOUNT (IVhi errIve1 * 1.01) (IVhi errIve1 * 1.01);
sqrtFinIv = (sqrtFinLo, sqrtFinHi);
propError = err1 * sqrtFinHi * inv ((IVlo iv1 - err1) * 2);
mAbs = maxAbs sqrtFinIv
in
if (validate_newton_down sqrtRealLo (IVlo iv1) ∧
validate_newton_up sqrtRealHi (IVhi iv1) ∧
validate_newton_down sqrtFinLo (IVlo errIve1) ∧
validate_newton_up sqrtFinHi (IVhi errIve1) ∧
0 < IVlo errIve1) then
propError + computeError mAbs m <= err
else F
| _ => F
else F
| Unop Inv e1 => F
| Binop op e1 e2 =>
(if (validErrorbound e1 typeMap A dVars /\ validErrorbound e2 typeMap A dVars)
then
case FloverMapTree_find e1 A, FloverMapTree_find e2 A of
| NONE, _ => F
| _, NONE => F
| SOME (ive1, err1), SOME (ive2, err2) =>
let errIve1 = widenInterval ive1 err1 in
let errIve2 = widenInterval ive2 err2 in
let upperBoundE1 = maxAbs ive1 in
let upperBoundE2 = maxAbs ive2 in
(case op of
| Plus =>
let mAbs = maxAbs (addInterval errIve1 errIve2) in
err1 + err2 + computeError mAbs m <= err
| Sub =>
let mAbs = maxAbs (subtractInterval errIve1 errIve2) in
err1 + err2 + computeError mAbs m <= err
| Mult =>
let mAbs = maxAbs (multInterval errIve1 errIve2);
eProp = upperBoundE1 * err2 + upperBoundE2 * err1 + err1 * err2 in
eProp + computeError mAbs m <= err
| Div =>
(if (noDivzero (IVhi errIve2) (IVlo errIve2))
then
let upperBoundInvE2 = maxAbs (invertInterval ive2);
minAbsIve2 = minAbsFun (errIve2);
errInv = (1 / (minAbsIve2 * minAbsIve2)) * err2;
mAbs = maxAbs (divideInterval errIve1 errIve2);
eProp = upperBoundE1 * errInv + upperBoundInvE2 * err1 + err1 * errInv in
eProp + computeError mAbs m <= err
else F))
else F)
| Fma e1 e2 e3 =>
(if (validErrorbound e1 typeMap A dVars /\
validErrorbound e2 typeMap A dVars /\
validErrorbound e3 typeMap A dVars) then
case (FloverMapTree_find e1 A,
FloverMapTree_find e2 A,
FloverMapTree_find e3 A) of
| SOME (ive1, err1), SOME (ive2, err2), SOME (ive3, err3) =>
let errIve1 = widenInterval ive1 err1;
errIve2 = widenInterval ive2 err2;
errIve3 = widenInterval ive3 err3;
upperBoundE1 = maxAbs ive1;
upperBoundE2 = maxAbs ive2;
upperBoundE3 = maxAbs ive3;
errIntv_prod = multInterval errIve1 errIve2;
mult_error_bound = (upperBoundE1 * err2 + upperBoundE2 * err1 + err1 * err2);
mAbs = maxAbs (addInterval errIntv_prod errIve3 ) in
mult_error_bound + err3 + computeError mAbs m <= err
|_, _, _ => F
else F)
| Downcast m1 e1 =>
if (validErrorbound e1 typeMap A dVars)
then
case FloverMapTree_find e1 A of
| NONE => F
| SOME (ive1, err1) =>
let errIve1 = widenInterval ive1 err1;
mAbs = maxAbs errIve1 in
err1 + computeError mAbs m1 <= err
else F
else F)
End
Theorem validErrorbound_eq =
SIMP_CONV flover_ss [Once validErrorbound_def] (Parse.Term ‘validErrorbound e Gamma A dVars’)
Definition validErrorboundCmd_def:
validErrorboundCmd (f:real cmd) (typeMap: (real expr # mType) binTree)
(A:analysisResult) (dVars:num_set) =
case f of
| Let m x e g =>
(case FloverMapTree_find e A, FloverMapTree_find (Var x) A of
| SOME (iv_e, err_e), SOME (iv_x, err_x) =>
if (validErrorbound e typeMap A dVars /\ err_e = err_x)
then validErrorboundCmd g typeMap A (insert x () dVars)
else F
| _ , _ => F)
| Ret e =>
validErrorbound e typeMap A dVars
End
Theorem validErrorboundCmd_eq =
SIMP_CONV flover_ss [Once validErrorboundCmd_def] (Parse.Term ‘validErrorboundCmd f Gamma A dVars’)
Definition eval_Real_def:
eval_Real E1 Gamma e nR =
eval_expr E1 (toRTMap (toRExpMap Gamma)) (toREval e) nR REAL
End
Definition eval_Fin_def:
eval_Fin E2 Gamma e nF m =
eval_expr E2 (toRExpMap Gamma) e nF m
End
val _ = export_rewrites ["eval_Real_def", "eval_Fin_def"]
Theorem err_always_positive:
∀ (e:real expr) (A:analysisResult) (iv:interval) (err:real) dVars tmap.
(validErrorbound e tmap A dVars) /\
(FloverMapTree_find e A = SOME (iv,err)) ==>
0 <= err
Proof
rpt strip_tac \\ Cases_on `e`
\\ qpat_x_assum `validErrorbound _ _ _ _` mp_tac
\\ simp[Once validErrorbound_def] \\ TOP_CASE_TAC \\ strip_tac
QED
Theorem validErrorboundCorrectVariable_eval:
∀ E1 E2 A v e nR nlo nhi P fVars dVars Gamma.
eval_Real E1 Gamma (Var v) nR /\
approxEnv E1 (toRExpMap Gamma) A fVars dVars E2 /\
validTypes (Var v) Gamma /\
validRanges (Var v) A E1 (toRTMap (toRExpMap Gamma)) /\
validErrorbound (Var v) Gamma A dVars /\
(domain (usedVars ((Var v):real expr)) DIFF (domain dVars)) SUBSET (domain fVars) /\
FloverMapTree_find (Var v) A = SOME ((nlo,nhi),e) ==>
∃ nF m.
eval_Fin E2 Gamma (Var v) nF m
Proof
rpt strip_tac
\\ IMP_RES_TAC validRanges_single \\ fs[]
\\ IMP_RES_TAC meps_0_deterministic \\ rveq
\\ fs[toREval_def]
\\ inversion `eval_expr E1 _ _ _ _` eval_expr_cases
\\ rveq
\\ qspecl_then [`E1`, `E2`, `v`, `nR`, `fVars`, `dVars`, `A`, `toRExpMap Gamma`]
destruct approxEnv_gives_value
\\ fs[domain_union, domain_lookup, usedVars_def]
>- (Cases_on `lookup v dVars` \\ fs[domain_lookup])
\\ fs[eval_expr_cases, toRExpMap_def, toRTMap_def, option_case_eq]
QED
Theorem validErrorboundCorrectVariable:
∀ (E1 E2:env) A fVars dVars (v:num) (nR nF err nlo nhi:real) (P:precond) m
Gamma.
approxEnv E1 (toRExpMap Gamma) A fVars dVars E2 /\
eval_Real E1 Gamma (Var v) nR /\
eval_Fin E2 Gamma (Var v) nF m /\
validTypes (Var v) Gamma /\
validRanges (Var v) A E1 (toRTMap (toRExpMap Gamma)) /\
validErrorbound (Var v) Gamma A dVars /\
(domain (usedVars ((Var v):real expr)) DIFF (domain dVars)) SUBSET (domain fVars) /\
FloverMapTree_find (Var v) A = SOME ((nlo,nhi),err) ==>
abs (nR - nF) <= err
Proof
rpt strip_tac
\\ IMP_RES_TAC validRanges_single \\ fs[]
\\ IMP_RES_TAC meps_0_deterministic \\ rveq
\\ fs[toREval_def]
\\ rpt (inversion `eval_expr _ _ _ _ _` eval_expr_cases)
\\ qpat_x_assum `validErrorbound _ _ _ _` mp_tac
\\ simp[Once validErrorbound_eq]
\\ rpt strip_tac \\ fs[]
>- (drule approxEnv_dVar_bounded
\\ rpt (disch_then drule) \\ rveq
\\ disch_then (qspecl_then [`m`, `(nlo,nhi)`, `err`] irule)
\\ fs[domain_lookup])
\\ rveq
\\ fs[usedVars_def,domain_lookup]
\\ irule REAL_LE_TRANS \\ find_exists_tac \\ fs[]
\\ drule approxEnv_fVar_bounded
\\ rpt (disch_then drule)
\\ disch_then (qspec_then `m` assume_tac)
\\ irule REAL_LE_TRANS
\\ qexists_tac `computeError nR m`
\\ conj_tac \\ TRY (first_x_assum irule \\ fs[domain_lookup])
\\ fs[toRExpMap_def] \\ rveq
\\ irule computeError_up \\ fs[]
\\ irule contained_leq_maxAbs \\ fs[contained_def, IVlo_def, IVhi_def]
QED
Theorem validErrorboundCorrectConstant_eval:
!(E:env) (n nR:real) m Gamma.
validTypes (Const m n) Gamma ==>
? nF m1.
eval_Fin E Gamma (Const m n) nF m1
Proof
rpt strip_tac \\ fs[validTypes_def]
\\ qexistsl_tac [`perturb n m (mTypeToR m n)`,`m`] \\ irule Const_dist'
\\ fs[]
\\ qexists_tac `mTypeToR m n` \\ conj_tac \\ fs[realTheory.abs, mTypeToR_pos]
QED
Theorem validErrorboundCorrectConstant:
∀(E1 E2:env) (A:analysisResult) (n nR nF e nlo nhi:real) dVars m Gamma.
eval_Real E1 Gamma (Const m n) nR /\
eval_Fin E2 Gamma (Const m n) nF m /\
validTypes (Const m n) Gamma /\
validErrorbound (Const m n) Gamma A dVars /\
(nlo <= nR /\ nR <= nhi) /\
FloverMapTree_find (Const m n) A = SOME ((nlo,nhi),e) ==>
(abs (nR - nF)) <= e
Proof
rpt strip_tac \\ fs[Once validErrorbound_eq, toREval_def]
\\ rveq \\ fs[validTypes_def] \\ rveq
\\ irule REAL_LE_TRANS
\\ find_exists_tac \\ fs[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `computeError nR m`
\\ inversion `eval_expr _ _ _ _ REAL` eval_expr_cases
\\ `nR = n` by (rveq \\ irule delta_REAL_deterministic \\ fs[])
\\ rveq \\ conj_tac
>- (irule const_abs_err_bounded
\\ qexistsl_tac [`E1`, `E2`, `toRExpMap Gamma`]
\\ inversion `eval_expr _ _ _ _ m` eval_expr_cases \\ rveq
\\ conj_tac \\ irule Const_dist' \\ fs[]
\\ find_exists_tac \\ fs[])
\\ irule computeError_up
\\ fs[maxAbs_def] \\ irule maxAbs \\ fs[]
QED
Theorem validErrorboundCorrectAddition:
∀ (E1 E2:env) (A:analysisResult) (e1:real expr) (e2:real expr)
(nR nR1 nR2 nF nF1 nF2:real) (e err1 err2:real)
(alo ahi e1lo e1hi e2lo e2hi :real) dVars m m1 m2 Gamma.
eval_Real E1 Gamma e1 nR1 /\
eval_Real E1 Gamma e2 nR2 /\
eval_Real E1 Gamma (Binop Plus e1 e2) nR /\
eval_Fin E2 Gamma e1 nF1 m1 /\
eval_Fin E2 Gamma e2 nF2 m2 /\
eval_expr (updEnv 2 nF2 (updEnv 1 nF1 emptyEnv))
(updDefVars (Binop Plus (Var 1) (Var 2)) m
(updDefVars (Var 2) m2 (updDefVars (Var 1) m1 (toRExpMap Gamma))))
(Binop Plus (Var 1) (Var 2)) nF m /\
validErrorbound (Binop Plus e1 e2) Gamma A dVars /\
(e1lo <= nR1 /\ nR1 <= e1hi) /\
(e2lo <= nR2 /\ nR2 <= e2hi) /\
FloverMapTree_find e1 A = SOME ((e1lo, e1hi), err1) /\
FloverMapTree_find e2 A = SOME ((e2lo, e2hi), err2) /\
FloverMapTree_find (Binop Plus e1 e2) A = SOME ((alo, ahi), e) /\
FloverMapTree_find (Binop Plus e1 e2) Gamma = SOME m /\
abs (nR1 - nF1) <= err1 /\
abs (nR2 - nF2) <= err2 ==>
abs (nR - nF) <= e
Proof
rpt strip_tac \\ simp[Once toREval_def]
\\ fs[Once validErrorbound_eq] \\ rveq
\\ fs[toRExpMap_def]
\\ irule REAL_LE_TRANS
\\ qexists_tac `err1 + err2 + (computeError (nF1 + nF2) m)`
\\ conj_tac
>- (irule add_abs_err_bounded
\\ rpt (find_exists_tac \\ fs[]))
\\ irule REAL_LE_TRANS \\ find_exists_tac
\\ conj_tac \\ fs[]
\\ qmatch_abbrev_tac `_ <= computeError (maxAbs iv) _`
\\ PairCases_on `iv` \\ irule computeError_up
\\ unabbrev_all_tac \\ fs[maxAbs_def]
\\ irule maxAbs
\\ `contained nF1 (widenInterval (e1lo,e1hi) err1)`
by (irule distance_gives_iv
\\ qexists_tac `nR1` \\ conj_tac
\\ simp[contained_def])
\\ `contained nF2 (widenInterval (e2lo,e2hi) err2)`
by (irule distance_gives_iv
\\ qexists_tac `nR2` \\ conj_tac
\\ simp[contained_def])
\\ assume_tac (REWRITE_RULE [validIntervalAdd_def, contained_def] interval_addition_valid)
\\ fs[contained_def, widenInterval_def]
QED
Theorem validErrorboundCorrectSubtraction:
!(E1 E2:env) (A:analysisResult) (e1:real expr) (e2:real expr)
(nR nR1 nR2 nF nF1 nF2:real) (e err1 err2:real)
(alo ahi e1lo e1hi e2lo e2hi:real) dVars m m1 m2 Gamma.
eval_Real E1 Gamma e1 nR1 /\
eval_Real E1 Gamma e2 nR2 /\
eval_Real E1 Gamma (Binop Sub e1 e2) nR /\
eval_Fin E2 Gamma e1 nF1 m1 /\
eval_Fin E2 Gamma e2 nF2 m2 /\
eval_expr (updEnv 2 nF2 (updEnv 1 nF1 emptyEnv))
(updDefVars (Binop Sub (Var 1) (Var 2)) m
(updDefVars (Var 2) m2 (updDefVars (Var 1) m1 (toRExpMap Gamma))))
(Binop Sub (Var 1) (Var 2)) nF m /\
validErrorbound (Binop Sub e1 e2) Gamma A dVars /\
(e1lo <= nR1 /\ nR1 <= e1hi) /\
(e2lo <= nR2 /\ nR2 <= e2hi) /\
FloverMapTree_find e1 A = SOME ((e1lo, e1hi), err1) /\
FloverMapTree_find e2 A = SOME ((e2lo, e2hi), err2) /\
FloverMapTree_find (Binop Sub e1 e2) A = SOME ((alo, ahi), e) /\
FloverMapTree_find (Binop Sub e1 e2) Gamma = SOME m /\
abs (nR1 - nF1) <= err1 /\
abs (nR2 - nF2) <= err2 ==>
abs (nR - nF) <= e
Proof
rpt strip_tac \\ simp[Once toREval_def]
\\ fs[Once validErrorbound_eq] \\ rveq
\\ irule REAL_LE_TRANS
\\ qexists_tac `err1 + err2 + computeError (nF1 - nF2) m`
\\ conj_tac
>- (irule subtract_abs_err_bounded
\\ rpt (find_exists_tac \\ fs[]))
\\ irule REAL_LE_TRANS \\ find_exists_tac
\\ conj_tac \\ fs[]
\\ qmatch_abbrev_tac `_ <= computeError (maxAbs iv) _`
\\ PairCases_on `iv` \\ irule computeError_up
\\ unabbrev_all_tac \\ fs[maxAbs_def]
\\ irule maxAbs
\\ `contained nF1 (widenInterval (e1lo,e1hi) err1)`
by (irule distance_gives_iv
\\ qexists_tac `nR1` \\ conj_tac
\\ simp[contained_def])
\\ `contained nF2 (widenInterval (e2lo,e2hi) err2)`
by (irule distance_gives_iv
\\ qexists_tac `nR2` \\ conj_tac
\\ simp[contained_def])
\\ assume_tac (REWRITE_RULE [validIntervalSub_def, contained_def] interval_subtraction_valid)
\\ fs[contained_def, widenInterval_def]
QED
local
val trivial_up_tac =
irule REAL_LE_LADD_IMP (* remove lhs of addition *)
(* Try first proving by transitivity only *)
\\ TRY (
irule REAL_LE_RMUL_IMP \\ fs[] \\ NO_TAC)
(* Try first proving by transitivity only *)
\\ TRY (
irule REAL_LE_LMUL_IMP \\ fs[] \\ NO_TAC)
(* Try proving by removing negation and simplification first *)
\\ TRY (
rewrite_tac [GSYM REAL_NEG_RMUL, GSYM REAL_NEG_LMUL]
\\ fs [REAL_LE_NEG] (* invert inequality with negation *)
\\ irule REAL_LE_ADD_FLIP \\ simp[real_sub] (* by assumption *)
\\ NO_TAC)
(* If the above fails, we may be able to prove it by "exploiting a negation" *)
\\ TRY (
(qmatch_goalsub_abbrev_tac `a * - b <= - (c * b)`
\\ real_rewrite `(a * - b ≤ - (c * b)) = (a * - b ≤ (c:real) * - b)`)
ORELSE
(qmatch_goalsub_abbrev_tac `a * - b <= - (b * c)`
\\ real_rewrite `(a * - b ≤ - (b * c)) = (a * - b ≤ (c:real) * - b)`)
ORELSE
(qmatch_goalsub_abbrev_tac `a * b <= b * c`
\\ real_rewrite `(a * b ≤ b * c) = (a * b ≤ (c:real) * b)`)
ORELSE
(qmatch_goalsub_abbrev_tac `- (a * b) <= a * - c`
\\ real_rewrite `(- (a * b) <= a * - c) = (a:real * - b <= a * - c)`
\\ once_rewrite_tac [REAL_MUL_COMM])
\\ irule REAL_LE_RMUL_IMP
\\ unabbrev_all_tac \\ fs[] \\ metis_tac[REAL_LE_ADD_FLIP, real_sub]
\\ NO_TAC);
in
Theorem multiplicationErrorBounded:
!(nR1 nR2 nF1 nF2: real) (err1 err2: real) (e1lo e1hi e2lo e2hi: real).
e1lo ≤ nR1 /\ nR1 ≤ e1hi /\
e2lo ≤ nR2 /\ nR2 ≤ e2hi /\
abs (nR1 − nF1) ≤ err1 /\
abs (nR2 − nF2) ≤ err2 /\
0 ≤ err1 /\ 0 ≤ err2 ==>
abs (nR1 * nR2 − nF1 * nF2) ≤
maxAbs (e1lo,e1hi) * err2 + maxAbs (e2lo,e2hi) * err1 + err1 * err2
Proof
rpt strip_tac
\\`nR1 <= maxAbs (e1lo, e1hi)`
by (irule contained_leq_maxAbs_val
\\ fs[contained_def, IVlo_def, IVhi_def])
\\ `nR2 <= maxAbs (e2lo, e2hi)`
by (irule contained_leq_maxAbs_val
\\ fs[contained_def, IVlo_def, IVhi_def])
\\`-nR1 <= maxAbs (e1lo, e1hi)`
by (irule contained_leq_maxAbs_neg_val
\\ fs[contained_def, IVlo_def, IVhi_def])
\\ `-nR2 <= maxAbs (e2lo, e2hi)`
by (irule contained_leq_maxAbs_neg_val
\\ fs[contained_def, IVlo_def, IVhi_def])
\\ `nR1 * err2 <= maxAbs (e1lo, e1hi) * err2`
by (irule REAL_LE_RMUL_IMP \\ fs[])
\\ `-nR1 * err2 <= maxAbs (e1lo, e1hi) * err2`
by (irule REAL_LE_RMUL_IMP \\ fs[])
\\ `nR2 * err1 <= maxAbs (e2lo, e2hi) * err1`
by (irule REAL_LE_RMUL_IMP \\ fs[])
\\ `-nR2 * err1 <= maxAbs (e2lo, e2hi) * err1`
by (irule REAL_LE_RMUL_IMP \\ fs[])
\\ `- (err1 * err2) <= err1 * err2`
by (once_rewrite_tac[REAL_NEG_LMUL] \\ irule REAL_LE_RMUL_IMP \\ REAL_ASM_ARITH_TAC)
\\ `0 <= maxAbs (e1lo, e1hi) * err2` by REAL_ASM_ARITH_TAC
\\ `maxAbs (e1lo, e1hi) * err2 <= maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
by REAL_ASM_ARITH_TAC
\\ `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1 <=
maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1 + err1 * err2`
by REAL_ASM_ARITH_TAC
\\ `! (x:real). ((abs x = x) /\ 0 < x) \/ ((abs x = - x) /\ x <= 0)`
by REAL_ASM_ARITH_TAC
(* Large case distinction for
a) different cases of the value of Rabs (...) and
b) wether arguments of multiplication in (nf1 * nF2) are < or >= 0 *)
\\ qpat_assum `!x. (A /\ B) \/ C` (qspecl_then [`nR1 - nF1` ] assume_tac)
\\ qpat_assum `!x. (A /\ B) \/ C` (qspecl_then [`nR2 - nF2` ] assume_tac)
\\ fs[] \\ rfs[realTheory.abs] \\ fs[]
(* All positive *)
>- (
`nF1 <= nR1 + err1` by (irule err_up \\ simp[REAL_LE_ABS_TRANS])
\\ `nF2 <= nR2 + err2` by (irule err_up \\ simp[REAL_LE_ABS_TRANS])
\\ qpat_assum `!x. (A /\ B) \/ C` (qspecl_then [`nR1 * nR2 - nF1 * nF2` ] assume_tac)
\\ fs[real_sub]
(* Absolute value positive *)
>-(
qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * (- (nR2 + err2))` \\ conj_tac
>- (fs[REAL_NEG_RMUL])
\\ qspecl_then [`- (nR2 + err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 + err2) < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 - err1) * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 - err1) * - (nR2 + err2) = - nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[])
(* 0 ≤ -(nR2 + err2) *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 + err2)` \\ conj_tac
>- (irule REAL_LE_LADD_IMP
\\ irule REAL_LE_RMUL_IMP \\ fs[])
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 + err2) = - nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nF1 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * - (nR2 - err2)` \\ conj_tac
>- (irule REAL_LE_LADD_IMP \\ once_rewrite_tac [REAL_NEG_RMUL]
\\ irule REAL_LE_LMUL_IMP \\ fs[real_sub]
\\ qpat_x_assum ‘∀ x. _’ kall_tac \\ REAL_ASM_ARITH_TAC)
\\ qspecl_then [`- (nR2 - err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 - err2) < 0 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 - err1) * - (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 - err1) * - (nR2 - err2) = nR1 * err2 + nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\simp[]
\\ simp[GSYM REAL_NEG_LMUL]
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ -(nR2 - err2) *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 - err2)` \\ conj_tac
>- (irule REAL_LE_LADD_IMP \\ irule REAL_LE_RMUL_IMP \\ fs[])
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 - err2) = nR1 * err2 + - nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])))
(* Absolute value negative *)
\\ simp [REAL_NEG_ADD]
\\ qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 - err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 - err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 - err1) * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 - err1) * (nR2 - err2) = - nR1 * err2 + - nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[])
(* 0 ≤ nR2 - err2 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 - err2) = - nR1 * err2 + nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL]))
(* 0 ≤ nF1 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 + err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 + err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 - err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 - err1) * (nR2 + err2) = nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL]
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nR2 + err2 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2) = nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])
(* First positive, second negative *)
>- (
`nF1 <= nR1 + err1` by (irule err_up \\ simp[REAL_LE_ABS_TRANS])
\\ `nF2 <= nR2 + err2`
by (once_rewrite_tac[REAL_ADD_COMM] \\ simp [GSYM REAL_LE_SUB_RADD]
\\ once_rewrite_tac [REAL_ADD_COMM, GSYM REAL_NEG_SUB] \\ simp[] )
\\ qpat_assum `!x. (A /\ B) \/ C` (qspecl_then [`nR1 * nR2 - nF1 * nF2` ] assume_tac)
\\ fs[real_sub]
\\ qpat_assum `nR2 + - nF2 <= _ `
(fn thm => assume_tac (SIMP_RULE bool_ss [GSYM real_sub, REAL_LE_SUB_RADD, REAL_ADD_LID] thm))
(* Absolute value positive *)
>-(
qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * (- (nR2 + err2))` \\ conj_tac
>- (fs[REAL_NEG_RMUL])
\\ qspecl_then [`- (nR2 + err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 + err2) < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 - err1) * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 - err1) * - (nR2 + err2) = - nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[])
(* 0 ≤ -(nR2 + err2) *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 + err2) = - nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nF1 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * -nR2` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`- nR2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -nR2 < 0 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 - err1) * - nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 - err1) * - nR2 = nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo,e2hi) * err1` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp [REAL_LE_ADDR])
(* 0 ≤ - nR2 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - nR2 = - nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo,e2hi) * err1` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp [REAL_LE_ADDR])))
(* Absolute value negative *)
\\ simp [REAL_NEG_ADD]
\\ qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * nR2` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 - err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 - err1) * nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 - err1) * nR2 = - nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo,e2hi) * err1` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp [REAL_LE_ADDR])
(* 0 ≤ nR2 - err2 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * nR2 = nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo,e2hi) * err1` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp [REAL_LE_ADDR]))
(* 0 ≤ nF1 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 + err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 + err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 - err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 - err1) * (nR2 + err2) = nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL]
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nR2 + err2 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2) = nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])
(* First negative, second positive *)
>- (
`nF1 <= nR1 + err1`
by (once_rewrite_tac[REAL_ADD_COMM] \\ simp [GSYM REAL_LE_SUB_RADD]
\\ once_rewrite_tac [REAL_ADD_COMM, GSYM REAL_NEG_SUB] \\ simp[])
\\ `nF2 <= nR2 + err2` by (irule err_up \\ simp[])
\\ qpat_assum `!x. (A /\ B) \/ C` (fn thm => qspecl_then [`nR1 * nR2 - nF1 * nF2` ] DISJ_CASES_TAC thm)
\\ fs[real_sub]
(* Absolute value positive *)
>-(
qpat_x_assum `nR1 + - nF1 <= _ `
(fn thm => assume_tac (SIMP_RULE bool_ss [GSYM real_sub, REAL_LE_SUB_RADD, REAL_ADD_LID] thm))
\\ qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * - (nR2 + err2)` \\ conj_tac
>- (fs[REAL_NEG_RMUL])
\\ qspecl_then [`- (nR2 + err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 + err2) < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nR1 * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `nR1 * nR2 + nR1 * - (nR2 + err2) = - nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ -(nR2 + err2) *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 + err2) = - nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nF1 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * - (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`- (nR2 - err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 - err2) < 0 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nR1 * - (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `nR1 * nR2 + nR1 * - (nR2 - err2) = nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ -(nR2 - err2) *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 - err2) = nR1 * err2 + - nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])))
(* Absolute value negative *)
\\ qpat_x_assum `nR1 + - nF1 <= _ `
(fn thm => assume_tac (SIMP_RULE bool_ss [GSYM real_sub, REAL_LE_SUB_RADD, REAL_ADD_LID] thm))
\\ simp [REAL_NEG_ADD]
\\ qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 - err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 - err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nR1 * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `-(nR1 * nR2) + nR1 * (nR2 - err2) = - nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ nR2 - err2 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 - err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 - err2) = - nR1 * err2 + nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL]))
(* 0 ≤ nF1 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 + err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 + err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nR1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `-(nR1 * nR2) + nR1 * (nR2 + err2) = nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ nR2 + err2 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2) = nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])
(* Both negative *)
>- (
`nF1 <= nR1 + err1`
by (once_rewrite_tac[REAL_ADD_COMM]
\\ simp [GSYM REAL_LE_SUB_RADD]
\\ once_rewrite_tac [REAL_ADD_COMM, GSYM REAL_NEG_SUB] \\ simp[])
\\ `nF2 <= nR2 + err2`
by (once_rewrite_tac[REAL_ADD_COMM]
\\ simp [GSYM REAL_LE_SUB_RADD]
\\ once_rewrite_tac [REAL_ADD_COMM, GSYM REAL_NEG_SUB] \\ simp[])
\\ `nR1 <= nF1`
by (qpat_x_assum `nR1 - nF1 <= _ `
(fn thm =>
assume_tac
(SIMP_RULE bool_ss [GSYM real_sub, REAL_LE_SUB_RADD, REAL_ADD_LID] thm))
\\ simp[])
\\ `nR2 <= nF2`
by (qpat_x_assum `nR2 - nF2 <= _ `
(fn thm =>
assume_tac (SIMP_RULE bool_ss [GSYM real_sub, REAL_LE_SUB_RADD, REAL_ADD_LID] thm))
\\ simp[])
\\ qpat_assum `!x. (A /\ B) \/ C`
(fn thm => qspecl_then [`nR1 * nR2 - nF1 * nF2` ] DISJ_CASES_TAC thm)
\\ fs[real_sub]
(* Absolute value positive *)
>-(
qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * - (nR2 + err2)` \\ conj_tac
>- (fs[REAL_NEG_RMUL])
\\ qspecl_then [`- (nR2 + err2)`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -(nR2 + err2) < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nR1 * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `nR1 * nR2 + nR1 * - (nR2 + err2) = - nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ -(nR2 + err2) *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - (nR2 + err2) = - nR1 * err2 + - nR2 * err1 + - err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ TRY(simp[GSYM REAL_NEG_LMUL])
\\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[REAL_NEG_LMUL])
(* 0 ≤ nF1 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nF1 * -nR2` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`- nR2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* -nR2 < 0 *)
>- (irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + nR1 * - nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `nR1 * nR2 + nR1 * - nR2 = 0`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2`
\\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ - nR2 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `nR1 * nR2 + (nR1 + err1) * - nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`nR1 * nR2 + (nR1 + err1) * - nR2 = - nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo,e2hi) * err1` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp [REAL_LE_ADDR])))
(* Absolute value negative *)
\\ simp [REAL_NEG_ADD]
\\ qspecl_then [`nF1`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nF1 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * nR2` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nR1 * nR2 ` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `-(nR1 * nR2) + nR1 * nR2 = 0`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ nR2 - err2 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * nR2` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `-(nR1 * nR2) + (nR1 + err1) * nR2 = nR2 * err1`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[]
\\ once_rewrite_tac [REAL_ADD_COMM]
\\ simp[REAL_LE_ADDR]))
(* 0 ≤ nF1 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nF1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ qspecl_then [`nR2 + err2`, `0`] DISJ_CASES_TAC REAL_LTE_TOTAL
(* nR2 + err2 < 0 *)
>- (
irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + nR1 * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite `-(nR1 * nR2) + nR1 * (nR2 + err2) = nR1 * err2`
\\ simp[] \\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2` \\ conj_tac \\ simp[]
\\ irule REAL_LE_TRANS
\\ qexists_tac `maxAbs (e1lo, e1hi) * err2 + maxAbs (e2lo, e2hi) * err1`
\\ conj_tac \\ simp[])
(* 0 ≤ nR2 + err2 *)
\\ irule REAL_LE_TRANS
\\ qexists_tac `-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2)` \\ conj_tac
>- trivial_up_tac
\\ real_rewrite
`-(nR1 * nR2) + (nR1 + err1) * (nR2 + err2) = nR1 * err2 + nR2 * err1 + err1 * err2`
\\ simp[] \\ irule REAL_LE_ADD2 \\ conj_tac \\ simp[GSYM REAL_NEG_LMUL])
QED
end
Theorem validErrorboundCorrectMult:
!(E1 E2:env) (A:analysisResult) (e1:real expr) (e2:real expr)
(nR nR1 nR2 nF nF1 nF2:real) (e err1 err2:real)
(alo ahi e1lo e1hi e2lo e2hi :real) dVars m m1 m2 Gamma.
eval_Real E1 Gamma e1 nR1 /\
eval_Real E1 Gamma e2 nR2 /\
eval_Real E1 Gamma (Binop Mult e1 e2) nR /\
eval_Fin E2 Gamma e1 nF1 m1 /\
eval_Fin E2 Gamma e2 nF2 m2 /\
eval_expr (updEnv 2 nF2 (updEnv 1 nF1 emptyEnv))
(updDefVars (Binop Mult (Var 1) (Var 2)) m
(updDefVars (Var 2) m2 (updDefVars (Var 1) m1 (toRExpMap Gamma))))
(Binop Mult (Var 1) (Var 2)) nF m /\
validErrorbound (Binop Mult e1 e2) Gamma A dVars /\
(e1lo <= nR1 /\ nR1 <= e1hi) /\
(e2lo <= nR2 /\ nR2 <= e2hi) /\
FloverMapTree_find e1 A = SOME ((e1lo, e1hi), err1) /\
FloverMapTree_find e2 A = SOME ((e2lo, e2hi), err2) /\
FloverMapTree_find (Binop Mult e1 e2) A = SOME ((alo, ahi), e) /\
FloverMapTree_find (Binop Mult e1 e2) Gamma = SOME m /\
abs (nR1 - nF1) <= err1 /\
abs (nR2 - nF2) <= err2 ==>
abs (nR - nF) <= e
Proof
rpt strip_tac \\ simp[Once toREval_def]
\\ fs[Once validErrorbound_eq] \\ rveq
\\ `0 <= err1`
by (irule err_always_positive
\\ qexistsl_tac [`A`, `dVars`, `e1`, `(e1lo,e1hi)`, `Gamma`]
\\ fs[])
\\ `0 <= err2`
by (drule err_always_positive
\\ rpt (disch_then drule)
\\ fs[])
\\ irule REAL_LE_TRANS
\\ qexists_tac `abs (nR1 * nR2 - nF1 * nF2) + computeError (nF1 * nF2) m`