build.gradle

// Copyright 2018 Google LLC
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

import com.google.firebase.gradle.plugins.license.LicenseResolverPlugin

buildscript {
    ext.kotlinVersion = '1.3.72'
    repositories {
        google()
        jcenter()
        mavenCentral()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        maven {
            url 'https://storage.googleapis.com/android-ci/mvn/'
        }
    }

    dependencies {
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.14'
        classpath 'net.ltgt.gradle:gradle-errorprone-plugin:1.3.0'
        classpath 'gradle.plugin.com.github.sherter.google-java-format:google-java-format-gradle-plugin:0.9'
        classpath 'com.google.gms:google-services:4.3.3'
        classpath 'digital.wup:android-maven-publish:3.6.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath 'org.jlleitschuh.gradle:ktlint-gradle:9.2.1'
    }
}

apply from: 'sdkProperties.gradle'
apply from: "gradle/errorProne.gradle"

ext {
    playServicesVersion = '16.0.1'
    supportAnnotationsVersion = '28.0.0'
    googleTruthVersion = '0.45'
    grpcVersion = '1.41.0'
    robolectricVersion = '4.3.1'
    protocVersion = '3.14.0'
    javaliteVersion = '3.14.0'
}

apply plugin: com.google.firebase.gradle.plugins.publish.PublishingPlugin
apply plugin: com.google.firebase.gradle.plugins.ci.ContinuousIntegrationPlugin
apply plugin: com.google.firebase.gradle.plugins.ci.SmokeTestsPlugin

firebaseContinuousIntegration {
    ignorePaths = [
            /.*\.gitignore$/,
            /.*\/.*.md$/,
    ]
}

// if(JavaVersion.current() != JavaVersion.VERSION_11){
//     throw new GradleException("This build must be run with java 11. You're using ${JavaVersion.current()}.")
// }

configure(subprojects) {
    repositories {
        google()
        jcenter()
        mavenLocal()
        maven {
            url 'https://storage.googleapis.com/android-ci/mvn/'
        }
    }

    apply plugin: "org.jlleitschuh.gradle.ktlint"
}

task clean(type: Delete) {
    delete rootProject.buildDir
}