Extract a “pure” lib from mkLib

This contains the parts of the Crane lib that don’t depend on `pkgs`.

Fixes ipetkov#699.

default.nix

@@ -1,3 +1,5 @@
-{ pkgs ? import <nixpkgs> { } }:
+{ pkgs ? import <nixpkgs> { }
+, pureLib ? import ./pure-lib { inherit (pkgs) lib; }
+}:
 
-pkgs.callPackage ./lib { }
+pkgs.callPackage ./lib { inherit pureLib; }

flake.nix

@@ -1,16 +1,19 @@
 {
   description = "A Nix library for building cargo projects. Never build twice thanks to incremental artifact caching.";
 
-  inputs = { };
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
 
   nixConfig = {
     extra-substituters = [ "https://crane.cachix.org" ];
     extra-trusted-public-keys = [ "crane.cachix.org-1:8Scfpmn9w+hGdXH/Q9tTLiYAE/2dnJYRJP7kl80GuRk=" ];
+    use-registries = false;
   };
 
-  outputs = { ... }:
+  outputs = { nixpkgs, ... }:
     let
+      lib = import ./pure-lib { inherit (nixpkgs) lib; };
       mkLib = pkgs: import ./default.nix {
+        pureLib = lib;
         inherit pkgs;
       };
       nodes = (builtins.fromJSON (builtins.readFile ./test/flake.lock)).nodes;
@@ -48,7 +51,7 @@
       ];
     in
     {
-      inherit mkLib;
+      inherit lib mkLib;
 
       overlays.default = _final: _prev: { };
 
@@ -121,7 +124,6 @@
       };
     } // eachDefaultSystem (system:
       let
-        nixpkgs = inputFromLock "nixpkgs";
         pkgs = import nixpkgs {
           inherit system;
         };

lib/default.nix

@@ -1,4 +1,5 @@
 { lib
+, pureLib
 , stdenv
 , makeScopeWithSplicing'
 , splicePackages
@@ -11,11 +12,6 @@
 }:
 
 let
-  minSupported = "24.05";
-  current = lib.concatStringsSep "." (lib.lists.sublist 0 2 (lib.splitVersion lib.version));
-  isUnsupported = lib.versionOlder current minSupported;
-  msg = "crane requires at least nixpkgs-${minSupported}, supplied nixpkgs-${current}";
-
   # Helps keep things in sync between `overrideToolchain` and `keep`
   attrsForToolchainOverride = [
     "cargo"
@@ -40,13 +36,8 @@ let
   scopeFn = self:
     let
       inherit (self) callPackage;
-
-      internalCrateNameFromCargoToml = callPackage ./internalCrateNameFromCargoToml.nix { };
-      internalCrateNameForCleanSource = callPackage ./internalCrateNameForCleanSource.nix {
-        inherit internalCrateNameFromCargoToml;
-      };
     in
-    {
+    pureLib // {
       appendCrateRegistries = input: self.overrideScope (_final: prev: {
         crateRegistries = prev.crateRegistries // (lib.foldl (a: b: a // b) { } input);
       });
@@ -65,28 +56,13 @@ let
       cargoNextest = callPackage ./cargoNextest.nix { };
       cargoTarpaulin = callPackage ./cargoTarpaulin.nix { };
       cargoTest = callPackage ./cargoTest.nix { };
-      cleanCargoSource = callPackage ./cleanCargoSource.nix {
-        inherit internalCrateNameForCleanSource;
-      };
-      cleanCargoToml = callPackage ./cleanCargoToml.nix { };
       configureCargoCommonVarsHook = callPackage ./setupHooks/configureCargoCommonVars.nix { };
       configureCargoVendoredDepsHook = callPackage ./setupHooks/configureCargoVendoredDeps.nix { };
       craneUtils = callPackage ../pkgs/crane-utils { };
 
-      crateNameFromCargoToml = callPackage ./crateNameFromCargoToml.nix {
-        inherit internalCrateNameFromCargoToml;
-      };
-
-      crateRegistries = self.registryFromDownloadUrl {
-        dl = "https://static.crates.io/crates";
-        indexUrl = "https://github.com/rust-lang/crates.io-index";
-      };
-
       devShell = callPackage ./devShell.nix { };
       downloadCargoPackage = callPackage ./downloadCargoPackage.nix { };
       downloadCargoPackageFromGit = callPackage ./downloadCargoPackageFromGit.nix { };
-      filterCargoSources = callPackage ./filterCargoSources.nix { };
-      findCargoFiles = callPackage ./findCargoFiles.nix { };
       inheritCargoArtifactsHook = callPackage ./setupHooks/inheritCargoArtifacts.nix { };
       installCargoArtifactsHook = callPackage ./setupHooks/installCargoArtifacts.nix { };
       installFromCargoBuildLogHook = callPackage ./setupHooks/installFromCargoBuildLog.nix { };
@@ -110,36 +86,26 @@ let
         lib.warnIf needsSplicing warningMsg (lib.genAttrs attrsForToolchainOverride (_: toolchain))
       );
 
-      path = callPackage ./path.nix {
-        inherit internalCrateNameForCleanSource;
-      };
-
-      registryFromDownloadUrl = callPackage ./registryFromDownloadUrl.nix { };
-      registryFromGitIndex = callPackage ./registryFromGitIndex.nix { };
-      registryFromSparse = callPackage ./registryFromSparse.nix { };
       removeReferencesToVendoredSourcesHook = callPackage ./setupHooks/removeReferencesToVendoredSources.nix { };
       replaceCargoLockHook = callPackage ./setupHooks/replaceCargoLockHook.nix { };
       taploFmt = callPackage ./taploFmt.nix { };
-      urlForCargoPackage = callPackage ./urlForCargoPackage.nix { };
       vendorCargoDeps = callPackage ./vendorCargoDeps.nix { };
       vendorMultipleCargoDeps = callPackage ./vendorMultipleCargoDeps.nix { };
       vendorCargoRegistries = callPackage ./vendorCargoRegistries.nix { };
       vendorGitDeps = callPackage ./vendorGitDeps.nix { };
       writeTOML = callPackage ./writeTOML.nix { };
     };
