build.gradle

buildscript {
    repositories {
        jcenter()
        mavenCentral()
        gradlePluginPortal()
        maven { url = 'https://repo.spongepowered.org/maven' }
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://maven.parchmentmc.org' }
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath "org.spongepowered:mixingradle:0.7-SNAPSHOT"
        classpath 'org.parchmentmc:librarian:1.+'
    }
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'org.spongepowered.mixin'
apply plugin: 'org.parchmentmc.librarian.forgegradle'

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17


// <mayor>.<path>.<hotfix>
version = watercore_version // 1 <mayor update> .0 <update> .0 <patch> -A/B/C/D... <hotfix>
group = 'me.srrapero720.watercore'

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"
minecraft {
    mappings channel: 'parchment', version: '2022.08.07-1.18.2'
    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        client {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            property 'forge.enabledGameTestNamespaces', 'watercore'
            arg "-mixin.config=watercore.mixin.json"
            mods {
                watercore {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            arg "-mixin.config=watercore.mixin.json"
            mods {
                watercore {
                    source sourceSets.main
                }
            }
        }
    }
}

// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    maven { url "https://maven.tterrag.com/" }
    maven {
        url 'https://www.cursemaven.com'
        content {
            includeGroup "curse.maven"
        }
    }
}

dependencies {
    //BASICS
    minecraft "net.minecraftforge:forge:${mcV}-${fgV}"
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'

    // CREATE STUFF
    implementation fg.deobf("com.simibubi.create:create-${mcV}:${createV}:slim") { transitive = false }
    implementation fg.deobf("com.jozufozu.flywheel:flywheel-forge-${mcV}:${flywheelV}")
    implementation fg.deobf("com.tterrag.registrate:Registrate:${registrateV}")

    // SUIT OF FANCYMENU
    implementation files("libs/drippy2.1.2.jar", "libs/fancymenu2.14.2.jar", "libs/konkrete1.6.0.jar")

    // SUPPORT FOR OTHER MODS
    implementation fg.deobf("curse.maven:ferritecore-429235:4074294")
    implementation fg.deobf("curse.maven:fastload-630620:4271605")
    implementation fg.deobf("curse.maven:lazy-dfu-forge-460819:3544496")

    //MIXIN: VM423535
    implementation fg.deobf("curse.maven:vanishmod-423535:4324040")

    //MIXIN: SL312664
    implementation fg.deobf("curse.maven:simple-login-312664:3864949")

    //LUCKPERMS
    implementation fg.deobf("net.luckperms:api:5.4")
}

mixin {
    add sourceSets.main, "watercore.mixin-refmap.json"
}

java { withSourcesJar() }


jar {
    manifest {
        attributes([
                "Specification-Title"     : "watercore",
                "Specification-Vendor"    : "srrapero720",
                "Specification-Version"   : "1", // We are version 1 of ourselves
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "srrapero720",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                "TweakClass"              : "org.spongepowered.asm.launch.MixinTweaker",
                "TweakOrder"              : 0,
                "MixinConfigs"            : "watercore.mixin.json"
        ])
    }
}

jar.finalizedBy('reobfJar')

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}