-
Notifications
You must be signed in to change notification settings - Fork 1
/
triggers.qc
2465 lines (2047 loc) · 66.4 KB
/
triggers.qc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// entity s;
void() trigger_reactivate =
{
self.solid = SOLID_TRIGGER;
};
//=============================================================================
float SPAWNFLAG_NOMESSAGE = 1;
float SPAWNFLAG_NOTOUCH = 1;
float SPAWNFLAG_TURNS_OFF = 2; //used for Wait for retrigger spawnflag
// the wait time has passed, so set back up for another activation
void() multi_wait =
{
if (self.max_health)
{
self.health = self.max_health;
self.takedamage = DAMAGE_YES;
self.solid = SOLID_BBOX;
}
};
// the trigger was just touched/killed/used
// self.enemy should be set to the activator so it can be held through a delay
// so wait for the delay time before firing
void() multi_trigger =
{
if (self.nextthink > time)
{
return; // allready been triggered
}
if (self.classname == "trigger_secret")
{
if (self.enemy.classname != "player")
return;
if (cutscene)
return; // Don't activate in cutscene mode
found_secrets = found_secrets + 1;
WriteByte (MSG_ALL, SVC_FOUNDSECRET);
}
if (self.noise != "")
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
// don't trigger again until reset
self.takedamage = DAMAGE_NO;
activator = self.enemy;
SUB_UseTargets();
if (self.wait > 0)
{
self.think = multi_wait;
self.nextthink = time + self.wait;
if (self.spawnflags & SPAWNFLAG_TURNS_OFF)
{
self.is_waiting = 1;
SUB_CheckWaiting();
}
}
else
{ // we can't just remove (self) here, because this is a touch function
// called wheil C code is looping through area links...
self.touch = SUB_Null;
self.nextthink = time + 0.1;
self.think = SUB_Remove;
}
};
void() multi_killed = //dumptruck_ds
{
if (self.estate != STATE_ACTIVE) // Supa, restore health and do nothing if we're still waiting to be activated
{
self.health = self.max_health; // nyah nyah~!
self.takedamage = DAMAGE_YES;
self.solid = SOLID_BBOX;
return;
}
self.enemy = damage_attacker;
multi_trigger();
};
void() multi_use = //dumptruck_ds
{
self.enemy = activator;
multi_trigger();
};
void() multi_touch = //dumptruck_ds
{
if (other.classname != "player")
return;
// from Copper -- dumptruck_ds
if (other.movetype == MOVETYPE_NOCLIP)
return;
if (self.estate != STATE_ACTIVE)
return;
// if the trigger has an angles field, check player's facing direction
if (self.movedir != '0 0 0')
{
makevectors (other.angles);
if (v_forward * self.movedir < 0)
return; // not facing the right way
}
self.enemy = other;
multi_trigger ();
};
/*QUAKED trigger_multiple (.5 .5 .5) ? notouch WAIT_FOR_RETRIGGER X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Variable sized repeatable trigger. Must be targeted at one or more entities. If "health" is set, the trigger must be killed to activate each time.
If "WAIT_FOR_RETRIGGER" is set, it must be triggered by another entity before it can trigger again.
If "delay" is set, the trigger waits some time after activating before firing.
"wait" : Seconds between triggerings. (.2 default)
If notouch is set, the trigger is only fired by other entities, not by touching.
NOTOUCH has been obsoleted by trigger_relay!
sounds
1) secret
2) beep beep
3) large switch
set "message" to text string
"is_waiting" : If set to 1, this trigger will do nothing until another trigger activates it
*/
void() trigger_multiple =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
if (!self.noise) {
if (self.sounds == 1)
{
precache_sound ("misc/secret.wav");
self.noise = "misc/secret.wav";
}
else if (self.sounds == 2)
{
precache_sound ("misc/talk.wav");
self.noise = "misc/talk.wav";
}
else if (self.sounds == 3)
{
precache_sound ("misc/trigger1.wav");
self.noise = "misc/trigger1.wav";
}
}
else
{
precache_sound (self.noise);
}
if (!self.wait)
{
self.wait = 0.2;
}
else if (self.wait < 0 && (self.spawnflags & SPAWNFLAG_TURNS_OFF))
{
objerror("Wait for retrigger and negative wait don't make sense");
}
self.use = multi_use;
InitTrigger ();
if (self.health)
{
if (self.spawnflags & SPAWNFLAG_NOTOUCH)
objerror ("health and notouch don't make sense\n");
self.max_health = self.health;
self.th_die = multi_killed;
self.takedamage = DAMAGE_YES;
self.solid = SOLID_BBOX;
setorigin (self, self.origin); // make sure it links into the world
}
else
{
if ( !(self.spawnflags & SPAWNFLAG_NOTOUCH) )
{
self.touch = multi_touch;
}
}
if(self.actionable != 0)
if(self.touch)
{
self.actiontouch = self.touch;
self.touch = SUB_Null;
}
SUB_CheckWaiting();
};
/*QUAKED trigger_once (.5 .5 .5) ? notouch X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Variable sized trigger. Triggers once, then removes itself. You must set the key "target" to the name of another object in the level that has a matching
"targetname". If "health" is set, the trigger must be killed to activate.
If notouch is set, the trigger is only fired by other entities, not by touching.
if "killtarget" is set, any objects that have a matching "target" will be removed when the trigger is fired.
if "angle" is set, the trigger will only fire when someone is facing the direction of the angle. Use "360" for an angle of 0.
sounds
1) secret
2) beep beep
3) large switch
set "message" to text string
*/
void() trigger_once =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
self.wait = -1;
trigger_multiple();
};
//=============================================================================
/*QUAKED trigger_relay (.5 .5 .5) (-8 -8 -8) (8 8 8) X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
This fixed size trigger cannot be touched, it can only be fired by other events. It can contain killtargets, targets, delays, and messages.
*/
void() trigger_relay =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
self.use = SUB_UseTargets;
};
//=============================================================================
/*QUAKED trigger_secret (.5 .5 .5) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
secret counter trigger
sounds
1) secret
2) beep beep
set "message" to text string
*/
void() trigger_secret =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
total_secrets = total_secrets + 1;
self.wait = -1;
if (!self.message)
self.message = "You found a secret area!";
if (!self.sounds)
self.sounds = 1;
if (!self.noise) {
if (self.sounds == 1)
{
precache_sound ("misc/secret.wav");
self.noise = "misc/secret.wav";
}
else if (self.sounds == 2)
{
precache_sound ("misc/talk.wav");
self.noise = "misc/talk.wav";
}
}
trigger_multiple ();
};
//=============================================================================
void counter_return_buttons (.string targetfield, string targetname)
{
for (entity e = world; (e = find(e, targetfield, targetname)); )
{
if (e.classname == "func_button")
{
e.think = button_return;
e.nextthink = e.ltime + 1;
}
}
}
void() counter_use =
{
if (self.estate != STATE_ACTIVE) return;
self.count = self.count - 1;
if (self.count < 0)
return;
self.cnt += 1;
if (other.aflag > 0 && other.aflag != self.cnt)
self.items = 1; //Wrong order
/**/
entity msgEnt = world;
if (activator.classname == "player" && (self.spawnflags & SPAWNFLAG_NOMESSAGE) == 0)
msgEnt = activator;
else if (self.spawnflags & TRIGGER_CENTERPRINTALL)
msgEnt = find(world, classname, "player"); //Re:Mobilize is for many reasons singleplayer-focused, so let's not bother with a loop to find "all the players". Here the spawnflags simply means "send a message to player never mind they're the direct activator or not".
/**/
if (self.count != 0)
{
if (msgEnt)
{
if (self.count >= 4)
centerprint (msgEnt, "There are more to go...");
else if (self.count == 3)
centerprint (msgEnt, "Only 3 more to go...");
else if (self.count == 2)
centerprint (msgEnt, "Only 2 more to go...");
else
centerprint (msgEnt, "Only 1 more to go...");
}
return;
}
if (msgEnt)
{
if(self.items == 0 && self.message != "")
centerprint(msgEnt, self.message);
else if(self.items == 0)
centerprint(msgEnt, "Sequence completed!");
else if(self.message2 != "")
centerprint(msgEnt, self.message2);
else
centerprint(msgEnt, "Wrong sequence");
}
self.enemy = activator;
if(self.items == 0)
multi_trigger ();
else
{
SUB_UsePain2();
//Get ready for the next try
self.cnt = 0;
self.count = self.frags;
self.items = 0;
//Return buttons to initial state
counter_return_buttons(target,self.targetname);
counter_return_buttons(target,self.targetname2);
counter_return_buttons(target,self.targetname3);
counter_return_buttons(target,self.targetname4);
counter_return_buttons(target2,self.targetname);
counter_return_buttons(target2,self.targetname2);
counter_return_buttons(target2,self.targetname3);
counter_return_buttons(target2,self.targetname4);
counter_return_buttons(target3,self.targetname);
counter_return_buttons(target3,self.targetname2);
counter_return_buttons(target3,self.targetname3);
counter_return_buttons(target3,self.targetname4);
counter_return_buttons(target4,self.targetname);
counter_return_buttons(target4,self.targetname2);
counter_return_buttons(target4,self.targetname3);
counter_return_buttons(target4,self.targetname4);
}
};
/*QUAKED trigger_counter (.5 .5 .5) ? nomessage X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Acts as an intermediary for an action that takes multiple inputs.
If nomessage is not set, t will print "1 more.. " etc when triggered and "sequence complete" when finished.
After the counter has been triggered "count" times (default 2), it will fire all of it's targets and remove itself.
*/
void() trigger_counter =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
self.wait = -1;
if (!self.count)
self.count = 2;
//Used when caring for the order
self.items = 0;
self.cnt = 0;
self.frags = self.count;
self.use = counter_use;
};
/*
==============================================================================
TELEPORT TRIGGERS with added functions from Zerstrorer and Qmaster
-- dumptruck_ds
==============================================================================
*/
float PLAYER_ONLY = 1;
float SILENT = 2;
float RANDOM = 4;
float TELE_STEALTH = 8;
float MONSTER_ONLY = 16;
float TELE_DD = 32;
void() play_teleport =
{
local float v;
local string tmpstr;
v = random() * 5;
if (v < 1)
tmpstr = "misc/r_tele1.wav";
else if (v < 2)
tmpstr = "misc/r_tele2.wav";
else if (v < 3)
tmpstr = "misc/r_tele3.wav";
else if (v < 4)
tmpstr = "misc/r_tele4.wav";
else
tmpstr = "misc/r_tele5.wav";
sound (self, CHAN_VOICE, tmpstr, 1, ATTN_NORM);
remove (self);
};
void(vector org) spawn_tfog =
{
local entity s;
s = spawn ();
s.origin = org;
s.spawnflags = self.spawnflags; //dumptruck_ds
s.nextthink = time + 0.2;
s.think = play_teleport;
WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
WriteByte (MSG_BROADCAST, TE_TELEPORT);
WriteCoord (MSG_BROADCAST, org_x);
WriteCoord (MSG_BROADCAST, org_y);
WriteCoord (MSG_BROADCAST, org_z);
};
void() tdeath_touch =
{
if (other == self.owner)
return;
// frag anyone who teleports in on top of an invincible player
if (other.classname == "player")
{
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes start
if (self.owner.classname != "player")
{ // other monsters explode themselves
T_Damage (self.owner, self, self, 50000);
return;
}
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes end
if (other.invincible_finished > time)
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes start
{ //player on spot has active pentagram
if (self.owner.invincible_finished > time)
{ // teleported player has active pentagram too
// can happen often in deathmatch 4
// and levels with more than one pentagram
self.classname = "teledeath3";
other.invincible_finished = 0;
T_Damage (other, self, self, 50000); // kill player on spot
/* 1998-07-26 only telefrag player on spot by Maddes
local entity other2;
other2 = self.owner;
self.owner = other;
other2.invincible_finished = 0;
T_Damage (other2, self, self, 50000); // kill teleported player
*/
}
else // 1998-07-26 only telefrag player on spot by Maddes
{ // 1998-07-26 only telefrag player on spot by Maddes
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes end
self.classname = "teledeath2";
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes start
T_Damage (self.owner, self, self, 50000);
} // 1998-07-26 only telefrag player on spot by Maddes
return;
}
/*
if (self.owner.classname != "player")
{ // other monsters explode themselves
T_Damage (self.owner, self, self, 50000);
return;
}
*/
// 1998-07-26 Pentagram telefrag fix by Zoid/Maddes end
}
if (other.health)
{
T_Damage (other, self, self, 50000);
}
};
void(vector org, entity death_owner) spawn_tdeath =
{
local entity death;
death = spawn();
death.classname = "teledeath";
death.movetype = MOVETYPE_NONE;
death.solid = SOLID_TRIGGER;
death.angles = '0 0 0';
setsize (death, death_owner.mins - '1 1 1', death_owner.maxs + '1 1 1');
setorigin (death, org);
death.touch = tdeath_touch;
death.nextthink = time + 0.2;
death.think = SUB_Remove;
death.owner = death_owner;
force_retouch = 2; // make sure even still objects get hit
};
/*-----------------------------------------------*/
/*| more Zerstrorer-- dumptruck_ds |*/
/*| teleport_randomspot - returns a random spot |*/
/*| to teleport to among all of the |*/
/*| "info_teleport_random" entities in the |*/
/*| level. self.count is number of spots |*/
/*-----------------------------------------------*/
entity() teleport_randomspot =
{
local float rndm;
// local float rndm, num1;
local entity spot,first;
rndm = rint(random() * (self.count - 1));
spot = find(world, classname, "info_teleport_random");
if(!spot)
dprint("No random teleport points found!\n");
first = spot;
while (rndm > 0)
{
rndm = rndm - 1;
spot = find(spot, classname, "info_teleport_random");
}
if (spot == world)
{
dprint("Random spot found world!!\n");
spot = first;
}
return spot;
};
// end dumptruck_ds
void() teleport_touch =
{
local entity t;
local vector org;
if (self.estate != STATE_ACTIVE) return;
if (self.targetname != "")
{
if (self.nextthink < time)
{
return; // not fired yet
}
}
if (self.spawnflags & PLAYER_ONLY)
{
if (other.classname != "player")
return;
}
if (self.spawnflags & MONSTER_ONLY) // is this going to work? dumptruck_ds
{
if (other.classname == "player")
return;
}
if (other.movetype == MOVETYPE_NOCLIP) // from Copper -- dumptruck_ds
return;
if (self.is_waiting == TRUE) // Supa, is this trigger waiting to be activated?
return;
if (self.is_waiting != -1) // Special case
if (self.targetname != "")
{
if (self.nextthink < time)
{
return; // not fired yet
}
}
// only teleport living creatures
if (other.health <= 0 || other.solid != SOLID_SLIDEBOX)
return;
SUB_UseTargets ();
// put a tfog where the player was
// ### dhm - if stealth, don't spawn a fog
if (!(self.spawnflags & TELE_STEALTH))
spawn_tfog (other.origin);
//dhm - if this is a random teleporter, pick a random spot!
if (self.spawnflags & RANDOM)
t = teleport_randomspot();
else if ((self.spawnflags & TELE_DD) && other.classname == "player")
t = find (world, targetname, self.noise);
else
t = find (world, targetname, self.target);
if (!t)
objerror ("couldn't find target");
float dest_speed = t.speed;
if(!dest_speed) dest_speed = 300; //Default push speed at destination
// // put a tfog where the player was
// spawn_tfog (other.origin);
//
// t = find (world, targetname, self.target);
// if (!t)
// objerror ("couldn't find target");
// spawn a tfog flash in front of the destination
makevectors (t.mangle);
org = t.origin + 32 * v_forward;
// ### dhm - if stealth, don't spawn a fog
if (!(self.spawnflags & TELE_STEALTH))
spawn_tfog (org);
spawn_tdeath(t.origin, other);
// move the player and lock him down for a little while
if (!other.health)
{
other.origin = t.origin;
other.velocity = (v_forward * other.velocity_x) + (v_forward * other.velocity_y);
return;
}
setorigin (other, t.origin);
other.angles = t.mangle;
if (other.classname == "player")
{
fog_setFromEnt(other, t); // retrieves fog values from teleport destination, if any
other.fixangle = 1; // turn this way immediately
other.teleport_time = time + 0.7;
if (other.flags & FL_ONGROUND)
other.flags = other.flags - FL_ONGROUND;
other.velocity = v_forward * dest_speed;
}
other.flags = other.flags - other.flags & FL_ONGROUND;
if ((self.spawnflags & MONSTER_ONLY) && other.classname != "player")
{
other.fixangle = 1; // turn this way immediately
other.teleport_time = time + 0.7;
if (other.flags & FL_ONGROUND)
other.flags = other.flags - FL_ONGROUND;
other.velocity = v_forward * dest_speed;
}
other.flags = other.flags - other.flags & FL_ONGROUND;
};
// this is from Qmaster:
// "I created an info_teleport_changedest
// target = targetname of trigger_teleport to affect
// message = targetname of new info_teleport_destination (or whatever entity
// really) to now teleport to
// So that I can automatically update the teleporter under my coagula map as you
// progress rather than have a bunch of triggers that I need to killtarget.
// Falling is not fatal then, but it does put you back some. Works as a sorta
// checkpoint system but also builds on my older idea for saving time in coop
// implemented in my Terracity map eons ago.
// looking at vanilla, you would only need to change trig.target to match
// self.message if you were to add this.""
void() teleport_destchange =
{
local entity trig;
trig = find(world,targetname,self.target);
if (!trig || trig.classname != "trigger_teleport") {
dprint("\b[TELEPORT_DESTCHANGE]\b Cannot find trigger_teleport\n");
return;
}
trig.goalentity = find (world, targetname, self.message);
if (!trig.goalentity) {
dprint("\b[TELEPORT_DESTCHANGE]\b Cannot find teleport destination\n");
return;
}
makevectors (trig.goalentity.mangle);
trig.goalentity.movedir = v_forward;
trig.goalentity.pos1 = trig.goalentity.origin + 32 * trig.goalentity.movedir;
trig.target = self.message; //dumptruck_ds see comment above
};
/*QUAKED info_teleport_changedest (0 0.5 0) (-4 -4 -4) (4 4 4) X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Allows a mapper to change the target of a teleport_trigger. Useful in maps where
the player may fall into a void and the mapper wants to update where they "respawn"
as they progress through the level. Could also be used for teleport puzzles and more.
target = trigger_teleport to change
message = new info_teleport_destination's targetname to switch to
targetname = name of this entity so we can use it
*/
void() info_teleport_changedest =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
self.use = teleport_destchange;
if (self.targetname == "") {
dprint("\b[ERROR]\b info_teleport_changedest with no targetname");
remove(self);
}
if (self.target == "") {
dprint("\b[ERROR]\b info_teleport_changedest with no target");
remove(self);
}
if (self.message == "") {
dprint("\b[ERROR]\b info_teleport_changedest with no message set for new destination");
remove(self);
}
};
/*QUAKED info_teleport_destination (.5 .5 .5) (-8 -8 -8) (8 8 32) X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
{
model ("progs/player.mdl");
}
This is the destination marker for a teleporter. It should have a "targetname" field with the same value as a teleporter's "target" field.
*/
void() info_teleport_destination =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
// this does nothing, just serves as a target spot
self.mangle = self.angles;
self.angles = '0 0 0';
self.model = "";
self.origin = self.origin + '0 0 27';
if (!self.targetname)
objerror ("no targetname");
};
/*QUAKED info_teleport_random (.5 .5 .5) (-8 -8 -8) (8 8 32) X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
{
model ("progs/player.mdl");
}
This is a random destination marker for a teleporter.
*/
void() info_teleport_random =
{
// this does nothing, just serves as a target spot
self.mangle = self.angles;
self.angles = '0 0 0';
self.model = "";
self.origin = self.origin + '0 0 27';
};
void() teleport_use =
{
self.nextthink = time + 0.2;
force_retouch = 2; // make sure even still objects get hit
self.think = SUB_Null;
};
// -------------------------
/*QUAKED trigger_teleport (.5 .5 .5) ? PLAYER_ONLY SILENT RANDOM STEALTH X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Any object touching this will be transported to the corresponding
info_teleport_destination entity. You must set the "target" field,
and create an object with a "targetname" field that matches.
If the trigger_teleport has a targetname, it will only teleport entities
when it has been fired.
SILENT(2) eliminates the teleporter ambient noise (good for hidden monster teleporters.
RANDOM(4) causes the teleporter to send the player to a random destination
among the info_teleport_random markers in the level. You MUST place a
"count" field that is the number of info_teleport_random entities you
placed.
STEALTH(8) eliminates the particle flash and noise when an entity is teleported.
MONSTER_ONLY(16) will only teleport monsters
*/void() trigger_teleport =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
InitTrigger ();
self.touch = teleport_touch;
// find the destination
if (!self.target)
objerror ("no target");
self.use = teleport_use;
if (!(self.spawnflags & SILENT))
{
precache_sound ("ambience/hum1.wav");
if (!self.is_waiting)
{
vector o = (self.mins + self.maxs)*0.5;
ambientsound (o, "ambience/hum1.wav",0.5 , ATTN_STATIC);
}
}
SUB_CheckWaiting();
};
/*
==============================================================================
trigger_setskill
==============================================================================
*/
void() trigger_skill_touch =
{
// from Copper -- dumptruck_ds
if (!CheckValidTouch()) return;
cvar_set ("skill", self.message);
};
/*QUAKED trigger_setskill (.5 .5 .5) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
sets skill level to the value of "message".
Only used on start map.
*/
void() trigger_setskill =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
InitTrigger ();
self.touch = trigger_skill_touch;
SUB_CheckWaiting();
};
/*
==============================================================================
ONLY REGISTERED TRIGGERS
==============================================================================
*/
void() trigger_onlyregistered_touch =
{
// from Copper -- dumptruck_ds
if (!CheckValidTouch()) return;
if (self.attack_finished > time)
return;
self.attack_finished = time + 2;
if (cvar("registered"))
{
self.message = "";
SUB_UseTargets ();
remove (self);
}
else
{
if (self.message != "")
{
centerprint (other, self.message);
sound (other, CHAN_BODY, "misc/talk.wav", 1, ATTN_NORM);
}
}
};
/*QUAKED trigger_onlyregistered (.5 .5 .5) ?
Only fires if playing the registered version, otherwise prints the message
*/
void() trigger_onlyregistered =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
precache_sound ("misc/talk.wav");
InitTrigger ();
self.touch = trigger_onlyregistered_touch;
SUB_CheckWaiting();
};
//============================================================================
// 1998-07-03 hurt_touch fix by Robert Field start
/*
void() hurt_on =
{
self.solid = SOLID_TRIGGER;
self.nextthink = -1;
};
*/
// 1998-07-03 hurt_touch fix by Robert Field end
void() hurt_touch =
{
if (self.estate != STATE_ACTIVE) return;
// from Copper -- dumptruck_ds
if (other.movetype == MOVETYPE_NOCLIP)
return;
if (other.takedamage && self.nextthink < time)
{
// 1998-07-03 hurt_touch fix by Robert Field start
// self.solid = SOLID_NOT;
if (time != self.hurt_together_time)
if (time < self.hurt_nextthink)
return;
// 1998-07-03 hurt_touch fix by Robert Field end
T_Damage (other, self, self, self.dmg);
// 1998-07-03 hurt_touch fix by Robert Field start
// self.think = hurt_on;
// self.nextthink = time + 1;
self.hurt_together_time = time;
self.hurt_nextthink = time + 1;
// 1998-07-03 hurt_touch fix by Robert Field end
}
return;
};
/*QUAKED trigger_hurt (.5 .5 .5) ? X X X X X X X X NOT_ON_EASY NOT_ON_NORMAL NOT_ON_HARD_OR_NIGHTMARE NOT_IN_DEATHMATCH NOT_IN_COOP NOT_IN_SINGLEPLAYER X NOT_ON_HARD_ONLY NOT_ON_NIGHTMARE_ONLY
Any object touching this will be hurt
set dmg to damage amount
defalt dmg = 5
*/
void() trigger_hurt =
{
if (SUB_Inhibit ()) // new spawnflags for all entities -- iw
return;
InitTrigger ();
self.touch = hurt_touch;
if (!self.dmg)
self.dmg = 5;
SUB_CheckWaiting();
};
//============================================================================
//////////////////////////////////////////////////////////////////////////////
// start dumptruck_ds additions //////////////////////////////////////////////
//////////////////////////////////////////////////////////////////////////////
float PUSH_ONCE = 1;
float DT_STARTOFF = 8; // trigger will start off
float DT_SILENT = 16; // push silently
float DT_NOISE = 32; // use custom sound using noise key/value
void() trigger_push_touch =
{
if (self.estate != STATE_ACTIVE) return;
// from Copper -- dumptruck_ds
if (other.movetype == MOVETYPE_NOCLIP)
return;
if (other.classname == "grenade")
other.velocity = self.speed * self.movedir * 10;
else if (other.health > 0)
{
other.velocity = self.speed * self.movedir * 10;
if (other.classname == "player")
if (!(self.spawnflags & DT_SILENT))
{
if (other.fly_sound < time)
if (!(self.spawnflags & DT_NOISE))
{
other.fly_sound = time + 1.5;