settings.gradle

pluginManagement {
    repositories {
        mavenLocal()
        mavenCentral()
        gradlePluginPortal()

        maven {
            name("Fabric")
            url("https://maven.fabricmc.net")
        }

        maven {
            name("Jitpack")
            url("https://jitpack.io")
        }

        maven {
            name("Nyan Maven")
            url("https://maven.hendrixshen.top")
        }

        maven {
            name("Cotton")
            url("https://server.bbkr.space/artifactory/libs-release")
        }
    }
}

def versions = Arrays.asList(
        "1.14.4",
        "1.15.2",
        "1.16.5",
        "1.17.1",
        "1.18.2",
        "1.19.2",
        "1.19.3",
        "1.19.4",
        "1.20.1",
        "1.20.2",
        "1.20.4",
)

for (String version : versions) {
    include(":$version")
    def proj = project(":$version")
    proj.projectDir = file("versions/$version")
    proj.buildFileName = "../../common.gradle"
}

include(":fabricWrapper")