Settings.hs

-- | Settings are centralized, as much as possible, into this file. This
-- includes database connection settings, static file locations, etc.
-- In addition, you can configure a number of different aspects of Yesod
-- by overriding methods in the Yesod typeclass. That instance is
-- declared in the Foundation.hs file.
module Settings where

import ClassyPrelude.Yesod
import Control.Exception           (throw)
import Data.Aeson                  (Result (..), fromJSON, withObject, (.!=),
                                    (.:?))
import Data.FileEmbed              (embedFile)
import Data.Yaml                   (decodeEither')

import Database.Persist.Postgresql (PostgresConf)
import Language.Haskell.TH.Syntax  (Exp, Name, Q)
import Network.Wai.Handler.Warp    (HostPreference)
import Yesod.Default.Config2       (applyEnvValue, configSettingsYml)
import Yesod.Default.Util          (WidgetFileSettings, widgetFileNoReload,
                                    widgetFileReload,
                                    TemplateLanguage(..),
                                    defaultTemplateLanguages, globFile,
                                    wfsHamletSettings, wfsLanguages)

import Text.Coffee
import Text.Hamlet
import Text.Lucius
import Text.Shakespeare.Text

-- | Actions which only require access to the database connection can be given
--   type @DB a@ (as opposed to @YesodDB App a@). This allows them to also be
--   called in tests.
type DB a = forall (m :: * -> *).
    (MonadIO m, Functor m) => ReaderT SqlBackend m a

data OAuthKeys = OAuthKeys
    { oauthKeysClientId     :: Text
    , oauthKeysClientSecret :: Text
    }

data StripeKeys = StripeKeys
    { stripeKeysSecretKey      :: Text
    , stripeKeysPublishableKey :: Text
    }

-- | Runtime settings to configure this application. These settings can be
-- loaded from various sources: defaults, environment variables, config files,
-- theoretically even a database.
data AppSettings = AppSettings
    { appStaticDir              :: String
    -- ^ Directory from which to serve static files.
    , appDatabaseConf           :: PostgresConf
    -- ^ Configuration settings for accessing the database.
    , appRoot                   :: Text
    -- ^ Base for all generated URLs.
    , appHost                   :: HostPreference
    -- ^ Host/interface the server should bind to.
    , appPort                   :: Int
    -- ^ Port to listen on
    , appIpFromHeader           :: Bool
    -- ^ Get the IP address from the header when logging. Useful when sitting
    -- behind a reverse proxy.

    , appDetailedRequestLogging :: Bool
    -- ^ Use detailed request logging system
    , appShouldLogAll           :: Bool
    -- ^ Should all log messages be displayed?
    , appReloadTemplates        :: Bool
    -- ^ Use the reload version of templates
    , appMutableStatic          :: Bool
    -- ^ Assume that files in the static dir may change after compilation
    , appSkipCombining          :: Bool
    -- ^ Perform no stylesheet/script combining

    -- Example app-specific configuration values.
    , appCopyright              :: Text
    -- ^ Copyright text to appear in the footer of the page
    , appAnalytics              :: Maybe Text
    -- ^ Segment Analytics code
    , appIntercomSecret         :: Maybe Text
    -- ^ Intercom secure secret
    , appSendMail               :: Bool
    -- ^ Actually send e-mail (via SendGrid)?
    , appDatabaseUrl            :: Bool
    -- ^ Parse database info from DATABASE_URL?
    , appAllowDummyAuth         :: Bool
    -- ^ Add the Dummy Auth plugin (for authenticating in tests)?
    , appForceSSL               :: Bool
    -- ^ Force all traffic to use SSL via sslOnlyMiddleware?
    }

instance FromJSON AppSettings where
    parseJSON = withObject "AppSettings" $ \o -> do
        let defaultDev =
#if DEVELOPMENT
                True
#else
                False
#endif
        appStaticDir              <- o .: "static-dir"
        appDatabaseConf           <- o .: "database"
        appRoot                   <- o .: "approot"
        appHost                   <- fromString <$> o .: "host"
        appPort                   <- o .: "port"
        appIpFromHeader           <- o .: "ip-from-header"

        appDetailedRequestLogging <- o .:? "detailed-logging" .!= defaultDev
        appShouldLogAll           <- o .:? "should-log-all"   .!= defaultDev
        appReloadTemplates        <- o .:? "reload-templates" .!= defaultDev
        appMutableStatic          <- o .:? "mutable-static"   .!= defaultDev
        appSkipCombining          <- o .:? "skip-combining"   .!= defaultDev

        appCopyright              <- o .: "copyright"
        appAnalytics              <- o .:? "analytics"
        appIntercomSecret         <- o .:? "intercom-secret"
        appSendMail               <- o .:? "send-mail"        .!= (not defaultDev)
        appDatabaseUrl            <- o .:? "database-url"     .!= (not defaultDev)
        appAllowDummyAuth         <- o .:? "allow-dummy-auth" .!= defaultDev
        appForceSSL               <- o .:? "force-ssl"        .!= (not defaultDev)

        return AppSettings {..}

-- | Settings for 'widgetFile', such as which template languages to support and
-- default Hamlet settings.
--
-- For more information on modifying behavior, see:
--
-- https://github.com/yesodweb/yesod/wiki/Overriding-widgetFile
widgetFileSettings :: WidgetFileSettings
widgetFileSettings = def
    { wfsLanguages = \hset -> defaultTemplateLanguages hset ++ [coffeeLang]
    , wfsHamletSettings = defaultHamletSettings
        { hamletNewlines = AlwaysNewlines
        }
    }

  where
    coffeeLang = TemplateLanguage True "coffee"
        Text.Coffee.coffeeFile Text.Coffee.coffeeFileReload

-- | How static files should be combined.
combineSettings :: CombineSettings
combineSettings = def

-- The rest of this file contains settings which rarely need changing by a
-- user.

widgetFile :: String -> Q Exp
widgetFile = (if appReloadTemplates compileTimeAppSettings
                then widgetFileReload
                else widgetFileNoReload)
              widgetFileSettings

coffeeFile :: String -> Q Exp
coffeeFile f =
    if appReloadTemplates compileTimeAppSettings
        then Text.Coffee.coffeeFileReload $ globFile "coffee" f
        else Text.Coffee.coffeeFile $ globFile "coffee" f

luciusFile :: String -> Q Exp
luciusFile f =
    if appReloadTemplates compileTimeAppSettings
        then Text.Lucius.luciusFileReload $ globFile "lucius" f
        else Text.Lucius.luciusFile $ globFile "lucius" f

textFile :: String -> Q Exp
textFile f =
    if appReloadTemplates compileTimeAppSettings
        then Text.Shakespeare.Text.textFileReload $ globFile "text" f
        else Text.Shakespeare.Text.textFile $ globFile "text" f

-- | Raw bytes at compile time of @config/settings.yml@
configSettingsYmlBS :: ByteString
configSettingsYmlBS = $(embedFile configSettingsYml)

-- | @config/settings.yml@, parsed to a @Value@.
configSettingsYmlValue :: Value
configSettingsYmlValue = either throw id $ decodeEither' configSettingsYmlBS

-- | A version of @AppSettings@ parsed at compile time from @config/settings.yml@.
compileTimeAppSettings :: AppSettings
compileTimeAppSettings =
    case fromJSON $ applyEnvValue False mempty configSettingsYmlValue of
        Error e -> error e
        Success settings -> settings

-- The following two functions can be used to combine multiple CSS or JS files
-- at compile time to decrease the number of http requests.
-- Sample usage (inside a Widget):
--
-- > $(combineStylesheets 'StaticR [style1_css, style2_css])

combineStylesheets :: Name -> [Route Static] -> Q Exp
combineStylesheets = combineStylesheets'
    (appSkipCombining compileTimeAppSettings)
    combineSettings

combineScripts :: Name -> [Route Static] -> Q Exp
combineScripts = combineScripts'
    (appSkipCombining compileTimeAppSettings)
    combineSettings