-
-  craneSpliced = makeScopeWithSplicing' {
-    f = scopeFn;
-    otherSplices = {
-      selfBuildBuild = lib.makeScope pkgsBuildBuild.newScope scopeFn;
-      selfBuildHost = lib.makeScope pkgsBuildHost.newScope scopeFn;
-      selfBuildTarget = lib.makeScope pkgsBuildTarget.newScope scopeFn;
-      selfHostHost = lib.makeScope pkgsHostHost.newScope scopeFn;
-      selfHostTarget = lib.makeScope pkgsHostTarget.newScope scopeFn;
-      selfTargetTarget = lib.optionalAttrs (pkgsTargetTarget?newScope) (lib.makeScope pkgsTargetTarget.newScope scopeFn);
-    };
-    keep = self: lib.optionalAttrs (self?cargo)
-      (lib.genAttrs attrsForToolchainOverride (n: self.${n}));
-  };
 in
-lib.warnIf isUnsupported msg (craneSpliced)
+makeScopeWithSplicing' {
+  f = scopeFn;
+  otherSplices = {
+    selfBuildBuild = lib.makeScope pkgsBuildBuild.newScope scopeFn;
+    selfBuildHost = lib.makeScope pkgsBuildHost.newScope scopeFn;
+    selfBuildTarget = lib.makeScope pkgsBuildTarget.newScope scopeFn;
+    selfHostHost = lib.makeScope pkgsHostHost.newScope scopeFn;
+    selfHostTarget = lib.makeScope pkgsHostTarget.newScope scopeFn;
+    selfTargetTarget = lib.optionalAttrs (pkgsTargetTarget?newScope) (lib.makeScope pkgsTargetTarget.newScope scopeFn);
+  };
+  keep = self: lib.optionalAttrs (self?cargo)
+    (lib.genAttrs attrsForToolchainOverride (n: self.${n}));
+}

pure-lib/default.nix

@@ -0,0 +1,49 @@
+{ lib
+}:
+
+let
+  minSupported = "24.05";
+  current = lib.concatStringsSep "." (lib.lists.sublist 0 2 (lib.splitVersion lib.version));
+  isUnsupported = lib.versionOlder current minSupported;
+  msg = "crane requires at least nixpkgs-${minSupported}, supplied nixpkgs-${current}";
+
+  pureLib =
+    let
+      internalCrateNameFromCargoToml = import ./internalCrateNameFromCargoToml.nix { inherit lib; };
+      internalCrateNameForCleanSource = import ./internalCrateNameForCleanSource.nix {
+        inherit internalCrateNameFromCargoToml;
+      };
+
+      crateRegistries = registryFromDownloadUrl {
+        dl = "https://static.crates.io/crates";
+        indexUrl = "https://github.com/rust-lang/crates.io-index";
+      };
+
+      filterCargoSources = import ./filterCargoSources.nix { inherit lib; };
+
+      registryFromDownloadUrl = import ./registryFromDownloadUrl.nix { inherit lib; };
+    in
+    {
+      inherit crateRegistries filterCargoSources registryFromDownloadUrl;
+
+      cleanCargoSource = import ./cleanCargoSource.nix {
+        inherit filterCargoSources internalCrateNameForCleanSource lib;
+      };
+      cleanCargoToml = import ./cleanCargoToml.nix { };
+
+      crateNameFromCargoToml = import ./crateNameFromCargoToml.nix {
+        inherit internalCrateNameFromCargoToml lib;
+      };
+
+      findCargoFiles = import ./findCargoFiles.nix { inherit lib; };
+
+      path = import ./path.nix {
+        inherit internalCrateNameForCleanSource lib;
+      };
+
+      registryFromGitIndex = import ./registryFromGitIndex.nix { inherit registryFromDownloadUrl; };
+      registryFromSparse = import ./registryFromSparse.nix { inherit registryFromDownloadUrl lib; };
+      urlForCargoPackage = import ./urlForCargoPackage.nix { inherit crateRegistries lib; };
+    };
+in
+lib.warnIf isUnsupported msg pureLib