gcd.adv

think "Greatest common divisor"
e
take shovel
dig with shovel
dig with shovel
e 
ne
n
take pen from backpack
take backpack
n
n
n
n
n
n
w
open cupboard
take pan
put dirt into pan
drop pan
put dirt into backpack
e
s
w
open cabinet
take parchment from folder from cabinet
take folder from cabinet
e
s

put parchment into shredder

take first parchment from shredder
call last in me "TESTB"
erase TESTB
write with pen on TESTB "think TESTB"
write with pen on TESTB "take all from scale"
write with pen on TESTB "put A onto scale"
write with pen on TESTB "put B onto scale"
write with pen on TESTB "call first in scale A"
write with pen on TESTB "call last in scale B"
write with pen on TESTB "take A"
write with pen on TESTB "put backpack onto scale"
write with pen on TESTB "take parchment from A"
write with pen on TESTB "take parchment from B"
write with pen on TESTB "take parchment from backpack"
write with pen on TESTB "put DIVIDE into B"
write with pen on TESTB "obey parchment in first in scale"

take first parchment from shredder
call last in me "DIVIDE"
erase DIVIDE
write with pen on DIVIDE "think DIVIDE"
write with pen on DIVIDE "take dirt from folder"
write with pen on DIVIDE "put dirt into B"
write with pen on DIVIDE "take all from scale"
write with pen on DIVIDE "take parchment from A"
write with pen on DIVIDE "take parchment from B"
write with pen on DIVIDE "take parchment from backpack"
write with pen on DIVIDE "put SUBTRACT into A"
write with pen on DIVIDE "put TESTB into B"
write with pen on DIVIDE "put A onto scale"
write with pen on DIVIDE "put B onto scale"
write with pen on DIVIDE "obey parchment in first in scale"

take first parchment from shredder
call last in me "SUBTRACT"
erase SUBTRACT
write with pen on SUBTRACT "think SUBTRACT"
write with pen on SUBTRACT "dig from B with shovel"
write with pen on SUBTRACT "put dirt into folder"
write with pen on SUBTRACT "dig from A with shovel"
write with pen on SUBTRACT "drop dirt in me"
write with pen on SUBTRACT "take all from scale"
write with pen on SUBTRACT "put B onto scale"
write with pen on SUBTRACT "put backpack onto scale"
write with pen on SUBTRACT "take parchment from A"
write with pen on SUBTRACT "take parchment from B"
write with pen on SUBTRACT "take parchment from backpack"
write with pen on SUBTRACT "put SUBTRACT into B"
write with pen on SUBTRACT "put DIVIDE into backpack"
write with pen on SUBTRACT "obey parchment in first in scale"

drop pen

s
s
e
call first in cauldron A
take A from cauldron
call first in cauldron B
take B from cauldron
se
obey TESTB

think "I've got the result in A. Now to print it out."
nw
w
n
n
e
put A into scale
push button
take label
w
n
e
put label into drain

quit

This implements Euler's algorithm to compute greatest common divisor:

given a, b with a > b
repeat:
  divide a by b
  if remainder == 0:
    GCD is b
  else
    let a = b, b = r

Here's the basic Colossal implementation:

TEST-B:
  sort so A >= B
  B says DIVIDE
  H says DONE

DONE:
  dunk the A

DIVIDE:
  move dirt from T into B
  A says SUBTRACT
  B says TEST-B

SUBTRACT:
  (dig out of B into T, A into nowhere)
  B says SUBTRACT
  H says DIVIDE