nix: flake & non-flake dev shells

- Added nix stuff
- Documented usage of nix stuff
- Moved #contributing to a separate file

.gitignore

@@ -2,4 +2,11 @@
 #
 # SPDX-License-Identifier: CC0-1.0
 
+# Cargo
 target/
+
+# Nix 
+result
+
+# fakegreet
+greetd.sock

.reuse/dep5

@@ -3,6 +3,6 @@ Upstream-Name: ReGreet
 Upstream-Contact: Harish Rajagopal <[email protected]>
 Source: https://github.com/rharish101/ReGreet
 
-Files: Cargo.lock
+Files: Cargo.lock flake.lock
 Copyright: 2022 Harish Rajagopal <[email protected]>
 License: CC0-1.0

CONTRIBUTING.md

@@ -0,0 +1,57 @@
+<!--
+SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+
+SPDX-License-Identifier: GPL-3.0-or-later
+-->
+
+# Contributing
+
+## Pre commit
+
+[pre-commit](https://pre-commit.com/) is used for managing hooks that run before each commit (such as clippy), to ensure
+code quality. Thus, this needs to be set up only when one intends to commit changes to git.
+
+Firstly, [install pre-commit](https://pre-commit.com/#installation) itself. Next, install pre-commit hooks:
+```sh
+pre-commit install
+```
+
+Now, pre-commit should ensure that the code passes all linters locally before committing. This will save time when
+creating PRs, since these linters also run in CI, and thus fail code that hasn't been linted well.
+
+## Nix dev shells
+
+Simply run `nix develop .#vscode --command code .` to get VS Code set up with all the extensions you need. The default
+shell doesn't have any text editors configred.
+
+You can also use nix without flakes if you choose to. See the [nix documentation in this repo](nix/README.md) for more
+details.
+
+## Testing
+
+You can run ReGreet without a greetd socket using `--demo` flag. It also disables some of the features such as logging
+to a file.
+
+```sh
+regreet --demo
+```
+
+Since the demo mode doesn't use greetd, authentication is done using hardcoded credentials within the codebase. These
+credentials are logged with the warning log level, so that you don't have to read the source code.
+
+-----
+
+Alternatively you can use `fakegreet` to emulate a running greetd daemon. Please keep in mind that it's behavior doesn't
+match the real thing. 
+
+```sh
+fakegreet 'cargo run'
+```
+
+Fakegreet credentials (taken from source code):
+
+||Value|
+|---|---|
+|User|user|
+|Password|password|
+|7+2|9|

README.md

@@ -230,28 +230,9 @@ The recommended configuration is to run greetd greeters as a separate user (`gre
 This can lead to insufficient permissions for either creating the cache/log directories, or writing to them.
 To make use of the caching and logging features, please create the directories manually with the correct permissions, if not done during installation with systemd-tmpfiles.
 
-## Contributing
-[pre-commit](https://pre-commit.com/) is used for managing hooks that run before each commit (such as clippy), to ensure code quality.
-Thus, this needs to be set up only when one intends to commit changes to git.
+# Contributing
 
-Firstly, [install pre-commit](https://pre-commit.com/#installation) itself.
-Next, install pre-commit hooks:
-```sh
-pre-commit install
-```
-
-Now, pre-commit should ensure that the code passes all linters locally before committing.
-This will save time when creating PRs, since these linters also run in CI, and thus fail code that hasn't been linted well.
-
-### Demo mode
-To aid development, a "demo" mode is included within ReGreet that runs ReGreet independent of greetd.
-Simply run ReGreet as follows:
-```sh
-regreet --demo
-```
-
-Since the demo mode doesn't use greetd, authentication is done using hardcoded credentials within the codebase.
-These credentials are logged with the warning log-level, so that you don't have to read the source code.
+See [CONTRIBUTING.md](CONTRIBUTING.md)
 
 ## Licenses
 This repository uses [REUSE](https://reuse.software/) to document licenses.

default.nix

@@ -0,0 +1,5 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{pkgs ? import <nixpkgs> {}}:
+pkgs.callPackage ./nix/packages {}

flake.nix

@@ -0,0 +1,41 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  description = "Dev tooling for ReGreet";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    supportedSystems = ["x86_64-linux"];
+    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+    pkgsFor = system:
+      import nixpkgs {
+        config.allowUnfree = true;
+        inherit system;
+      };
+  in {
+    formatter = forAllSystems (system: (pkgsFor system).alejandra);
+
+    packages = forAllSystems (system: let
+      pkgs = pkgsFor system;
+    in
+      {
+        default = self.packages.${system}.regreet;
+      }
+      // (pkgs.callPackage ./nix/packages {}));
+
+    devShells = forAllSystems (system: let
+      pkgs = pkgsFor system;
+    in
+      {
+        default = self.devShells.${system}.rust;
+      }
+      // (pkgs.callPackage ./nix/shells {}));
+  };
+}

nix/README.md

@@ -0,0 +1,50 @@
+<!--
+SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+
+SPDX-License-Identifier: GPL-3.0-or-later
+-->
+
+# Nix
+
+## Structure
+
+|Path||
+|---|---|
+|[`/nix/packages`](packages)|Filenames are keys in both `flake.packages` and attributes in [`/default.nix`](../default.nix)|
+|[`/nix/shells`](shells)|Filenames are keys in both `flake.devShells` and attributes in [`/shell.nix`](../shell.nix)|
+
+## Loading a shell / building packages
+
+<details><summary>With flakes</summary>
+
+See the flake source for what `.#default` points to.
+
+```sh
+nix develop .#<filename>
+nix build .#<filename>
+
+# Example
+
+nix develop .#vscode
+# Loads ./shells/vscode.nix
+```
+
+</details>
+
+-----
+
+<details><summary>Without flakes</summary>
+
+You have to select an attribute with `-A`. `default` is not set (it doesnt work like that in `nix-*` commnands)!
+
+```sh
+nix-shell -A <filename>
+nix-build -A <filename>
+
+# Example
+
+nix-build -A regreet
+# Builds ./packages/regreet.nix
+```
+
+</details>

nix/packages/default.nix

@@ -0,0 +1,19 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  lib,
+  callPackage,
+}: let
+  inherit (builtins) map listToAttrs filter attrNames readDir;
+  inherit (lib) removeSuffix;
+
+  ls = attrNames (readDir ./.);
+  notThisFile = name: name != "default.nix";
+  rmDotNix = removeSuffix ".nix";
+  mkAttr = file: {
+    name = rmDotNix file;
+    value = callPackage ./${file} {};
+  };
+in
+  listToAttrs (map mkAttr (filter notThisFile ls))

nix/packages/regreet.nix

@@ -0,0 +1,27 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  buildFeatures ? ["gtk4_8"],
+  lib,
+  rustPlatform,
+  pkg-config,
+  wrapGAppsHook4,
+  glib,
+  gtk4,
+  pango,
+  librsvg,
+}: let
+  manifest = (lib.importTOML ../../Cargo.toml).package;
+in
+  rustPlatform.buildRustPackage rec {
+    pname = manifest.name;
+    inherit (manifest) version;
+    cargoLock.lockFile = ../../Cargo.lock;
+    src = lib.cleanSource ../..;
+
+    inherit buildFeatures;
+
+    nativeBuildInputs = [pkg-config wrapGAppsHook4];
+    buildInputs = [glib gtk4 pango librsvg];
+  }

nix/shells/default.nix

@@ -0,0 +1,19 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  lib,
+  callPackage,
+}: let
+  inherit (builtins) map listToAttrs filter attrNames readDir;
+  inherit (lib) removeSuffix;
+
+  ls = attrNames (readDir ./.);
+  notThisFile = name: name != "default.nix";
+  rmDotNix = removeSuffix ".nix";
+  mkAttr = file: {
+    name = rmDotNix file;
+    value = callPackage ./${file} {};
+  };
+in
+  listToAttrs (map mkAttr (filter notThisFile ls))

