Passing variables between Terragrunt and Terraform

[ulankford]

I am trying to create an EC2 instance with an EBS volume attached to the said instance.
I have the code to create the EC2 instance using terragrunt, and it works fine.

However, to create the EBS volume and attach it to the instance I need to use some terraform code.

e.g.

Layout tree is:

dev
-ec2
--terragrunt.hcl
--ebs.tf

In the ebs.tf file we can have

resource "aws_ebs_volume" "this" {
availability_zone = "ap-southeast-2a"
size = 20
}

resource "aws_volume_attachment" "this" {
device_name = "/dev/sdh"
volume_id = aws_ebs_volume.this.id
instance_id = <instance.parameter.from.terragrunt>
}

terragrunt.hcl

locals {
environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
env = local.environment_vars.locals.environment

project_vars = read_terragrunt_config(find_in_parent_folders("project.hcl"))
project = local.project_vars.locals.project_name
application = local.project_vars.locals.application_name

}

include {
path = find_in_parent_folders()
}

terraform {
source = "git::[email protected]:terraform-aws-modules/terraform-aws-ec2-instance.git?ref=v3.3.0"
}
``
dependency "sg" {
config_path = "../sg-ec2"

mock_outputs = {
security_group_id = "sg-xxxxxxxxxxxx"
}
}

inputs = {

name = "ui01-${local.project}-${local.application}-${local.env}"
description = "UI 01 ${local.project} ${local.application} Instance for ${local.env}"

ami = "ami-0bd2230cfb28832f7" # Amazon Linux kernel 5.10
instance_type = "c5.large"
key_name = "key-test" # This key is manually created
monitoring = true
iam_instance_profile = "AmazonSSMRoleForInstancesQuickSetup"

vpc_id = "vpc-xxxxxxx"
subnet_id = "subnet-xxxxxxxx"

vpc_security_group_ids = ["${dependency.sg.outputs.security_group_id}"]

}

Is it possible to use the output of the instance and pass this parameter/object to the ebs.tf file so that the ebs volume gets attached to the instance on the fly?

Another question is, is it possible for the *.tf files to use the variables defined in the .hcl files?

e.g.
If you call in terragrunt

locals {
environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
env = local.environment_vars.locals.environment
}

env.hcl is:
locals {
environment = "dev"
}

you can use the variable env as ${local.env} for your inputs
Can you call this variable in the .tf file in some way?

[denis256]

Passing of variables to TF files can be done with variable definitions, simplified example(if I read correctly code in question):

.
├── app
│   ├── ebs.tf
│   └── terragrunt.hcl
└── common.hcl

common.hcl

locals {
  instance_id = "instance-123"
}

terragrunt.hcl

locals {
  common = read_terragrunt_config(find_in_parent_folders("common.hcl"))
}
inputs = {
  instance_id = local.common.locals.instance_id
}

ebs.tf

variable "instance_id" {
  type = string
}

resource "local_file" "ebs_files" {
  content     = "Creating EBS for instance ${var.instance_id}"
  filename = "${path.module}/ebs.txt"
}

$ cd app
terragrunt apply

$ cat  ebs.txt
Creating EBS for instance instance-123

So instance-123 was defined in Terragrunt code common.hcl and ended in ebs.txt created from TF file

[ulankford]

OK, thank you. That partially answers my question, but in this solution, one has to have the instance id already known.
Is it possible to pass it dynamically, without having to have it hardcoded in the common.hcl file?

[denis256]

Hi, I can think of a scenario to use dependency to another module with terraform modules

Example:

├── ebs
│   ├── ebs.tf
│   └── terragrunt.hcl
└── ec2-instance
    ├── main.tf
    └── terragrunt.hcl

# ec2-instance/main.tf

module "date" {
  source = "[email protected]:denis256/terraform-test-module.git//modules/date?ref=v0.0.7"
}

output "instance_id" {
  value = module.date.date
}

# ec2-instance/terragrunt.hcl
# Empty file

# ebs/terragrunt.hcl
dependency "ec2_instance" {
  config_path = "../ec2-instance"
  mock_outputs = {
    instance_id = "123"
  }
}

inputs = {
  instance_id = dependency.ec2_instance.outputs.instance_id
}

