Defining top-level mkSubmoduleOptions causes error: infinite recursion encountered

[MrFoxPro]

 {
  options.hosts = mkSubmoduleOptions {
      type = types.attrsOf (
      ...
  };

  config.flake =
    concatMapAttrs (
     ...
    )
    config.hosts;
}

# using it:
hosts = {
  huananzhi = {
    modules = [./hosts/huananzhi/huananzhi.nix];
    ipv4 = {
      address = "192.168.0.11/28";
      gateway = "192.168.0.1";
    };
  };
}; 

This causes aforementioned error, however, wrapping it works as expected:

{
  options.nixos = mkSubmoduleOptions {
    hosts = mkOption {
      type = types.attrsOf (
          ...
      )
    };
  };

  config.flake =
    concatMapAttrs (
    ...
    )
    config.nixos.hosts;
}
# using it:
nixos.hosts = {
  huananzhi = {
    modules = [./hosts/huananzhi/huananzhi.nix];
    ipv4 = {
      address = "192.168.0.11/28";
      gateway = "192.168.0.1";
    };
  };
};

What am I doing wrong here?

[roberth]

  options.hosts = mkSubmoduleOptions {
      type = types.attrsOf (

That looks a bit like you've put a type where an option is expected, or maybe you didn't copy the line in between.

Nothing jumps out to me, so I'd need at least a more complete example and a --show-trace, or ideally an actual flake that exhibits the problem.

[MrFoxPro]

You're probably correct, but, how to make top-level option then?
here is full code

{
  self,
  inputs,
  lib,
  config,
  helpers,
  share,
  ...
}:
with lib;
with builtins; let
  inherit (inputs.flake-parts.lib) mkSubmoduleOptions;
in {
  options.hosts = mkSubmoduleOptions {
      type = types.attrsOf (
        types.submodule ({name, ...}: {
          freeformType = types.attrs;
          options.hostname = mkOption {
            type = types.str;
            default = name;
            readOnly = true;
          };
          options.modules = mkOption {
            type = types.listOf types.anything;
            default = [];
          };
          options.installer = mkOption {
            type = types.nullOr (
              types.submodule ({name, ...}: {
                options.hostname = mkOption {
                  type = types.str;
                  default = "portable-${name}";
                };
              })
            );
            default = {};
          };
          options.node = mkOption {
            # type = types.nullOr (
            #   types.submodule ({name, ...}: {
            #   })
            # );
            type = types.nullOr types.attrs;
            default = null;
          };
        })
      );
      default = {};
  };

  config.flake =
    concatMapAttrs (
      name: host: let
        system = host.system or "x86_64-linux";
        pkgs = helpers.mkPkgs {inherit inputs lib system;};
        specialArgs = {inherit self inputs pkgs lib share;};
      in
        {
          nixosConfigurations.${name} = nixosSystem {
            inherit system specialArgs;
            modules = with inputs;
              [
                home-manager.nixosModules.home-manager
                ragenix.nixosModules.age
                disko.nixosModules.disko
                impermanence.nixosModules.impermanence

                ./presets
              ]
              ++ host.modules;
          };
        }
        // optionalAttrs (host.installer != null) {
          installers."${name}-installer" = inputs.nixos-generators.nixosGenerate {
            inherit specialArgs;
            format = "install-iso";
            modules = [
              ./presets
              {
                networking.hostName = "${name}-installer";
                system.build.targetSystem = self.nixosConfigurations.${name};
              }
              ./hosts/nixon/nixon.nix
            ];
          };
        }
        // optionalAttrs (host.node != null) {}
    )
    config.hosts;
}

[roberth]

Do you really need a submodule? I think you could do:

-  options.hosts = mkSubmoduleOptions {
-      type = types.attrsOf (
+  options.hosts = mkOption {
+      type = types.attrsOf (

I wonder why this line did not give a proper type error, apparently.

type = types.attrsOf (

mkSubmoduleOptions expects a tree of options, as it creates a module from its argument.i

What error did you get?

here is full code

That's a whole file, not a reproducible example.

[MrFoxPro]

@roberth Ooh seems like that's working. So simple! Thank you.

[roberth]

This should help next time NixOS/nixpkgs#242339