build.gradle

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        google()
    }

    dependencies {
    }
}

plugins {
    id "com.diffplug.spotless" version "6.25.0"
}

spotless {
    format 'misc', {
        target '**/*.gradle', '.gitattributes', '.gitignore'

        trimTrailingWhitespace()
        indentWithSpaces()
        endWithNewline()
    }
    java {
        target 'core/src/**/*.java', 'desktop/src/**/*.java'
        toggleOffOn()

        importOrder()
        removeUnusedImports()
        palantirJavaFormat('2.40.0')
        formatAnnotations()
        endWithNewline()
    }
}

allprojects {
    apply plugin: "eclipse"

    version = '0.0.20'
    ext {
        appName = "assessment1"
        gdxVersion = '1.12.1'
        roboVMVersion = '2.3.20'
        box2DLightsVersion = '1.5'
        ashleyVersion = '1.7.4'
        aiVersion = '1.8.2'
        gdxControllersVersion = '2.2.1'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        google()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
        maven { url "https://jitpack.io" }
    }
}

project(":desktop") {
    apply plugin: "java-library"

    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        api "com.badlogicgames.gdx:gdx-box2d-platform:$gdxVersion:natives-desktop"

    }
}

project(":core") {
    apply plugin: "java-library"

    dependencies {
        api "com.badlogicgames.gdx:gdx:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
        implementation "com.badlogicgames.ashley:ashley:1.7.4"
        implementation "space.earlygrey:shapedrawer:2.6.0"


        testImplementation platform("org.junit:junit-bom:5.10.2")
        testImplementation "org.junit.jupiter:junit-jupiter"
        testImplementation "org.assertj:assertj-core:3.25.1"
        testImplementation 'org.mockito:mockito-core:5.11.0'
        testImplementation "com.badlogicgames.gdx:gdx-backend-headless:$gdxVersion"
        testImplementation "com.badlogicgames.gdx:gdx:$gdxVersion"
        testImplementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        testImplementation 'junit:junit:4.+'
    }

    test {
        useJUnitPlatform()
        testLogging {
            showStandardStreams = true
        }
    }
}