# ebs/ebs.tf 
variable "instance_id" {
  type = string
}

resource "local_file" "ebs_files" {
  content     = "Creating EBS for instance ${var.instance_id}"
  filename = "${path.module}/ebs.txt"
}

Execution:

$ cd ebs
$ terragrunt run-all apply
...
$ cat ebs.txt 
Creating EBS for instance 1642288592

https://github.com/denis256/terragrunt-tests/tree/master/variable-passing-module

[ulankford]

It seems in this example, the EC2 instance is created by the ec2-instance/main.tf file?

I already have a ec2-instance/terragrunt.hcl file that creates my desired ec2 instances.... is it possible to extract the outputs of this and pass it along to the ebs/terragrunt.hcl and/or ebs/* modules?

I feel like we are 95% there now though...

Your example does work though, but when I try and implement it to my real world example it fails.

[ulankford]

OK so I have this almost working fully, well in fact it does work, I can grab the instance id and attach an ebs volume to this instance, but at the same time the ebs directory tries to create a new ec2 instance. This is not what I want as I have a ec2 directory looking after the entire ec2 instance creation.

├── ebs
│ ├── ebs.tf
│ └── terragrunt.hcl
└── ec2-instance
└── terragrunt.hcl

ebs.tf

variable "instance_id" {
  type = string
}

resource "aws_ebs_volume" "this" {
  availability_zone = "ap-southeast-2a"
  size              = 20
}

resource "aws_volume_attachment" "this" {
  device_name = "/dev/sdh"
  volume_id   = aws_ebs_volume.this.id
  instance_id = "${var.instance_id}"
}

terragrunt.hcl

locals { }

include {
  path = find_in_parent_folders()
}

terraform {
  source = "git::[email protected]:terraform-aws-modules/terraform-aws-ec2-instance.git?ref=v3.3.0"
}

dependency "ec2-linux-ui" {
  config_path = "../ec2-linux-ui"
  mock_outputs = {
    instance_id = "12345"
  }
}

inputs = {
      instance_id = dependency.ec2-linux-ui.outputs.id
}

terragrunt.hcl for the ec2 instance

locals {
  environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
  env              = local.environment_vars.locals.environment
  project_vars = read_terragrunt_config(find_in_parent_folders("project.hcl"))
  project      = local.project_vars.locals.project_name
  application  = local.project_vars.locals.application_name
}

include {
  path = find_in_parent_folders()
}

terraform {
  source = "git::[email protected]:terraform-aws-modules/terraform-aws-ec2-instance.git?ref=v3.3.0"
}

# Need the output of the correct Security Group ID to attach to the RDS instance
dependency "sg" {
  config_path = "../sg-ec2"

  mock_outputs = {
    security_group_id = "sg-xxxxxxxxxx"
  }
}

inputs = {

  # Naming
  name        = "ui01-${local.project}-${local.application}-${local.env}"
  description = "UI 01 ${local.project} ${local.application} Instance for ${local.env}"

  # EC2 Config
  ami                  = "ami-0bd2230cfb28832f7" # Amazon Linux kernel 5.10
  instance_type        = "c5.large"
  key_name             = "xxxxxxx" 
  monitoring           = true


  # Networking
  vpc_id    = "xxxxxxx"   
  subnet_id = "xxxxxxxx"

  # Security Group
  vpc_security_group_ids = ["${dependency.sg.outputs.security_group_id}"]

}

Not sure why the ebs/terragrunt.hcl file wants to create a new instance when I can successfully get the instance id returned from the ec2-linux-ui dependency? If I can fix that, we are done.

[denis256]

I think creation of a new instance occurs because of reference to terraform-aws-ec2-instance in terragrunt.hcl in ebs directory

In on my local test if I add:

terraform {
  source = "git::[email protected]:terraform-aws-modules/terraform-aws-ec2-instance.git?ref=v3.3.0"
}

then terraform plan plan shows creation of a new instance.

[ulankford]

Yes, that works.

Commenting out that terraform { } part makes the process go smoothly.

Thanks for your help. Now I need to try and figure out how we can pass terraform-generated values to Terragrunt to consume. I guess its similar. Just need to test it.