build.gradle

plugins {
    id 'java'
    id 'application'
    id 'maven-publish'

    // Remove the `maven` plugin when using Gradle >= 7
    id 'maven'
}

repositories {
    mavenCentral()
    mavenLocal()

    maven {
        url "https://maven.restlet.talend.com"
    }
}

description = 'OpenCADC User Storage Interface'
def git_url = 'https://github.com/opencadc/cadc-vosui.git'

sourceCompatibility = '1.8'
group = 'org.opencadc'
version = '1.2.12'

dependencies {
    implementation 'com.opencsv:opencsv:[5.6,6.0)'
    implementation 'commons-fileupload:commons-fileupload:[1.4,1.5)'
    implementation 'org.apache.commons:commons-configuration2:[2.7,3.0)'
    implementation 'org.freemarker:freemarker:[2.3.31,2.4.0)'
    implementation 'org.opencadc:cadc-web-util:[1.2.11,2.0.0)'
    implementation 'org.opencadc:cadc-util:[1.6,2.0.0)'
    implementation 'org.opencadc:cadc-registry:[1.5.15,1.6.0)'
    implementation 'org.opencadc:cadc-vosi:[1.3.12,2.0.0)'
    implementation 'org.opencadc:cadc-access-control-identity:[1.1.0,)'
    implementation 'org.opencadc:cadc-access-control:[1.1.22,1.2.0)'
    implementation 'org.opencadc:cadc-vos:[1.2.1,1.3)'

    implementation 'org.restlet.jee:org.restlet:[2.4.3,2.4.99)'
    implementation 'org.restlet.jee:org.restlet.ext.servlet:[2.4.3,2.4.99)'
    implementation 'org.restlet.jee:org.restlet.ext.freemarker:[2.4.3,2.4.99)'
    implementation 'org.restlet.jee:org.restlet.ext.json:[2.4.3,2.4.99)'

    testImplementation 'junit:junit:[4.12,5.0)'
    testImplementation 'org.opencadc:cadc-web-test:[2.1.0,3.0.0)'
    testImplementation 'org.easymock:easymock:[4.2, 5.0)'
    testImplementation 'org.mockito:mockito-core:[3.9.0,4.0.0)'
}

// Minimal publishing required to run publishToMavenLocal in preparation for Gradle 7.
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
        }
    }
}

mainClassName = "ca.nrc.cadc.beacon.web.restlet.StorageApplication"

run {
    if ((System.getProperty("SSO_SERVERS") != null)
            && (System.getProperty("SSO_SERVERS") != "")) {
        systemProperty 'SSO_SERVERS', System.getProperty("SSO_SERVERS")
    }

    classpath += files('RsaSignaturePub.key')
}