build.gradle

import org.gradle.internal.os.OperatingSystem

switch (OperatingSystem.current()) {
    case OperatingSystem.WINDOWS:
        project.ext.lwjglNatives = "natives-windows"
        break
    case OperatingSystem.LINUX:
        project.ext.lwjglNatives = "natives-linux"
        break
    case OperatingSystem.MAC_OS:
        project.ext.lwjglNatives = "natives-macos"
        break
}

buildscript {
    repositories {
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.6.2"
    }
}

apply plugin: "org.sonarqube"

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven'

    group 'com.panguengine'
    version engineVersion

    sourceCompatibility = targetCompatibility = 11

    repositories {
        jcenter()
        mavenCentral()
        maven {
            url 'https://jitpack.io'
        }
        maven {
            url "https://oss.sonatype.org/content/repositories/snapshots/"
        }
        maven {
            url "https://oss.sonatype.org/content/repositories/releases/"
        }
        mavenLocal()
    }

    dependencies {
        testImplementation 'org.junit.jupiter:junit-jupiter-api:5.5.0'
        testImplementation 'org.junit.jupiter:junit-jupiter-params:5.5.0'
        testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.5.0'
        testImplementation 'org.hamcrest:hamcrest-all:1.3'
        testImplementation 'org.mockito:mockito-all:1.10.19'
        testImplementation 'name.falgout.jeffrey.testing.junit5:mockito-extension:1.1.1'
        testImplementation 'org.slf4j:slf4j-simple:1.7.25'
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }

    jar {
//        archiveBaseName.set("pangu-" + project.name)
        from rootProject.file('LICENSE')
    }
}