build.gradle

import org.apache.tools.ant.filters.ReplaceTokens
import org.codehaus.groovy.runtime.GStringImpl

plugins {
  id "org.sonarqube" version "2.7.1"
}

project.ext {
    environment = getEnvProperty('env', 'docker') as Object
    bundleDir = getEnvProperty('liferay.workspace.home.dir', project.projectDir.toString() + '/bundles')
    liferayData = project.projectDir.toString() + '/docker/liferay/data'
    liferayMount = project.projectDir.toString() + '/docker/liferay/mount/files'
    dockerContainerPrefix = getEnvProperty('liferay.docker.container.prefix', 'oss')
    dockerComposeFilePath = getEnvProperty('liferay.docker.compose.path', project.projectDir.toString() + '/docker/docker-compose.yml')
    deployFolder = "${bundleDir}/deploy" as GStringImpl
    bundleDirectories = [
            file("$bundleDir/deploy"),
            file("$bundleDir/osgi/deploy"),
            file("$bundleDir/osgi/modules"),
            file("$liferayData"),
            file("$liferayMount")
    ]
    Properties localProperties = new Properties()
    localProperties.load(file("${project.projectDir.toString()}/gradle-local.properties").newDataInputStream())
    dbName = getLocalProperty(localProperties,'dbName', 'liferay')
    dbUser = getLocalProperty(localProperties,'dbUser', 'liferay')
    dbPassword = getLocalProperty(localProperties,'dbPassword', 'liferay')
    defaultLiferayAdminPassword = getLocalProperty(localProperties,'default.admin.password', 'test')
    keyUrl = getLocalProperty(localProperties, 'KEYCLOAK_URL', '')
    keyClient = getLocalProperty(localProperties, 'KEYCLOAK_CLIENTID', '')
    keySecret = getLocalProperty(localProperties, 'KEYCLOAK_CLIENTSECRET', '')
    emailUser = getLocalProperty(localProperties, 'EMAIL_USER', '')
    emailPass = getLocalProperty(localProperties, 'EMAIL_PASSWORD','')
    downloadUrl = getEnvProperty('DOWNLOAD_URL', '')
    downloadName = getEnvProperty('DOWNLOAD_APPNAME', '')
    downloadUser = getEnvProperty('DOWNLOAD_APPUSER', '')
    downloadPass = getEnvProperty('DOWNLOAD_APPPW', '')
    ipgeolocationApiUrl = getEnvProperty('IPGEOLOCATION_APIURL', '')
    ipgeolocationApiKey = getEnvProperty('IPGEOLOCATION_APIKEY', '')
    sendinblueApiKey = getEnvProperty('SENDINBLUE_API_KEY', '')
    sendinblueApiUrl = getEnvProperty('SENDINBLUE_API_URL', '')
    sendinblueFolderId = getEnvProperty('SENDINBLUE_FOLDER', '')
    licenseUrl = getEnvProperty('LICENSE_URL', '')
    licenseUser = getEnvProperty('LICENSE_USER', '')
    licensePass = getEnvProperty('LICENSE_PASSWORD', '')
}
task startContainers(
        description: 'Start all docker containers',
        group: 'docker'
) {
    doLast {
        exec {
            executable 'docker-compose'
            args('-p', dockerContainerPrefix, '-f', dockerComposeFilePath, 'up', '--build', '--force-recreate', '-d')
            environment('LIFERAY_BUNDLE_DIR', bundleDir)
        }
    }
}

