build.gradle

buildscript {
    apply from: "${rootDir}/gradle/dependencies.gradle"

    repositories {
        mavenCentral()
        jcenter()
        mavenLocal()
    }

    dependencies {
        classpath gradle_plugins.values()
    }
}
apply plugin: 'java'

project.ext.set("debugUpload", false)


repositories {
    mavenCentral()
    maven { url 'http://repo.spring.io/libs-snapshot' }
}

//apply from: "${rootDir}/gradle/root/versions.gradle"
apply from: "${rootDir}/gradle/root/idea.gradle"
apply from: "${rootDir}/gradle/root/eclipse.gradle"
apply from: "${rootDir}/gradle/root/jacoco.gradle"
apply from: "${rootDir}/gradle/root/nexusstaging.gradle"

subprojects {
    apply plugin: 'eclipse'
    apply plugin: 'project-report'

    // USE SEMANTIC VERSIONING AS SPECIFIED HERE: http://semver.org/spec/v2.0.0.html
    //
    // Major Release: X.0.0-RELEASE: Breaking Changes. Should be avoided if possible, or planned for future release.
    // Minor Release: 0.X.0-RELEASE: Additional Features, updates from minor releases in Spring
    // Micro Release: 0.0.X-RELEASE: Bugfixes, non-breaking changes, updates from micro releases in Spring
    //
    // DO NOT FORGET TO DOCUMENT CHANGES IN CHANGELOG.md
    //
    // Add a GitHub release for every new release: https://github.com/otto-de/edison-aws/releases
    version = '3.4.0'
    group = 'de.otto.edison'

    repositories {
        mavenCentral()
        mavenLocal()
        maven { url 'https://oss.sonatype.org/content/repositories/releases/' }
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
    }

    ext['thymeleaf.version'] = versions.thymeleaf
    ext['thymeleaf-layout-dialect.version'] = versions.thymeleaf_layout_dialect

    task allDeps(type: DependencyReportTask) {}

    apply from: "${rootDir}/gradle/idea.gradle"
    apply from: "${rootDir}/gradle/compile.gradle"
    apply from: "${rootDir}/gradle/test.gradle"
    apply from: "${rootDir}/gradle/jacoco.gradle"
    apply from: "${rootDir}/gradle/maven.gradle"
    apply from: "${rootDir}/gradle/signing.gradle"

    targetCompatibility = '17'
    sourceCompatibility = '17'
}

task startLocalStack(type:Exec) {
    commandLine "docker", "run", "--name", "localstack_for_testing", "-d", "-p", "4567-4583:4567-4583", "-p", "8080:8080", "localstack/localstack:latest"
}
task stopLocalStack(type: Exec) {
    commandLine 'docker', 'rm', '-f', 'localstack_for_testing'
}