create multiple instances of modules

[dbd-infra]

We want to use sqs/sns/sqs-sns-connection modules to create multiple channels.

There is an example how to use for_each to create multiple copies of config.
Is there a similar way for our purpose or please suggest the best way to configure it.

---

Tracked in ticket #109938

[arsci]

Hi @dbd-infra, you can use the Terraform for_each argument directly with those modules. Here's a (simplified) example:

The locals block here is just an example input of the for_each argument. You could also set this through variables

This example will create 3 sets of an SQS queue, SNS topic, and connection.

locals {
  to_create = toset(["1","2","3"])
}

module "sqs" {

  for_each = local.to_create

  source = "git::[email protected]:gruntwork-io/terraform-aws-messaging.git//modules/sqs?ref=v0.9.1"

  name = each.key
}

module "sns" {

  for_each = local.to_create

  source = "git::[email protected]:gruntwork-io/terraform-aws-messaging.git//modules/sns?ref=v0.9.1"

  name = each.key
}

module "connection" {

  for_each = local.to_create

  source = "git::[email protected]:gruntwork-io/terraform-aws-messaging.git//modules/sns-sqs-connection?ref=v0.9.1"

  sns_topic_arn = module.sns[each.key].topic_arn
  sqs_arn       = module.sqs[each.key].queue_arn
  sqs_queue_url = module.sqs[each.key].queue_url
}