maven-publish.gradle

apply plugin: "maven-publish"
apply plugin: "signing"

task javadocsJar(type: Jar, dependsOn: "dokkaJavadoc") {
    getArchiveClassifier().set("javadoc")
    from dokkaJavadoc.outputDirectory
}

task sourcesJar(type: Jar) {
    getArchiveClassifier().set("sources")
    from sourceSets.main.allJava
}

afterEvaluate {
    publishing {
        def properties = project.ext.mavenPublishProperties

        repositories {
            maven {
                name "SonatypeMavenCentral"
                url properties.repository.url
                credentials {
                    username properties.repository.username
                    password properties.repository.password
                }
            }
        }
        publications {
            release(MavenPublication) {
                from components.java

                groupId = properties.group
                version = properties.version
                artifactId = properties.artifactId

                artifact sourcesJar
                artifact javadocsJar

                pom {
                    name = properties.name
                    description = properties.description
                    url = properties.url
                    licenses {
                        license {
                            name = 'The Apache License, Version 2.0'
                            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }
                    developers {
                        developer {
                            id = 'stjepanbanek'
                            name = 'Stjepan Banek'
                            email = 'stjepan.banek@infinum.com'
                        }
                        developer {
                            id = 'nikolagobovic'
                            name = 'Nikola Gobovic'
                            email = 'nikola.gobovic@infinum.com'
                        }
                        developer {
                            id = 'thisAAY'
                            name = 'Ahmed Ali'
                            email = 'ahmedali.abdelghany.yousef@infinum.com'
                        }

                        developer {
                            id = 'DrakslerT'
                            name = 'Tim Draksler'
                            email = 'tim.draksler@infinum.com'
                        }
                    }
                    scm {
                        connection.set(properties.scm.connection)
                        developerConnection.set(properties.scm.connection)
                        url.set(properties.scm.url)
                    }
                }
                signing {
                    sign publishing.publications.release
                }
            }
        }
    }
}