base: lmp: enable sstate hash equivalence

meta-lmp-base/classes/lmp-staging.bbclass

@@ -12,6 +12,10 @@ LMPSTAGING_LOCK_TO_AVOID_OOM = "clang-native rust-native rust-llvm-native"
 python __anonymous() {
     pn = d.getVar('PN')
 
+    if d.getVar('RM_WORK_EXCLUDE_ALL') != "":
+        d.delVarFlag('rm_work_rootfs', 'cleandirs')
+        d.delVarFlag('rm_work_populatesdk', 'cleandirs')
+
     if bb.data.inherits_class('module', d):
         d.appendVar('DEPENDS', ' virtual/kernel')
         if 'modsign' in d.getVar('DISTRO_FEATURES'):
@@ -33,6 +37,14 @@ python __anonymous() {
 
 inherit ${LMPSTAGING_INHERIT_KERNEL_MODSIGN}
 
+RM_WORK_EXCLUDE_ALL ?= ""
+do_rm_work:prepend () {
+    if [ "${RM_WORK_EXCLUDE_ALL}" != "" ]; then
+        bbnote "rm_work: Skipping as RM_WORK_EXCLUDE_ALL is defined"
+        exit 0
+     fi
+}
+
 BB_HASHCHECK_FUNCTION:lmp = "lmp_sstate_checkhashes"
 def lmp_sstate_checkhashes(sq_data, d, **kwargs):
     if 'summary' not in kwargs or kwargs.get('summary'):

meta-lmp-base/conf/distro/include/lmp.inc

@@ -80,6 +80,10 @@ INHERIT += "lmp"
 INHERIT += "lmp-staging"
 INHERIT += "uninative"
 
+# OEEquivHash
+BB_SIGNATURE_HANDLER ?= "OEEquivHash"
+BB_HASHSERVE ??= "auto"
+
 # Clang toolchain
 TOOLCHAIN ?= "clang"
 RUNTIME = "llvm"

meta-lmp-base/recipes-core/images/core-image-minimal-initramfs.bbappend

@@ -1,7 +1,4 @@
 # Only initramfs-module-install-efi is supported
 INITRAMFS_SCRIPTS:remove = "initramfs-module-install"
 
-SSTATE_SKIP_CREATION:task-image-qa = "0"
-SSTATE_SKIP_CREATION:task-image-complete = "0"
-
-inherit nopackages
+require recipes-samples/images/lmp-feature-initramfs.inc

meta-lmp-base/recipes-core/images/initramfs-ostree-lmp-image.bb

@@ -34,7 +34,7 @@ IMAGE_CLASSES:remove = "image_repo_manifest"
 # avoid circular dependencies
 EXTRA_IMAGEDEPENDS = ""
 
-inherit core-image nopackages
+inherit core-image
 
 IMAGE_ROOTFS_SIZE = "8192"
 
@@ -45,5 +45,4 @@ IMAGE_OVERHEAD_FACTOR = "1.0"
 
 BAD_RECOMMENDATIONS += "busybox-syslog"
 
-SSTATE_SKIP_CREATION:task-image-qa = "0"
-SSTATE_SKIP_CREATION:task-image-complete = "0"
+require recipes-samples/images/lmp-feature-initramfs.inc

meta-lmp-base/recipes-samples/images/lmp-feature-initramfs.inc

@@ -0,0 +1,20 @@
+# this file is required to store the initramfs on the sstate cache
+# oe-core patch not accepted
+# https://patchwork.yoctoproject.org/project/oe-core/patch/[email protected]/
+
+# override sstate.bbclass sstate_report_unihash
+python sstate_report_unihash() {
+    report_unihash = getattr(bb.parse.siggen, 'report_unihash', None)
+
+    if report_unihash:
+        ss = sstate_state_fromvars(d)
+        if ss['task'] == 'image_complete':
+            os.environ['PSEUDO_DISABLED'] = '1'
+        report_unihash(os.getcwd(), ss['task'], d)
+}
+
+SSTATE_SKIP_CREATION:task-image-qa = "0"
+# this needs the sstate_report_unihash override
+SSTATE_SKIP_CREATION:task-image-complete = "0"
+
+inherit nopackages