build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'idea'
}

repositories {
    flatDir {
        dirs 'lib'
    }
}

java {
    withJavadocJar()
    withSourcesJar()
}

group 'diarg'
version '0.12-SNAPSHOT'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    maven {
        url 'http://tweetyproject.org/mvn/'
    }
}

dependencies {
    implementation('net.sf.tweety:tweety-full:1.17') {
        exclude group: 'org.ojalgo', module: 'ojalgo'
        exclude group: 'jspf', module: 'core'
    }
    implementation("com.google.guava:guava:29.0-jre")
    compile 'org.junit.jupiter:junit-jupiter-api:5.6.1'
    testRuntimeOnly("org.junit.platform:junit-platform-launcher:1.6.2")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.6.2")
    testRuntimeOnly("org.junit.vintage:junit-vintage-engine:5.6.2")
}

task run(type: JavaExec) {
    classpath sourceSets.main.runtimeClasspath
    main = "diarg.DiArg"
}

javadoc {
    source = sourceSets.main.allJava
    classpath = configurations.compileClasspath

    options
            {
                setMemberLevel JavadocMemberLevel.PUBLIC
                setAuthor true
            }
}

sourceSets {
    main {
        java {
            srcDir 'src'
            srcDir 'test'
        }
    }
}

test {
    useJUnitPlatform {
        includeEngines 'junit-jupiter'
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'di-arg'
            from components.java
            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom {
                name = 'DiArg'
                description = 'An Argumentation-Based Dialogue Reasoner'
                url = 'https://github.com/TimKam/diarg'
                licenses {
                    license {
                        name = 'BSD 2-Clause License'
                        url = 'https://github.com/TimKam/diarg/LICENSE'
                    }
                }
                developers {
                    developer {
                        id = 'TimKam'
                        name = 'Timotheus Kampik'
                        email = 'tkampik@cs.umu.se'
                    }
                }
            }
        }
    }
}