build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url 'https://maven.fabric.io/public' }

    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.2.3'
        classpath 'io.fabric.tools:gradle:+'
    }
}

apply plugin: 'com.android.application'
apply plugin: 'io.fabric'

repositories {
    maven { url 'https://dl.bintray.com/kennyc1012/maven' }
    maven { url "http://dl.bintray.com/amulyakhare/maven" }
    // Use if material dialogs can not be found in JCenter
    // maven { url 'https://dl.bintray.com/drummer-aidan/maven' }
    maven { url 'https://maven.fabric.io/public' }
    flatDir { dirs 'libs' }
    mavenCentral()
    jcenter()
}

def VERSION_NAME = '2.8.2'

android {
    compileSdkVersion 22
    buildToolsVersion "22.0.1"

    defaultConfig {
        applicationId "com.kennyc.open.imgur"
        minSdkVersion 15
        targetSdkVersion 22
        versionCode 27
        buildConfigField "String", "API_CLIENT_ID", project.API_CLIENT_ID
        buildConfigField "String", "API_CLIENT_SECRET", project.API_CLIENT_SECRET
    }

    productFlavors {
        full {
            versionName VERSION_NAME
        }

        beta {
            versionName VERSION_NAME + "-beta"
        }
    }

    buildTypes {

        release {
            ext.enableCrashlytics = true
            minifyEnabled false
            manifestPlaceholders = [fabric_key: project.FABRIC_KEY]
        }

        debug {
            ext.enableCrashlytics = false
            minifyEnabled false
            manifestPlaceholders = [fabric_key: ""]
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
}

def SUPPORT_VERSION = '22.2.0'

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:support-annotations:' + SUPPORT_VERSION
    compile 'com.android.support:support-v13:' + SUPPORT_VERSION
    compile 'com.android.support:cardview-v7:' + SUPPORT_VERSION
    compile 'com.android.support:appcompat-v7:' + SUPPORT_VERSION
    //compile 'com.android.support:design:' + SUPPORT_VERSION
    compile 'pl.droidsonroids.gif:android-gif-drawable:1.1.7'
    compile 'com.nostra13.universalimageloader:universal-image-loader:1.9.4'
    compile 'com.kennyc:snackbar:2.5'
    compile 'com.squareup.okhttp:okhttp:2.4.0'
    compile 'com.jakewharton:butterknife:6.1.0'
    compile 'com.jpardogo.materialtabstrip:library:1.0.9'
    compile 'com.amulyakhare:com.amulyakhare.textdrawable:1.0.1'
    compile 'com.afollestad:material-dialogs:0.7.5.1'
    compile 'com.github.clans:fab:1.5.0'
    compile 'com.davemorrissey.labs:subsampling-scale-image-view:3.1.3'
    compile(name: 'sliding_panel', ext: 'aar')
    compile(name: 'bottom-sheet-1.0', ext: 'aar')
    compile project(':libraries:EventBus')
    compile('com.crashlytics.sdk.android:crashlytics:+@aar') {
        transitive = true;
    }
}