From ad5d499711243ebde6b5ca1d1537e09c34693ca3 Mon Sep 17 00:00:00 2001
From: Srushti Patel <137830748+srushti-patl@users.noreply.github.com>
Date: Wed, 17 Jan 2024 14:41:47 -0800
Subject: [PATCH] CXF-83184 Adding Virtual Device & Adding VD 2 Azure Example
 (#23)

* CXF-83184 Adding Virtual Device & Adding VD 2 Azure Example

* CXF-83184 Updating changes for VD2Azure example

* CXF-83184 fixing change for virtual interface type

* CXF-83184 fixing style for versions.tf file
---
 .../README.md                                 |   0
 .../virtual-device-2-azure-connection/main.tf |  98 ++++++++
 .../outputs.tf                                |   6 +
 .../terraform.tfvars.example                  |  60 +++++
 .../variables.tf                              | 213 ++++++++++++++++++
 .../versions.tf                               |  13 ++
 modules/virtual-device-connection/README.md   |   0
 modules/virtual-device-connection/main.tf     | 177 +++++++++++++++
 modules/virtual-device-connection/outputs.tf  |   6 +
 .../virtual-device-connection/variables.tf    | 116 ++++++++++
 modules/virtual-device-connection/versions.tf |   9 +
 11 files changed, 698 insertions(+)
 create mode 100644 examples/virtual-device-2-azure-connection/README.md
 create mode 100644 examples/virtual-device-2-azure-connection/main.tf
 create mode 100644 examples/virtual-device-2-azure-connection/outputs.tf
 create mode 100644 examples/virtual-device-2-azure-connection/terraform.tfvars.example
 create mode 100644 examples/virtual-device-2-azure-connection/variables.tf
 create mode 100644 examples/virtual-device-2-azure-connection/versions.tf
 create mode 100644 modules/virtual-device-connection/README.md
 create mode 100644 modules/virtual-device-connection/main.tf
 create mode 100644 modules/virtual-device-connection/outputs.tf
 create mode 100644 modules/virtual-device-connection/variables.tf
 create mode 100644 modules/virtual-device-connection/versions.tf

diff --git a/examples/virtual-device-2-azure-connection/README.md b/examples/virtual-device-2-azure-connection/README.md
new file mode 100644
index 00000000..e69de29b
diff --git a/examples/virtual-device-2-azure-connection/main.tf b/examples/virtual-device-2-azure-connection/main.tf
new file mode 100644
index 00000000..116dd26f
--- /dev/null
+++ b/examples/virtual-device-2-azure-connection/main.tf
@@ -0,0 +1,98 @@
+provider "equinix" {
+  client_id     = var.equinix_client_id
+  client_secret = var.equinix_client_secret
+  endpoint      = var.equinix_endpoint
+}
+provider "azurerm" {
+  features {}
+  client_id       = var.azure_client_id
+  client_secret   = var.azure_client_secret
+  tenant_id       = var.azure_tenant_id
+  subscription_id = var.azure_subscription_id
+
+  skip_provider_registration = true
+}
+
+#Network Edge Module
+resource "equinix_network_acl_template" "wan-acl-template" {
+  name        = var.template_name
+  description = var.template_description
+  inbound_rule {
+    subnet   = var.template_subnet
+    protocol = var.template_protocol
+    src_port = var.template_src_port
+    dst_port = var.template_dst_port
+  }
+}
+
+resource "equinix_network_device" "C8KV-SV" {
+  name            = var.ne_name
+  metro_code      = var.ne_metro_code
+  type_code       = var.ne_type_code
+  self_managed    = true
+  byol            = true
+  package_code    = var.ne_package_code
+  notifications   = var.ne_notifications
+  hostname        = var.ne_hostname
+  account_number  = var.ne_account_number
+  version         = var.ne_version
+  core_count      = var.ne_core_count
+  term_length     = var.ne_term_length
+
+  ssh_key {
+    username = var.ne_ssh_key_username
+    key_name = var.ne_ssh_key_name
+  }
+  acl_template_id = equinix_network_acl_template.wan-acl-template.id
+}
+
+resource "equinix_network_ssh_key" "suneeth-ssh" {
+  name       = var.network_public_key_name
+  public_key = var.network_public_key
+}
+
+#Azure Provider
+resource "azurerm_resource_group" "port2azure" {
+  name     = var.azure_resource_name
+  location = var.azure_location
+}
+resource "azurerm_express_route_circuit" "port2azure" {
+  name                  = var.azure_service_key_name
+  resource_group_name   = azurerm_resource_group.port2azure.name
+  location              = azurerm_resource_group.port2azure.location
+  service_provider_name = var.azure_service_provider_name
+  peering_location      = var.azure_peering_location
+  bandwidth_in_mbps     = var.bandwidth
+  sku {
+    tier   = var.azure_tier
+    family = var.azure_family
+  }
+  allow_classic_operations = false
+  tags = {
+    environment = var.azure_environment
+  }
+}
+
+#Connection
+module "create_virtual_device_2_azure_connection" {
+  source = "../../modules/virtual-device-connection"
+
+  connection_name       = var.connection_name
+  connection_type       = var.connection_type
+  notifications_type    = var.notifications_type
+  notifications_emails  = var.notifications_emails
+  bandwidth             = azurerm_express_route_circuit.port2azure.bandwidth_in_mbps
+  purchase_order_number = var.purchase_order_number
+
+  # A-side
+  aside_vd_type = var.aside_vd_type
+  aside_vd_uuid = equinix_network_device.C8KV-SV.id
+
+  # Z-side
+  zside_ap_type               = var.zside_ap_type
+  zside_peering_type          = var.zside_peering_type
+  zside_ap_authentication_key = azurerm_express_route_circuit.port2azure.service_key
+  zside_ap_profile_type       = var.zside_ap_profile_type
+  zside_location              = var.zside_location
+  zside_sp_name               = var.zside_sp_name
+}
diff --git a/examples/virtual-device-2-azure-connection/outputs.tf b/examples/virtual-device-2-azure-connection/outputs.tf
new file mode 100644
index 00000000..fbb76c08
--- /dev/null
+++ b/examples/virtual-device-2-azure-connection/outputs.tf
@@ -0,0 +1,6 @@
+output "virtual_device_id" {
+  value = equinix_network_device.C8KV-SV.id
+}
+output "azure_connection_id" {
+  value = module.create_virtual_device_2_azure_connection.primary_connection_id
+}
diff --git a/examples/virtual-device-2-azure-connection/terraform.tfvars.example b/examples/virtual-device-2-azure-connection/terraform.tfvars.example
new file mode 100644
index 00000000..0a68c861
--- /dev/null
+++ b/examples/virtual-device-2-azure-connection/terraform.tfvars.example
@@ -0,0 +1,60 @@
+equinix_client_id      = "MyEquinixClientId"
+equinix_client_secret  = "MyEquinixSecret"
+equinix_endpoint       = "endpointURL"
+
+#NE Acl Template
+template_name           = "test-wan-acl-template"
+template_description    = "WAN ACL template"
+template_subnet         = "172.16.25.0/24"
+template_protocol       = "TCP"
+template_src_port       = "any"
+template_dst_port       = "22"
+
+#Network Edge
+ne_name                 = "Terra_Test_router"
+ne_metro_code           = "SV"
+ne_type_code            = "C8000V"
+ne_package_code         = "network-essentials"
+ne_notifications        = ["test@eq.com"]
+ne_hostname             = "C8KV"
+ne_account_number       = "182390403"
+ne_version              = "17.11.01a"
+ne_core_count           = 2
+ne_term_length          = 1
+
+ne_ssh_key_username     = "<SSH_Key_Username>"
+ne_ssh_key_name         = "<SSH_Key_Name"
+
+#network_ssh_key
+network_public_key_name = "<Public_SSH_Key_Name>"
+network_public_key      = "<Public_SSH_Key>"
+
+#Azure Provider
+azure_client_id             = "<Azure Client Id>"
+azure_client_secret         = "<Azure Client Secret Value>"
+azure_tenant_id             = "<Azure Tenant Id>"
+azure_subscription_id       = "<Azure Subscription Id>"
+azure_resource_name         = "Azure-Test"
+azure_location              = "West US 2"
+
+azure_service_key_name      = "Test_Azure_Key"
+azure_service_provider_name = "<Service Provider Name>"
+azure_peering_location      = "Silicon Valley Test"
+azure_tier                  = "Standard"
+azure_family                = "UnlimitedData"
+azure_environment           = "UAT"
+
+#VD_2_Azure_Connection
+connection_name             = "VD2Azure"
+secondary_connection_name   = "VD2Azure Sec"
+connection_type             = "EVPL_VC"
+notifications_type          = "ALL"
+notifications_emails        = ["example@equinix.com"]
+purchase_order_number       = "1-323292"
+
+aside_vd_type               = "EDGE"
+zside_ap_type               = "SP"
+zside_ap_profile_type       = "L2_PROFILE"
+zside_location              = "SV"
+zside_sp_name               = "Azure ExpressRoute"
+zside_peering_type          = "PRIVATE"
diff --git a/examples/virtual-device-2-azure-connection/variables.tf b/examples/virtual-device-2-azure-connection/variables.tf
new file mode 100644
index 00000000..4bb8d65a
--- /dev/null
+++ b/examples/virtual-device-2-azure-connection/variables.tf
@@ -0,0 +1,213 @@
+variable "equinix_client_id" {
+  description = "Equinix client ID (consumer key), obtained after registering app in the developer platform"
+  type        = string
+}
+variable "equinix_client_secret" {
+  description = "Equinix client secret ID (consumer secret), obtained after registering app in the developer platform"
+  type        = string
+}
+variable "equinix_endpoint" {
+  description = "Equinix endpoint URL"
+  type        = string
+}
+##NE Acl Template
+variable "template_name" {
+  description = "ACL Template Name"
+  type        = string
+}
+variable "template_description" {
+  description = "ACL Template description"
+  type        = string
+}
+variable "template_subnet" {
+  description = "Inbound traffic source IP subnets in CIDR format"
+  type        = string
+
+}
+variable "template_protocol" {
+  description = "Inbound traffic protocol"
+  type        = string
+}
+variable "template_src_port" {
+  description = "Inbound traffic source ports"
+  type        = string
+}
+variable "template_dst_port" {
+  description = "Inbound traffic destination ports"
+  type        = string
+}
+
+#Network Edge
+variable "ne_name" {
+  description = "Device Name"
+  type        = string
+}
+variable "ne_metro_code" {
+  description = "Device location metro code"
+  type        = string
+}
+variable "ne_type_code" {
+  description = ""
+  type        = string
+}
+variable "ne_package_code" {
+  description = "Device software package code"
+  type        = string
+}
+variable "ne_notifications" {
+  description = "List of email addresses that will receive device status notifications"
+  type        = list(string)
+}
+variable "ne_hostname" {
+  description = "Device hostname prefix"
+  type        = string
+}
+variable "ne_account_number" {
+  description = "Billing account number for a device"
+  type        = string
+  default     = 0
+}
+variable "ne_version" {
+  description = "Device software version"
+  type        = string
+  default     = null
+}
+variable "ne_core_count" {
+  description = "Core count number"
+  type        = number
+}
+variable "ne_term_length" {
+  description = "Term length in months"
+  type        = number
+}
+variable "ne_ssh_key_username" {
+  description = "username for ssh key"
+  type        = string
+}
+
+variable "ne_ssh_key_name" {
+  description = "ssh key name for device"
+  type        = string
+}
+variable "network_public_key_name" {
+  description = "The name of SSH key used for identification."
+  type = string
+}
+variable "network_public_key" {
+  description = "The SSH public key"
+  type        = string
+}
+#Azure Provider
+variable "azure_client_id" {
+  description = "Azure Client id"
+  type        = string
+}
+variable "azure_client_secret" {
+  description = "Azure Secret value"
+  type        = string
+}
+variable "azure_tenant_id" {
+  description = "Azure Tenant id"
+  type        = string
+}
+variable "azure_subscription_id" {
+  description = "Azure Subscription id"
+  type        = string
+}
+variable "azure_resource_name" {
+  description = "The name of Azure Resource"
+  type        = string
+}
+variable "azure_location" {
+  description = "The location of Azure service provider(resource)"
+  type        = string
+}
+variable "azure_service_key_name" {
+  description = "Azure Service Key Name"
+  type        = string
+}
+variable "azure_service_provider_name" {
+  description = "The name of Azure Service Provider"
+  type        = string
+  default     = ""
+}
+variable "azure_peering_location" {
+  description = "The name of the peering location (not the Azure resource location)"
+  type        = string
+  default     = ""
+}
+variable "azure_tier" {
+  description = "The Service tier. Possible values are Basic, Local, Standard or Premium"
+  type        = string
+}
+variable "azure_family" {
+  description = "The billing mode for bandwidth. Possible values are MeteredData or UnlimitedData"
+  type        = string
+}
+variable "azure_environment" {
+  description = "The Cloud environment which should be used for Service Key"
+  type        = string
+}
+#Connection Variables
+variable "connection_name" {
+  description = "Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores"
+  type        = string
+}
+variable "secondary_connection_name" {
+  description = "Secondary Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores"
+  type        = string
+  default     = ""
+}
+variable "connection_type" {
+  description = "Defines the connection type like VG_VC, EVPL_VC, EPL_VC, EC_VC, IP_VC, ACCESS_EPL_VC"
+  type        = string
+}
+variable "notifications_type" {
+  description = "Notification Type - ALL is the only type currently supported"
+  type        = string
+  default     = "ALL"
+}
+variable "notifications_emails" {
+  description = "Array of contact emails"
+  type        = list(string)
+}
+variable "bandwidth" {
+  description = "Connection bandwidth in Mbps"
+  type        = number
+  default     = 50
+}
+variable "purchase_order_number" {
+  description = "Purchase order number"
+  type        = string
+  default     = ""
+}
+variable "aside_vd_type" {
+  description = "Virtual Device type - EDGE"
+  type        = string
+  default     = ""
+}
+variable "aside_vd_uuid" {
+  description = "Virtual Device UUID"
+  type        = string
+  default     = ""
+}
+variable "zside_ap_type" {
+  description = "Access point type - COLO, VD, VG, SP, IGW, SUBNET, GW"
+  type        = string
+}
+variable "zside_ap_profile_type" {
+  description = "Service profile type - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE"
+  type        = string
+}
+variable "zside_location" {
+  description = "Access point metro code"
+  type        = string
+}
+variable "zside_sp_name" {
+  description = "Equinix Service Profile Name"
+  type        = string
+}
+variable "zside_peering_type" {
+  description = "Zside Access Point Peering type. Available values; PRIVATE, MICROSOFT, PUBLIC, MANUAL"
+  type        = string
+}
diff --git a/examples/virtual-device-2-azure-connection/versions.tf b/examples/virtual-device-2-azure-connection/versions.tf
new file mode 100644
index 00000000..63fdff35
--- /dev/null
+++ b/examples/virtual-device-2-azure-connection/versions.tf
@@ -0,0 +1,13 @@
+terraform {
+  required_version = ">= 1.5.2"
+  required_providers {
+    equinix = {
+      source  = "equinix/equinix"
+      version = ">= 1.20.0"
+    }
+    azurerm = {
+      source = "hashicorp/azurerm"
+      version = "3.84.0"
+    }
+  }
+}
diff --git a/modules/virtual-device-connection/README.md b/modules/virtual-device-connection/README.md
new file mode 100644
index 00000000..e69de29b
diff --git a/modules/virtual-device-connection/main.tf b/modules/virtual-device-connection/main.tf
new file mode 100644
index 00000000..6036f64b
--- /dev/null
+++ b/modules/virtual-device-connection/main.tf
@@ -0,0 +1,177 @@
+data "equinix_fabric_service_profiles" "zside_sp" {
+  count = var.zside_ap_type == "SP" ? 1 : 0
+  filter {
+    property = "/name"
+    operator = "="
+    values   = [var.zside_sp_name]
+  }
+}
+data "equinix_fabric_ports" "zside_port" {
+  count = var.zside_ap_type == "COLO" ? 1 : 0
+  filters {
+    name = var.zside_port_name
+  }
+}
+resource "equinix_fabric_connection" "virtual_device_connection" {
+  name = var.connection_name
+  type = var.connection_type
+  notifications {
+    type   = var.notifications_type
+    emails = var.notifications_emails
+  }
+  bandwidth = var.bandwidth
+  redundancy { priority = "PRIMARY" }
+  order {
+    purchase_order_number = var.purchase_order_number != "" ? var.purchase_order_number : null
+  }
+  additional_info = var.additional_info != [] ? var.additional_info : null
+
+  a_side {
+    access_point {
+      type = "VD"
+      virtual_device {
+        type = var.aside_vd_type
+        uuid = var.aside_vd_uuid
+      }
+      interface {
+        type = var.aside_interface_type != "" ? var.aside_interface_type : null
+        id   = var.aside_interface_id != "" ? var.aside_interface_id : null
+      }
+    }
+  }
+
+  dynamic "z_side" {
+    # Port Z_Side Type
+    for_each = var.zside_ap_type == "COLO" ? [1] : []
+    content {
+      access_point {
+        type = var.zside_ap_type
+        port {
+          uuid = data.equinix_fabric_ports.zside_port[0].data.0.uuid
+        }
+        link_protocol {
+          type       = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type
+          vlan_tag   = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "DOT1Q" ? var.zside_vlan_tag : null
+          vlan_s_tag = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "QINQ" ? var.zside_vlan_tag : null
+          vlan_c_tag = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "QINQ" && one(data.equinix_fabric_ports.aside_port.data.0.encapsulation).type != "QINQ" ? var.zside_vlan_inner_tag : null
+        }
+        location {
+          metro_code = var.zside_location
+        }
+      }
+    }
+  }
+
+  dynamic "z_side" {
+    # Service Profile Z_Side Type
+    for_each = var.zside_ap_type == "SP" ? [1] : []
+    content {
+      access_point {
+        type   = var.zside_ap_type
+        authentication_key = var.zside_ap_authentication_key
+        seller_region      = var.zside_seller_region != "" ? var.zside_seller_region : null
+        profile{
+          type = var.zside_ap_profile_type
+          uuid = data.equinix_fabric_service_profiles.zside_sp[0].data.0.uuid
+        }
+        location {
+          metro_code = var.zside_location
+        }
+        peering_type = var.zside_peering_type != "" ? var.zside_peering_type : null
+      }
+    }
+  }
+
+  dynamic "z_side" {
+    #Service Token Zside Type
+    for_each = var.zside_service_token_uuid != "" ? [1] : []
+    content {
+      service_token {
+        uuid = var.zside_service_token_uuid
+      }
+    }
+  }
+}
+
+resource "equinix_fabric_connection" "secondary_virtual_device_connection" {
+  count = var.secondary_connection_name != "" ? 1 : 0
+
+  name  = var.secondary_connection_name
+  type  = var.connection_type
+  notifications {
+    type   = var.notifications_type
+    emails = var.notifications_emails
+  }
+  bandwidth = var.secondary_bandwidth
+  order {
+    purchase_order_number = var.purchase_order_number != "" ? var.purchase_order_number : null
+  }
+
+  additional_info = var.additional_info != [] ? var.additional_info : null
+
+  a_side {
+    access_point {
+      type = "VD"
+      virtual_device {
+        type = var.aside_vd_type
+        uuid = var.aside_vd_uuid
+      }
+      interface {
+        type = var.aside_interface_type != "" ? var.aside_interface_type : null
+        id   = var.aside_interface_id != "" ? var.aside_interface_id : null
+      }
+    }
+  }
+  dynamic "z_side" {
+    # Service Profile Z_Side Type
+    for_each = var.zside_ap_type == "SP" ? [1] : []
+    content {
+      access_point {
+        type               = var.zside_ap_type
+        authentication_key = var.zside_ap_authentication_key
+        seller_region      = var.zside_seller_region
+        profile {
+          type = var.zside_ap_profile_type
+          uuid = data.equinix_fabric_service_profiles.zside_sp[0].data.0.uuid
+        }
+        location {
+          metro_code = var.zside_location
+        }
+        peering_type = var.zside_peering_type != "" ? var.zside_peering_type : null
+      }
+    }
+  }
+
+  dynamic "z_side" {
+    # Port Z_Side Type
+    for_each = var.zside_ap_type == "COLO" ? [1] : []
+    content {
+      access_point {
+        type = var.zside_ap_type
+        port {
+          uuid = data.equinix_fabric_ports.zside_port[0].data.0.uuid
+        }
+        link_protocol {
+          type       = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type
+          vlan_tag   = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "DOT1Q" ? var.zside_vlan_tag : null
+          vlan_s_tag = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "QINQ" ? var.zside_vlan_tag : null
+          vlan_c_tag = one(data.equinix_fabric_ports.zside_port[0].data.0.encapsulation).type == "QINQ" && one(data.equinix_fabric_ports.aside_port.data.0.encapsulation).type != "QINQ" ? var.zside_vlan_inner_tag : null
+        }
+        location {
+          metro_code = var.zside_location
+        }
+      }
+    }
+  }
+
+  dynamic "z_side" {
+    #Service Token Zside Type
+    for_each = var.zside_service_token_uuid != "" ? [1] : []
+    content {
+      service_token {
+        uuid = var.zside_service_token_uuid
+      }
+    }
+  }
+
+}
diff --git a/modules/virtual-device-connection/outputs.tf b/modules/virtual-device-connection/outputs.tf
new file mode 100644
index 00000000..5caf1164
--- /dev/null
+++ b/modules/virtual-device-connection/outputs.tf
@@ -0,0 +1,6 @@
+output "primary_connection_id" {
+  value = equinix_fabric_connection.virtual_device_connection.id
+}
+output "secondary_connection_id" {
+  value = var.secondary_connection_name != "" ? equinix_fabric_connection.secondary_virtual_device_connection[0].id : null
+}
diff --git a/modules/virtual-device-connection/variables.tf b/modules/virtual-device-connection/variables.tf
new file mode 100644
index 00000000..a850e7fa
--- /dev/null
+++ b/modules/virtual-device-connection/variables.tf
@@ -0,0 +1,116 @@
+variable "connection_name" {
+  description = "Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores"
+  type        = string
+}
+variable "secondary_connection_name" {
+  description = "Secondary Connection name. An alpha-numeric 24 characters string which can include only hyphens and underscores"
+  type        = string
+  default     = ""
+}
+variable "connection_type" {
+  description = "Defines the connection type like VG_VC, EVPL_VC, EPL_VC, EC_VC, IP_VC, ACCESS_EPL_VC"
+  type        = string
+}
+variable "notifications_type" {
+  description = "Notification Type - ALL is the only type currently supported"
+  type        = string
+  default     = "ALL"
+}
+variable "notifications_emails" {
+  description = "Array of contact emails"
+  type        = list(string)
+}
+variable "bandwidth" {
+  description = "Connection bandwidth in Mbps"
+  type        = number
+}
+variable "secondary_bandwidth" {
+  description = "Connection bandwidth in Mbps"
+  type        = number
+  default     = 0
+}
+variable "purchase_order_number" {
+  description = "Purchase order number"
+  type        = string
+  default     = ""
+}
+variable "aside_vd_type" {
+  description = "Virtual Device type - EDGE"
+  type        = string
+  default     = ""
+}
+variable "aside_vd_uuid" {
+  description = "Virtual Device UUID"
+  type        = string
+  default     = ""
+}
+variable "aside_interface_type" {
+  description = "Virtual Device Interface type - CLOUD, NETWORK"
+  type        = string
+  default     = ""
+}
+variable "aside_interface_id" {
+  description = "Interface Id"
+  type        = number
+  default     = null
+}
+variable "zside_ap_type" {
+  description = "Access point type - VD, SP, COLO, CLOUD_ROUTER, NETWORK"
+  type        = string
+  default     = ""
+}
+variable "zside_ap_authentication_key" {
+  description = "Authentication key for provider based connections"
+  type        = string
+  default     = ""
+}
+variable "zside_ap_profile_type" {
+  description = "Service profile type - L2_PROFILE, L3_PROFILE, ECIA_PROFILE, ECMC_PROFILE"
+  type        = string
+  default     = ""
+}
+variable "zside_location" {
+  description = "Access point metro code"
+  type        = string
+  default     = ""
+}
+variable "zside_sp_name" {
+  description = "Equinix Service Profile Name"
+  type        = string
+  default     = ""
+}
+variable "zside_port_name" {
+  description = "Equinix Z-Side Port Name"
+  type        = string
+  default     = ""
+}
+variable "zside_seller_region" {
+  description = "Access point seller region"
+  type        = string
+  default     = ""
+}
+variable "zside_vlan_tag" {
+  description = "VLan Tag information for DOT1Q connections, and the outer VLan tag for QINQ connections"
+  type        = string
+  default     = ""
+}
+variable "zside_vlan_inner_tag" {
+  description = "Inner VLan tag for QINQ connections"
+  type        = string
+  default     = ""
+}
+variable "zside_peering_type" {
+  description = "Zside Access Point Peering type. Available values; PRIVATE, MICROSOFT, PUBLIC, MANUAL"
+  type        = string
+  default     = ""
+}
+variable "zside_service_token_uuid" {
+  description = "Service Token UUID"
+  type        = string
+  default     = ""
+}
+variable "additional_info" {
+  description = "Additional info parameters. It's a list of maps containing 'key' and 'value' keys with their corresponding values."
+  type        = list(object({ key = string, value = string }))
+  default     = []
+}
diff --git a/modules/virtual-device-connection/versions.tf b/modules/virtual-device-connection/versions.tf
new file mode 100644
index 00000000..8e226867
--- /dev/null
+++ b/modules/virtual-device-connection/versions.tf
@@ -0,0 +1,9 @@
+terraform {
+  required_version = ">= 1.5.4"
+  required_providers {
+    equinix = {
+      source  = "equinix/equinix"
+      version = ">= 1.20.0"
+    }
+  }
+}