task startLiferay(
        'description': 'Start Liferay stack',
        'group': 'docker'
) {
    doLast {
        delete "$bundleDir"
        delete "$liferayMount"
        bundleDirectories.forEach {
            if (!it.exists()) {
                it.mkdirs()
            }
        }
        copy {
            from("$projectDir/configs/$environment/")
            into("$liferayMount")
            include("*.properties")
            filter(ReplaceTokens, tokens: [
                    'MYSQL_DATABASE'        : dbName,
                    'MYSQL_USER'            : dbUser,
                    'MYSQL_PASSWORD'        : dbPassword,
                    'DEFAULT_ADMIN_PASSWORD': defaultLiferayAdminPassword,
                    'KEYCLOAK_URL'          : keyUrl,
                    'KEYCLOAK_CLIENTID'     : keyClient,
                    'KEYCLOAK_CLIENTSECRET' : keySecret,
                    'EMAIL_USER'            : emailUser,
                    'EMAIL_PASSWORD'        : emailPass,
                    'DOWNLOAD_URL'          : downloadUrl,
                    'DOWNLOAD_APPNAME'      : downloadName,
                    'DOWNLOAD_APPUSER'      : downloadUser,
                    'DOWNLOAD_APPPW'        : downloadPass,
                    'IPGEOLOCATION_APIURL'  : ipgeolocationApiUrl,
                    'IPGEOLOCATION_APIKEY'  : ipgeolocationApiKey,
                    'SENDINBLUE_API_KEY'    : sendinblueApiKey,
                    'SENDINBLUE_API_URL'    : sendinblueApiUrl,
                    'SENDINBLUE_FOLDER'     : sendinblueFolderId,
                    'LICENSE_URL'           : licenseUrl,
                    'LICENSE_USER'          : licenseUser,
                    'LICENSE_PASSWORD'      : licensePass
            ])
        }
        copy {
            from("$projectDir/configs/$environment/") {
                exclude "osgi", "**.properties", "config"
            }
            into("$liferayMount")
        }
        copy {
            from("$projectDir/configs/common/")
            into("$liferayMount/osgi/configs/")
            include "**/**"
        }
        copy {
            from("$projectDir/configs/$environment/osgi/configs/")
            into("$liferayMount/osgi/configs")
            include "*.config"
        }
        copy {
            from("$projectDir/configs/$environment/osgi/modules/")
            into("$liferayMount/osgi/modules")
            include "*.xml"
        }
        copy {
            from projectDir
            into deployFolder
            include "license.xml"
        }
    }
    finalizedBy startContainers
}

task stopLiferay(
        'description': 'Stop all containers',
        'group': 'docker'
) {
    doLast {
        exec {
            executable 'docker-compose'
            args('-p', dockerContainerPrefix, '-f', dockerComposeFilePath, 'down', '--rmi', 'local')
        }
        print "stop"
    }
}

task dumpDB(
        description: 'Dump the database into the file system.',
        group: 'docker'
) {
    doLast {
        exec {
            executable 'docker'
            args('exec', '-t', "${dockerContainerPrefix}-mariadb", 'mysqldump', "-u${dbUser}", "-p${dbPassword}",
                    '--extended-insert=FALSE', '--no-autocommit', '--opt', "${dbName}")
            standardOutput new FileOutputStream("${projectDir}/docker/mariadb/docker-entrypoint-initdb.d/${dbName}.sql")
        }
        exec {
            executable 'bash'
            args('-c', "sed -i'' -e '1d' ${projectDir}/docker/mariadb/docker-entrypoint-initdb.d/${dbName}.sql")
        }
        delete("${projectDir}/docker/mariadb/docker-entrypoint-initdb.d/${dbName}.sql-e")
    }
}

task geoipDownload{
    group = 'Deltares'
    description = 'Downloads GeoIp2-Lite database'

    doLast {
        def bundlePath = ('/liferay/home/geoip2/')
        def geoLiteTar = ('GeoLite2-City.tar.gz')

        def f = new File(bundlePath + geoLiteTar)

        if (!f.exists()) {
            new URL('https://geolite.maxmind.com/download/geoip/database/' + geoLiteTar).withInputStream{ i -> f.withOutputStream{ it << i }}
        }

        copy {
            from (tarTree(resources.gzip(bundlePath + geoLiteTar))) {
                include "**/*.mmdb"
                eachFile { fcd ->
                    fcd.relativePath = new RelativePath(true, fcd.relativePath.segments.drop(1))
                }
                includeEmptyDirs = false
            }
            into bundlePath
        }
    }
}

def getEnvProperty(String propertyName, String defaultValue) {
    if (project.hasProperty(propertyName)) {
        return project.getProperty(propertyName) ?: defaultValue
    }
    return defaultValue
}

def getLocalProperty(Properties properties, String propertyName, String defaultValue) {
    if (properties.containsKey(propertyName)) {
        return properties.get(propertyName) ?: defaultValue
    }
    return getEnvProperty(propertyName, defaultValue)
}