build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'org.openjfx.javafxplugin' version '0.1.0'
    id "io.github.gradle-nexus.publish-plugin" version "2.0.0"
}

allprojects {
    group = 'org.jabref'
    version = '2.0.0-SNAPSHOT'
    ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

    repositories {
        mavenCentral()
    }
}

apply plugin: 'java'
apply from: 'eclipse.gradle'


tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17

    withJavadocJar()
    withSourcesJar()
}

javafx {
    version = "20"
    modules = ['javafx.controls', 'javafx.fxml', 'javafx.web', 'javafx.swing']
}

dependencies {
    implementation 'jakarta.inject:jakarta.inject-api:2.0.1'
    implementation 'org.slf4j:slf4j-api:2.0.16'
    implementation 'jakarta.annotation:jakarta.annotation-api:3.0.0'
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'afterburner.fx'
            from components.java
            pom {
                name = 'afterburner.fx'
                description = 'Afterburner.fx is a MVP framework for JavaFX.'
                url = 'https://github.com/JabRef/afterburner.fx'

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution = 'repo'
                    }
                }
                developers {
                    developer {
                        id = 'siedlerchr'
                        name = 'Christoph Schwentker'
                    }

                    developer {
                        id = 'koppor'
                        name = 'Oliver Kopp'
                    }
                    developer {
                        id = 'tobiasdiez'
                        name = 'Tobias Diez'
                    }
                    developer {
                        name = 'Adam Bien'
                    }
                }
                scm {
                    url = 'https://github.com/JabRef/afterburner.fx'
                    connection = 'scm:git:git://github.com/JabRef/afterburner.fx.git'
                    developerConnection = 'scm:git:git@github.com/JabRef/afterburner.fx.git'
                }
            }
        }
    }
}

signing {
    required = isReleaseVersion
    useInMemoryPgpKeys(System.getenv("SIGNING_KEY"), System.getenv("SIGNING_PASSWORD"))
    sign publishing.publications.mavenJava
}
nexusPublishing {
    repositories {
        sonatype {  //only for users registered in Sonatype after 24 Feb 2021
            username = System.getenv("MAVEN_USERNAME")
            password = System.getenv("MAVEN_PASSWORD")
            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
        }
    }
}