maven.gradle

apply plugin: "maven"
apply plugin: "propdeps-maven"

install {
    repositories.mavenInstaller {
        customizePom(pom, project)
    }
}

def customizePom(pom, gradleProject) {
    pom.whenConfigured { generatedPom ->

        // eliminate test-scoped dependencies (no need in maven central poms)
        generatedPom.dependencies.removeAll { dep ->
            dep.scope == 'test'
        }

        // add all items necessary for maven central publication
        generatedPom.project {
            name = gradleProject.description
            description = gradleProject.description
            url = 'http://github.com/spring-projects/spring-hadoop'
            organization {
                name = 'Spring by Pivotal'
                url = 'http://projects.spring.io/spring-hadoop/'
            }
            licenses {
                license {
                    name 'The Apache Software License, Version 2.0'
                    url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    distribution 'repo'
                }
            }
            scm {
                url = 'http://github.com/spring-projects/spring-hadoop'
                connection = 'scm:git:git://github.com/spring-projects/spring-hadoop'
                developerConnection = 'scm:git:git://github.com/spring-projects/spring-hadoop'
            }
            developers {
                developer {
                    id = 'costin'
                    name = 'Costin Leau'
                    properties {
                        twitter = 'costinl'
                    }
                }
                developer {
                    id = 'trisberg'
                    name = 'Thomas Risberg'
                    email = 'trisberg@gopivotal.com'
                    properties {
                        twitter = 'trisberg'
                    }
                }
                developer {
                    id = 'jvalkeal'
                    name = 'Janne Valkealahti'
                    email = 'jvalkealahti@gopivotal.com'
                    properties {
                        twitter = 'tunebluez'
                    }
                }
            }
        }
    }
}