build.gradle

import org.apache.tools.ant.taskdefs.condition.Os

apply plugin: 'com.android.application'

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
    compile 'com.android.support:appcompat-v7:20.0+'
}

android {
    compileSdkVersion 14
    buildToolsVersion '20.0.0'

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
            jniLibs.srcDir 'libs'
            jni.srcDirs = []
        }

        // Move the tests to tests/java, tests/res, etc...
        instrumentTest.setRoot('tests')

        // Move the build types to build-types/<type>
        // For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...
        // This moves them out of them default location under src/<type>/... which would
        // conflict with src/ being used by the main source set.
        // Adding new build types or product flavors should be accompanied
        // by a similar customization.
        debug.setRoot('build-types/debug')
        release.setRoot('build-types/release')
    }

    task ndkBuild(type: Exec) {
        def Properties localProps = new Properties()
        localProps.load(new FileInputStream("local.properties"))
        def ndk_dir = localProps['ndk.dir']
        def ndk_build_cmd = "$ndk_dir/ndk-build"
        if (Os.isFamily(Os.FAMILY_WINDOWS)) {
            ndk_build_cmd = "$ndk_dir/ndk-build.cmd"
        }
        commandLine ndk_build_cmd, '-j', Runtime.runtime.availableProcessors(), "NDK_OUT=$buildDir/native/obj", "NDK_PROJECT_PATH=."
    }

    tasks.withType(JavaCompile) {
        compileTask -> compileTask.dependsOn ndkBuild
    }
}

buildscript {
    repositories {
        jcenter()
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:1.5+'
    }

}