PMASIAUJ - Section 3.5, Exercise 5 question

[mindcrime]

Jason team:

I have implemented exercise 5 from Section 3.5 in "Programming Multi-agent Systems in AgentSpeak Using Jason" and my solution works fine. But I was just wondering if what I did is considered correct/idiomatic in the Jason/Agentspeak world, and/or if there are better solutions. If anybody can share any comments on the merits of this solution, and any better alternatives it would be much appreciated.

supermarket1.asl

beer_price(30).

started.

+started <- 
    ?beer_price(Bp);
    .print( "Beer price: ", Bp );
    .send(robot, tell, price(beer, Bp)).

... rest elided

supermarket2.asl

beer_price(21).

started.

+started <- 
    ?beer_price(Bp);
    .print( "Beer price: ", Bp );
    .send(robot, tell, price(beer, Bp)).

... rest elided

robot.asl

/* rule to pick which market has the cheapest beer */
cheapest_beer(Ag1, Ag2) :-
     price(beer, N1)[source(Ag1)] & price(beer, N2)[source(Ag2)] & N1 < N2.

/* two separate plans with two different context tests to see which beer market is cheapest. */
@h2a
+!has(owner,beer) : not available(beer,fridge) & cheapest_beer( supermarket, supermarket2) <- .print( "Ordering more beer from supermarket"); 

    .send( supermarket, achieve, order(beer,5));
    !at(robot,fridge). // go to fridge and wait there

@h2b
+!has(owner,beer) : not available(beer,fridge) & cheapest_beer( supermarket2, supermarket) <- .print( "Ordering more beer from supermarket2"); 
    .send( supermarket2, achieve, order(beer,5));
    !at(robot,fridge). // go to fridge and wait there

This works as expected, based on what values I plug in for beer_price in the respective supermarket definitions.

output

[Env] executing: sip(beer)
[Env] executing: sip(beer)
[owner] I'm out of beer!!
[robot] Ordering more beer from supermarket2
[supermarket2] received order from robot

My biggest qualm about this is that it uses the two separate plan triggers and is hard-coded to deal with exactly two markets. I feel like there is probably a much cleaner solution that can easily accommodate an arbitrary number of markets, and maybe a way to do all of this without the redundant plan triggers. But I don't see that better solution at first blush. Any tips would be greatly appreciated.

[jomifred]

your solution looks very good for me. I do like your inference rule for best price, exploiting backtracking.

for the plans, I guess you can keep just the h2a replacing supermarket by S and supermarket2 by _

[jomifred]

and for a generic cheapest rule, a first draft could be

cheapest_beer(Ag,N1) :-
     price(beer, N1)[source(Ag)] & not (price(beer, N2)[source(_)] & N2 < N1).

[jomifred]

although this code is short, its complexity is O(n^2), where n is the number of sources of beliefs price/2. A faster solution (O(n)) can be written using internal actions .min and .findall.

[mindcrime]

Ah. Yeah, that makes sense. Thanks for the tip!