mwm.ahk

#Requires AutoHotkey v2
#SingleInstance force
#WinActivateForce
#Warn VarUnset, Off
A_MaxHotkeysPerInterval := 1000
KeyHistory(0), ListLines(false), ProcessSetPriority("H")

#include *i lib\miguru\miguru.ahk
#include *i lib\Popup.ahk

GroupAdd("MIGURU_AUTOFLOAT", "Microsoft Teams-Benachrichtigung" " ahk_exe Teams.exe"                                                  )
GroupAdd("MIGURU_AUTOFLOAT", "Microsoft Teams-Notification"     " ahk_exe Teams.exe"                                                  )
GroupAdd("MIGURU_AUTOFLOAT",                                    " ahk_exe QuickLook.exe"                                              )
GroupAdd("MIGURU_AUTOFLOAT",                                    " ahk_exe outlook.exe"              " ahk_class MsoSplash"            )
GroupAdd("MIGURU_AUTOFLOAT",                                    " ahk_exe explorer.exe"             " ahk_class OperationStatusWindow")
GroupAdd("MIGURU_AUTOFLOAT",                                    " ahk_exe taskmgr.exe"                                                )
GroupAdd("MIGURU_AUTOFLOAT", "Calculator"                       " ahk_exe ApplicationFrameHost.exe"                                   )
GroupAdd("MIGURU_AUTOFLOAT",                                    " ahk_exe zeal.exe"                                                   )
GroupAdd("MIGURU_AUTOFLOAT", "Window Spy for AHKv2"                                                                                   )
GroupAdd("MIGURU_AUTOFLOAT", "WinMerge"                                                                                               )

GroupAdd("MIGURU_DECOLESS",                                     " ahk_exe qutebrowser.exe"                                            )
GroupAdd("MIGURU_DECOLESS",                                     " ahk_exe alacritty.exe"                                              )
GroupAdd("MIGURU_DECOLESS",                                     " ahk_exe msrdc.exe"                " ahk_class RAIL_WINDOW"          )

GroupAdd("MIGURU_IGNORE",                                       " ahk_exe msrdc.exe"                                                  )
GroupAdd("MIGURU_IGNORE",    "WinUI Desktop"                    " ahk_exe PowerToys.Peek.UI.exe"    " ahk_class WinUIDesktopWin32WindowClass")

if !IsSet(MiguruWM) {
    prog := RegExReplace(A_ScriptName, "i)\.ahk$", ".exe")
    if FileExist(prog) {
        Run(prog)
    }
    ExitApp()
}

layouts := [
    TallLayout(),
    WideLayout(),
    FullscreenLayout(),
    FloatingLayout(),
    ColumnLayout(),
    RowLayout(),
    ThreeColumnLayout(),
    TwoPaneLayout(),
    SpiralLayout(),
]

mwm := { __Call: (name, params*) => } ; Ignore requests while mwm isn't ready yet
mwm := MiguruWM({
    layout: layouts[1],
    showPopup: (text, opts) => Popup(text, ObjMerge({
        duration: 500,
        showIcon: true,
    }, opts)),
    focusIndicator: HazeOver(),
    ;; …see https://github.com/imawizard/MiguruWM/wiki/Configuration
})

MiguruWM.SetupTrayMenu()

; Use Alt as modifier but disable it if pressed alone
mod1 := "Alt"
Alt::return

