Dealing with Both Deno and Node Projects

[yvesnrb]

If you work with both Deno and Node projects, you'll need to use either the typescript-language-server or the deno lsp with the js-mode and typescript-mode major modes depending on your project. Here is a pain free way to manage this using project.el:

First, configure the Deno language server:

(defclass eglot-deno (eglot-lsp-server) ()
  :documentation "A custom class for deno lsp.")

(cl-defmethod eglot-initialization-options ((server eglot-deno))
  "Passes through required deno initialization options"
  (list :enable t
	:lint t)))

Define a couple functions to determine the type of the current project:

(defun deno-project-p ()
  "Predicate for determining if the open project is a Deno one."
  (let ((p-root (cdr (project-current))))
    (file-exists-p (concat p-root "deno.json"))))

(defun node-project-p ()
  "Predicate for determining if the open project is a Node one."
  (let ((p-root (cdr (project-current))))
    (file-exists-p (concat p-root "package.json"))))

Define a function to determine the correct CONTACT for buffers of js-mode and typescript-mode:

(defun es-server-program (_)
  "Decide which server to use for ECMA Script based on project characteristics."
  (cond ((deno-project-p) '(eglot-deno "deno" "lsp"))
	((node-project-p) '("typescript-language-server" "--stdio"))
	(t                nil)))

Notice that it defaults to nil if the project has neither a package.json or a deno.json file. I prefer to not have any LSP when I'm editing free floating JS/TS files. Customize to taste.

Add this function to the eglot-server-programs list:

(add-to-list 'eglot-server-programs '((js-mode typescript-mode) . es-server-program))

[joaotavora]

I think nowadays you can further simplify your recipe: from the NEWS of the unreleased upcoming version of Eglot:

##### Easier to use LSP initialize.initializationOptions ([#901][github#901], [#845][github#845])
In `eglot-server-programs` a plist may be appended to the usual list
of strings passed as command line arguments.  The value of its
`:initializationOptions` key constructs the corresponding LSP JSON
object.  This may be easier than creating a `defclass` for a specific
server and specializing `eglot-initialization-options` to that class.

[yvesnrb]

Very cool, I do prefer this method over the CLOS class thing. Thanks for letting me know!

[rumboon]

I just wanted to add this for documentation since this thread helped me figure out how to deal with having both nodejs and deno projects having their respective lsp servers.

Without checking if the project is a deno or nodejs project I added an alternative lsp server for the typescript-ts-mode. So when one is not available use the alternative. This solution also works for me in monorepo's as well.

(with-eval-after-load 'eglot
  (add-to-list
   'eglot-server-programs
   `(typescript-ts-mode . ,(eglot-alternatives
                            '(("typescript-language-server" "--stdio")
                              ("deno" "lsp"))))))