build.gradle

plugins {
    id 'org.springframework.boot' version '2.2.6.RELEASE'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'org.sonarqube' version '2.8'
    id 'maven-publish'
    id 'jacoco'
    id 'java'
}

group = 'cloud.klasse'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '14'

publishing {
    publications {
        bootJava(MavenPublication) {
            artifact bootJar
        }
    }
    repositories {
        maven {
            url = "https://arts.build.ricksha.dev/artifactory/gradle-dev-local"
            credentials {
                username "${artifactory_user}"
                password "${artifactory_password}"
            }
        }
    }
}

repositories {
    maven {
        url = "https://arts.build.ricksha.dev/artifactory/gradle-dev"
        credentials {
            username "${artifactory_user}"
            password "${artifactory_password}"
        }
    }
    mavenCentral()
}

configurations {
    developmentOnly
    runtimeClasspath {
        extendsFrom developmentOnly
    }
    compileOnly {
        extendsFrom annotationProcessor
    }
}

dependencies {
//    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-rest'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-web'

    implementation 'io.jsonwebtoken:jjwt-api:0.11.1'
    implementation 'io.jsonwebtoken:jjwt-impl:0.11.1'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.11.1'

    implementation 'com.google.zxing:javase:3.4.0'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'com.h2database:h2'
    runtimeOnly 'org.postgresql:postgresql'
    annotationProcessor 'org.projectlombok:lombok'
    testCompile "org.mockito:mockito-junit-jupiter:3.1.0"
    testImplementation 'org.assertj:assertj-core:3.15.0'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }
    // https://mvnrepository.com/artifact/org.springdoc/springdoc-openapi-ui
    compile group: 'org.springdoc', name: 'springdoc-openapi-ui', version: '1.3.4'
    // https://mvnrepository.com/artifact/org.springdoc/springdoc-openapi-data-rest
    compile group: 'org.springdoc', name: 'springdoc-openapi-data-rest', version: '1.3.4'
}

sonarqube {
    properties {
        property 'sonar.coverage.jacoco.xmlReportPaths', 'build/reports/jacoco/test/jacocoTestReport.xml'
    }
}

jacocoTestReport {
    reports {
        xml.enabled true
        csv.enabled false
        html.enabled false
    }
}

test.finalizedBy jacocoTestReport

test {
    useJUnitPlatform()
    reports.junitXml.enabled = true
}

task projectName {
    doLast {
        println project.name
    }
}

task projectVersion {
    doLast {
        println project.version
    }
}