-
Notifications
You must be signed in to change notification settings - Fork 1
/
cezinho-parser.y
287 lines (250 loc) · 8.95 KB
/
cezinho-parser.y
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
%{
/*
*
* Created by Murilo Adriano Vasconcelos || Matrícula : 094816
* & Paulo Cezar Pereira Costa || Matrícula : 080153
*
* Copyright 2011 Universidade Federal de Goias. All rights reserved.
*
*/
#include <cstdio>
#include <cstdlib>
#include <string>
#include <cstring>
#include "ast/ast.h"
#define TRACE printf("reduce at line %d\n", __LINE__);
extern int yylex(void);
void yyerror(const char* s);
void yyerror(const char* s, int err_line);
extern int yylineno;
extern FILE* yyin;
std::string cz_new_line = "\n";
ASTNode* root;
%}
%union {
ASTNode* node;
DataType datatype;
Op oper;
std::string* lxval;
}
%token<lxval> MAIN
%token INT
%token CHAR
%token RETURN
%token READ
%token WRITE
%token WRITELN
%token BREAK
%token IF
%token ELSE
%token WHILE
%token<lxval> ID
%token<lxval> LITINT
%token<lxval> LITCHAR
%token<lxval> LITSTRING
%right '='
%left OR
%left AND
%nonassoc EQUAL NEQUAL
%nonassoc '<' '>' LESSEQ GREATEREQ
%left '+' '-'
%left '*' '/'
%type<datatype> Type
%type<oper> UnaryOp
%type<node> Program Decls VarDecl FuncDecl ParamDecList Block VarDeclList StmtList Stmt Expr BinaryExpr UnaryExpr PostFixExpr ArgumentList Constant
%start Program
%%
Program:
Decls {
root = $1;
root->reverse();
scope_lvl = 0;
var_symbol_tab.clear();
func_symbol_tab.clear();
while(!declared.empty()) declared.pop();
root->walk(0);
}
;
Decls:
Type VarDecl ';' Decls {
$$ = $4;
static_cast<VarDecl*>($2)->setDataType($1);
$$->add( $2 );
$$->set_location(yylineno);
}
| Type ID FuncDecl Decls {
$$ = $4;
static_cast<FuncDecl*>($3)->setFuncName($2);
static_cast<FuncDecl*>($3)->setDataType($1);
$$->add( $3 );
$$->set_location( yylineno );
}
| Type MAIN FuncDecl {
$$ = new ASTNode();
static_cast<FuncDecl*>($3)->setFuncName( $2 );
static_cast<FuncDecl*>($3)->setDataType( $1 );
$$->add( $3 );
$$->set_location( yylineno );
}
;
VarDecl:
ID {
$$ = new VarDecl();
$$->add( new DeclIdentifier($1) );
$$->set_location( yylineno );
}
| ID '[' Constant ']' {
$$ = new VarDecl();
$$->add( new DeclIdentifier($1, $3) );
$$->set_location( yylineno );
}
| VarDecl ',' ID {
$$ = $1;
$$->add( new DeclIdentifier($3) );
$$->set_location( yylineno );
}
| VarDecl ',' ID '[' Constant ']' {
$$ = $1;
$$->add( new DeclIdentifier($3, $5) );
$$->set_location( yylineno );
}
;
FuncDecl:
'(' ParamDecList ')' Block { $$ = new FuncDecl( $2, $4 ); $$->set_location( yylineno ); }
| '(' ')' Block { $$ = new FuncDecl( NULL, $3 ); $$->set_location( yylineno ); }
;
ParamDecList:
Type ID {
$$ = new ParamList();
$$->add( new Param( $1, $2 ) );
$$->set_location( yylineno );
}
| Type ID '[' ']' {
$$ = new ParamList();
$$->add( new Param( ($1==INT_T)?INT_ARRAY_T:CHAR_ARRAY_T, $2 ) );
$$->set_location( yylineno );
}
| ParamDecList ',' Type ID { $$ = $1; $$->add( new Param( $3, $4 ) ); $$->set_location( yylineno ); }
| ParamDecList ',' Type ID '[' ']' {
$$ = $1;
$$->add( new Param( ($3==INT_T)?INT_ARRAY_T:CHAR_ARRAY_T, $4 ) );
$$->set_location( yylineno );
}
;
Block:
'{' VarDeclList StmtList '}' {
$$ = new Block( static_cast<VarDeclList*>($2), static_cast<StatementList*>($3) );
$$->set_location( yylineno );
}
| '{' VarDeclList '}' {
$$ = new Block( static_cast<VarDeclList*>($2) );
$$->set_location( yylineno );
}
| '{' StmtList '}' { $$ = new Block( static_cast<StatementList*>($2) );
$$->set_location( yylineno );
}
;
VarDeclList:
Type VarDecl ';' {
$$ = new VarDeclList();
static_cast<VarDecl*>($2)->setDataType($1);
$$->add($2);
$$->set_location( yylineno );
}
| VarDeclList Type VarDecl ';' {
$$ = $1;
static_cast<VarDecl*>($3)->setDataType($2);
$$->add( $3 );
$$->set_location( yylineno );
}
;
Type:
INT { $$ = INT_T; }
| CHAR { $$ = CHAR_T; }
;
StmtList:
Stmt { $$ = new StatementList(); $$->add( $1 ); $$->set_location( yylineno ); }
| StmtList Stmt { $$ = $1; $$->add( $2 ); $$->set_location( yylineno ); }
;
Stmt:
';' { $$ = new Statement(); $$->set_location( yylineno ); }
| Expr ';' { $$ = $1; }
| RETURN Expr ';' { $$ = new Return( $2 ); $$->set_location( yylineno ); }
| READ ID ';' { $$ = new Read( new Identifier( $2 ) ); $$->set_location( yylineno ); }
| READ ID '[' Expr ']' ';' { $$ = new Read( new Identifier( $2, $4) ); $$->set_location( yylineno ); }
| WRITE Expr ';' { $$ = new Write( $2 ); $$->set_location( yylineno ); }
| WRITELN ';' {
$$ = new Write( new ConstExpr( CHAR_ARRAY_T, &cz_new_line ) );
$$->set_location( yylineno );
}
| BREAK ';' { $$ = new Break(); $$->set_location( yylineno ); }
| IF '(' Expr ')' Stmt { $$ = new If( $3, $5 ); $$->set_location( yylineno ); }
| IF '(' Expr ')' Stmt ELSE Stmt { $$ = new If( $3, $5, $7 ); $$->set_location( yylineno ); }
| WHILE '(' Expr ')' Stmt { $$ = new While( $3, $5 ); $$->set_location( yylineno ); }
| Block { $$ = $1; }
;
Expr:
UnaryExpr '=' Expr {
Identifier* aux = dynamic_cast<Identifier*>($1);
if( aux == NULL ) yyerror( "Lado esquerdo de uma atribuicao deve ser um identificador." );
else $$ = new Assignment(aux, $3);
$$->set_location( yylineno );
}
| BinaryExpr { $$ = $1; }
;
BinaryExpr:
BinaryExpr '+' BinaryExpr { $$ = new BinaryExpr( PLUS, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr '-' BinaryExpr { $$ = new BinaryExpr( MINUS, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr '*' BinaryExpr { $$ = new BinaryExpr( TIMES, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr '/' BinaryExpr { $$ = new BinaryExpr( DIVIDES, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr '<' BinaryExpr { $$ = new BinaryExpr( LESS, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr '>' BinaryExpr { $$ = new BinaryExpr( GREATER, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr EQUAL BinaryExpr { $$ = new BinaryExpr( EQUALS, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr NEQUAL BinaryExpr { $$ = new BinaryExpr( NOT_EQUAL, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr LESSEQ BinaryExpr { $$ = new BinaryExpr( LESS_EQUAL, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr GREATEREQ BinaryExpr { $$ = new BinaryExpr( GREATER_EQUAL, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr OR BinaryExpr { $$ = new BinaryExpr( LOGICAL_OR, $1, $3 ); $$->set_location( yylineno ); }
| BinaryExpr AND BinaryExpr { $$ = new BinaryExpr( LOGICAL_AND, $1, $3 ); $$->set_location( yylineno ); }
| UnaryExpr { $$ = $1; }
;
UnaryExpr:
UnaryOp UnaryExpr { $$ = new UnaryExpr( $1, $2 ); $$->set_location( yylineno ); }
| PostFixExpr { $$ = $1; }
;
PostFixExpr:
ID '(' ArgumentList ')' { $$ = new FuncCall( $1, $3 ); $$->set_location( yylineno ); }
| ID '(' ')' { $$ = new FuncCall( $1 ); $$->set_location( yylineno ); }
| ID { $$ = new Identifier( $1 ); $$->set_location( yylineno ); }
| ID '[' Expr ']' { $$ = new Identifier( $1, $3 ); $$->set_location( yylineno ); }
| Constant { $$ = $1; }
| '(' Expr ')' { $$ = $2; }
;
Constant:
LITINT { $$ = new ConstExpr( INT_T, $1 ); $$->set_location( yylineno ); }
| LITCHAR { $$ = new ConstExpr( CHAR_T, $1 ); $$->set_location( yylineno ); }
| LITSTRING { $$ = new ConstExpr( CHAR_ARRAY_T, $1 ); $$->set_location( yylineno ); }
;
ArgumentList:
Expr { $$ = new ArgList(); $$->add( $1 ); $$->set_location( yylineno ); }
| ArgumentList ',' Expr { $$ = $1; $$->add( $3 ); $$->set_location( yylineno ); }
;
UnaryOp:
'-' { $$ = MINUS; }
| '!' { $$ = NOT; }
;
%%
void yyerror(const char *s) {
fprintf(stderr, "ERRO! Linha: %d - %s\n", yylineno, s );
exit(1);
}
void yyerror(const char *s, int err_line ) {
fprintf(stderr, "ERRO! Proximo a linha: %d - %s\n", err_line, s );
exit(1);
}
int main( int argc, char** argv ){
if( argc > 1 ) yyin = fopen( argv[1], "r" );
else fprintf( stdout, "Nenhum arquivo de entrada especificado.. Fazendo analise da entrada padrao..\n");
yyparse();
fprintf(stdout, "ANALISE SINTATICA OK.\n");
return 0;
}