build.gradle

plugins {
    id 'fabric-loom' version '1.6-SNAPSHOT' apply(false)
    id 'net.minecraftforge.gradle' version '[6.0,6.2)' apply(false)
    id 'org.spongepowered.gradle.vanilla' version '0.2.1-SNAPSHOT' apply(false)
    id 'org.spongepowered.mixin' version '0.7-SNAPSHOT' apply(false)
}

subprojects {
    apply plugin: 'java'

    java.toolchain.languageVersion = JavaLanguageVersion.of(17)
        
    jar {
        from(rootProject.file("LICENSE")) {
            rename { "${it}_${mod_name}" }
        }
        manifest {
            attributes([
                'Specification-Title'     : mod_name,
                'Specification-Vendor'    : mod_authors,
                'Specification-Version'   : project.jar.archiveVersion,
                'Implementation-Title'    : project.name,
                'Implementation-Version'  : project.jar.archiveVersion,
                'Implementation-Vendor'   : mod_authors,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Timestamp'               : System.currentTimeMillis(),
                'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                'Built-On-Minecraft'      : minecraft_version
            ])
        }
    }

    repositories {
        mavenCentral()
        maven {
            name = 'Sponge / Mixin'
            url = 'https://repo.spongepowered.org/repository/maven-public/'
        }
        maven {
            name = 'BlameJared Maven (JEI / CraftTweaker / Bookshelf)'
            url = 'https://maven.blamejared.com'
        }
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.encoding = 'UTF-8'
        it.options.getRelease().set(17)
    }

    processResources {
        def expandProps = [
                "version"                           : version,
                "mapping_version"                   : mapping_version,
                "group"                             : project.group, //Else we target the task's group.
                "minecraft_version"                 : minecraft_version,
                "forge_version"                     : forge_version,
                "forge_loader_version_range"        : forge_loader_version_range,
                "forge_version_range"               : forge_version_range,
                "minecraft_version_range_forge"     : minecraft_version_range_forge,
                "fabric_version"                    : fabric_version,
                "fabric_loader_version"             : fabric_loader_version,
                "minecraft_version_range_fabric"    : minecraft_version_range_fabric,
                "modmenu_version"                   : modmenu_version,
                "mod_name"                          : mod_name,
                "mod_authors"                       : mod_authors,
                "forge_mod_credits"                 : mod_credits,
                "fabric_mod_credits"                : mod_credits.split("\n").collect { "\"${it.trim()}\"" }.join(", "), // JSON array format
                "mod_id"                            : mod_id,
                "license"                           : license,
                "description"                       : project.description,
                "display_url"                       : display_url,
                "issue_tracker_url"                 : issue_tracker_url
        ]

        filesMatching(['pack.mcmeta', 'fabric.mod.json', 'META-INF/mods.toml', '*.mixins.json']) {
            expand expandProps
        }
        inputs.properties(expandProps)
    }
}