build.gradle

group 'com.shankyank.gradle'
version '0.5'

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'idea'
apply plugin: 'eclipse'

if (file('deploy.gradle')) {
    apply from: 'deploy.gradle'
}

repositories {
    mavenCentral()
    jcenter()
}

publishing {
    publications {
        plugin(MavenPublication) {
            from components.java
            artifact sourceJar
            artifact javadocJar
        }
    }
}

dependencies {
    compile gradleApi()
    compile localGroovy()
    compile 'com.amazonaws:aws-java-sdk-api-gateway:1.10.+'
    compile 'io.swagger:swagger-core:1.5.+'
    compile 'io.swagger:swagger-parser:1.0.+'
    compile 'com.github.fge:json-schema-validator:2.2.+'
}

task sourceJar(type: Jar, dependsOn: classes) {
    classifier = 'src'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives jar
    archives sourceJar
    archives javadocJar
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

eclipse {
    classpath {
        downloadJavadoc = true
        downloadSources = true
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.8'
}