; Keybindings .............................................................{{{1

#Hotif GetKeyState(mod1, "P") and !GetKeyState("Shift", "P")

*1::mwm.Do("focus-workspace", { workspace: 1 })
*2::mwm.Do("focus-workspace", { workspace: 2 })
*3::mwm.Do("focus-workspace", { workspace: 3 })
*4::mwm.Do("focus-workspace", { workspace: 4 })
*5::mwm.Do("focus-workspace", { workspace: 5 })
*6::mwm.Do("focus-workspace", { workspace: 6 })
*7::mwm.Do("focus-workspace", { workspace: 7 })
*8::mwm.Do("focus-workspace", { workspace: 8 })
*9::mwm.Do("focus-workspace", { workspace: 9 })

*w::mwm.Do("focus-monitor", { monitor: 1 })
*e::mwm.Do("focus-monitor", { monitor: 2 })
*r::mwm.Do("focus-monitor", { monitor: 3 })

*j::mwm.Do("focus-window", { target: "next"     })
*k::mwm.Do("focus-window", { target: "previous" })
*m::mwm.Do("focus-window", { target: "master" })

*l::mwm.Set("master-size", { delta:  0.025 })
*h::mwm.Set("master-size", { delta: -0.025 })

*,::mwm.Set("master-count", { delta:  1 })
*.::mwm.Set("master-count", { delta: -1 })

*t::mwm.Do("float-window", { value: "toggle" }), mwm.Do("center-window")
*p::OpenSearch()
*q::Reload()

*Enter::mwm.Do("swap-window", { with: "master" })
*Space::mwm.Do("cycle-layout", { value: layouts })

*vk01::MoveActiveWindow()
*vk02::ResizeActiveWindow()

*F1::Logger.ToggleConsole()
*F2::mwm.Do("get-workspace-info")
*F3::mwm.Do("get-monitor-info")

#Hotif GetKeyState(mod1, "P") and GetKeyState("Shift", "P")

*1::mwm.Do("send-to-workspace", { workspace: 1 })
*2::mwm.Do("send-to-workspace", { workspace: 2 })
*3::mwm.Do("send-to-workspace", { workspace: 3 })
*4::mwm.Do("send-to-workspace", { workspace: 4 })
*5::mwm.Do("send-to-workspace", { workspace: 5 })
*6::mwm.Do("send-to-workspace", { workspace: 6 })
*7::mwm.Do("send-to-workspace", { workspace: 7 })
*8::mwm.Do("send-to-workspace", { workspace: 8 })
*9::mwm.Do("send-to-workspace", { workspace: 9 })

*w::mwm.Do("send-to-monitor", { monitor: 1 })
*e::mwm.Do("send-to-monitor", { monitor: 2 })
*r::mwm.Do("send-to-monitor", { monitor: 3 })

*j::mwm.Do("swap-window", { with: "next"     })
*k::mwm.Do("swap-window", { with: "previous" })

*c::try WinClose("A")
*q::ExitApp()

*Enter::OpenTerminal()
*Space::ResetLayout()

; ..........................................................................}}}

; Helper functions ........................................................{{{1

ResetLayout() {
    defaults := mwm.Options

    mwm.Set("layout", { value: defaults.layout })
    mwm.Set("master-size", { value: defaults.masterSize })
    mwm.Set("master-count", { value: defaults.masterCount })
    mwm.Set("padding", { value: defaults.padding })
    mwm.Set("spacing", { value: defaults.spacing })
}

GetSHAppFolderPath(hwnd := 0) {
    if !hwnd {
        hwnd := WinExist("A")
    }
    res := ""
    app := ComObject("Shell.Application")
    for window in app.Windows {
        if window && window.hwnd == hwnd {
            res := window.Document.Folder.Self.Path
            break
        }
    }
    return res
}

OpenTerminal() {
    wd := EnvGet("USERPROFILE")
    if WinGetProcessName("A") == "explorer.exe" {
        path := GetSHAppFolderPath()
        if path && Substr(path, 1, 2) !== "::" {
            wd := path
        }
    }
    Run("wt.exe -d " wd)
}

OpenTaskView() {
    Send("#{Tab}")
}

OpenSearch() {
    Send("#s")
}

ShowDesktop() {
    Send("#d")
}

MoveActiveWindow() {
    MouseGetPos(, , &hwnd)
    if !hwnd {
        return
    }
    WinActivate("ahk_id" hwnd)
    mwm.Do("float-window", { hwnd: hwnd, value: true })
    PostMessage(WM_SYSCOMMAND, SC_MOVE,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYDOWN,    VK_LEFT,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYUP,      VK_LEFT,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYDOWN,    VK_RIGHT, , , "ahk_id" hwnd)
    PostMessage(WM_KEYUP,      VK_RIGHT, , , "ahk_id" hwnd)
    KeyWait("vk01")
    Send("{vk01 Up}")
}

ResizeActiveWindow() {
    MouseGetPos(, , &hwnd)
    if !hwnd {
        return
    }
    WinActivate("ahk_id" hwnd)
    mwm.Do("float-window", { hwnd: hwnd, value: true })
    PostMessage(WM_SYSCOMMAND, SC_SIZE,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYDOWN,    VK_DOWN,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYUP,      VK_DOWN,  , , "ahk_id" hwnd)
    PostMessage(WM_KEYDOWN,    VK_RIGHT, , , "ahk_id" hwnd)
    PostMessage(WM_KEYUP,      VK_RIGHT, , , "ahk_id" hwnd)
    KeyWait("vk02")
    Send("{vk01 Up}")
}

; ..........................................................................}}}