build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.61'
    id "com.jfrog.bintray" version "1.8.5"
    id "maven-publish"
    id 'java-library'
}

group = "com.ing.dlt"
version '1.0.12'

repositories {
    mavenCentral()
    maven { url "https://dl.bintray.com/ethereum/maven/" }
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    implementation "org.bouncycastle:bcprov-jdk15on:1.66"
    testImplementation 'org.junit.jupiter:junit-jupiter:5.6.0'
}

test {
    useJUnitPlatform()
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

java {
    withSourcesJar()
    withJavadocJar()
}


// Bintray publishing
bintray {
    user = System.getenv('BINTRAY_USER')
    key = System.getenv('BINTRAY_KEY')
    publications = ['MyPublication']
    publish = true

    pkg {
        repo = 'zkkrypto'
        name = project.name
        licenses = ['Apache-2.0']
        vcsUrl = 'https://github.com/ing-bank/zkkrypto.git'

        version {
            name = project.version
            released = new Date()
            vcsTag = project.version
        }
    }
}

publishing {
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId = project.group
            artifactId = project.archivesBaseName
            version = project.version
        }
    }
}