nix/shells/rust.nix

@@ -0,0 +1,29 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  callPackage,
+  mkShell,
+  rust-analyzer,
+  rustfmt,
+  clippy,
+  pre-commit,
+  greetd,
+}:
+mkShell {
+  inputsFrom = [(callPackage ../packages/regreet.nix {})];
+  buildInputs = [
+    rust-analyzer
+    rustfmt
+    clippy
+
+    pre-commit
+
+    greetd.greetd # fakegreet
+  ];
+
+  shellHook = ''
+    echo "Installing pre commit hooks";
+    pre-commit install;
+  '';
+}

nix/shells/vscode.nix

@@ -0,0 +1,25 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{
+  callPackage,
+  mkShell,
+  vscode-with-extensions,
+  vscode-extensions,
+}:
+mkShell {
+  inputsFrom = [(callPackage ./rust.nix {})];
+  buildInputs = [
+    (
+      vscode-with-extensions.override {
+        vscodeExtensions = with vscode-extensions; [
+          rust-lang.rust-analyzer
+          tamasfe.even-better-toml
+          bbenoist.nix
+
+          vscodevim.vim # you can disable this in extension settings if you want
+        ];
+      }
+    )
+  ];
+}

shell.nix

@@ -0,0 +1,5 @@
+# SPDX-FileCopyrightText: 2024 Harish Rajagopal <[email protected]>
+#
+# SPDX-License-Identifier: GPL-3.0-or-later
+{pkgs ? import <nixpkgs> {config.allowUnfree = true;}}:
+pkgs.callPackage ./nix/shells {}