implement bintray publish & release 1.0.0

.gitignore

@@ -5,3 +5,4 @@
 /out
 /src/main/generated/
 /src/test/generated_tests/
+/gradle.properties

build.gradle.kts

@@ -1,9 +1,13 @@
+import com.jfrog.bintray.gradle.BintrayExtension
+
 plugins {
     java
+    `maven-publish`
+    id("com.jfrog.bintray") version "1.8.5"
 }
 
 group = "me.hltj"
-version = "1.0.0-SNAPSHOT"
+version = "1.0.0"
 
 repositories {
     mavenCentral()
@@ -19,10 +23,69 @@ dependencies {
 }
 
 java {
+    withJavadocJar()
+    withSourcesJar()
     sourceCompatibility = JavaVersion.VERSION_1_8
     targetCompatibility = JavaVersion.VERSION_1_8
 }
 
+tasks.withType<Javadoc> {
+    (options as CoreJavadocOptions).addStringOption("Xdoclint:none", "-quiet")
+}
+
 tasks.withType<Test> {
     useJUnitPlatform()
 }
+
+
+publishing {
+    publications {
+        create<MavenPublication>("bintray") {
+            from(components["java"])
+            pom {
+                name.set("Vert.x Future Utils")
+                description.set("Convenient Utilities for Vert.x Future")
+                url.set("https://github.com/hltj/vertx-future-utils")
+                licenses {
+                    license {
+                        name.set("GNU Lesser General Public License")
+                        url.set("https://www.gnu.org/licenses/lgpl-3.0.txt")
+                    }
+                }
+                developers {
+                    developer {
+                        id.set("hltj")
+                        name.set("JiaYanwei")
+                        email.set("[email protected]")
+                    }
+                }
+                scm {
+                    url.set("https://github.com/hltj/vertx-future-utils.git")
+                }
+            }
+        }
+    }
+}
+
+bintray {
+    user = propertyOrEnv("bintray.user", "BINTRAY_USER")
+    key = propertyOrEnv("bintray.key", "BINTRAY_KEY")
+    setPublications("bintray")
+
+    with(pkg) {
+        repo = "mvn"
+        name = project.name
+        vcsUrl = "https://github.com/hltj/vertx-future-utils.git"
+        setLicenses("LGPL-3.0")
+        setLabels("vert.x", "future", "utilities", "utility-library")
+
+        with(version) {
+            val versionString = project.version.toString()
+            name = versionString
+            vcsTag = versionString
+        }
+    }
+}
+
+fun BintrayExtension.propertyOrEnv(propertyName: String, envName: String) =
+    project.properties[propertyName]?.toString() ?: System.getenv(envName)