array.5c

/*
 * $Id: array.5c,v 1.2 2003/05/29 08:15:44 keithp Exp $
 *
 * Copyright © 2003 Keith Packard
 *
 * Permission to use, copy, modify, distribute, and sell this software and its
 * documentation for any purpose is hereby granted without fee, provided that
 * the above copyright notice appear in all copies and that both that
 * copyright notice and this permission notice appear in supporting
 * documentation, and that the name of Keith Packard not be used in
 * advertising or publicity pertaining to distribution of the software without
 * specific, written prior permission.  Keith Packard makes no
 * representations about the suitability of this software for any purpose.  It
 * is provided "as is" without express or implied warranty.
 *
 * KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
 * INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
 * EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
 * CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
 * DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
 * TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
 * PERFORMANCE OF THIS SOFTWARE.
 */

namespace Array {
    public bool contains (&poly[*] a, poly v) {
	for (int i = 0; i < dim(a); i++)
	    if (a[i] == v)
		return true;
	return false;
    }

    public poly append (&poly[*] a, poly v) {
	if (contains(&a, v))
	    return v;
	a = (poly[dim(a)+1]) { [i] = i < dim(a) ? a[i] : v };
	return v;
    }

    public poly push (&poly[*] a, poly v) {
	a = (poly[dim(a)+1]) { [i] = i < dim(a) ? a[i] : v };
	return v;
    }
	
    public exception	empty (&poly[*] a);
    
    public poly pop (&poly[*] a) {
	if (dim(a) == 0)
	    raise empty (a);
	poly v = a[dim(a)-1];
	a = (poly[dim(a)-1]) { [i] = a[i] };
	return v;
    }

    public void iterate (&poly[*] a, void (poly v) f) {
	for (int i = 0; i < dim (a); i++)
	    f(a[i]);
    }
    
    public void remove (&poly[*] a, poly v) {
	if (!contains (&a, v))
	    return;
	bool found = false;
	a = (poly[dim(a)-1]) { [i] = found ? a[i+1] :
	    a[i] == v ? (found=true, a[i+1]) : a[i] };
    }
	
}