fix:add forge tests for TestSendReceiver

solidity/contracts/test/TestSendReceiver.sol

@@ -16,7 +16,7 @@ contract TestSendReceiver is IMessageRecipient {
 
     uint256 public constant HANDLE_GAS_AMOUNT = 50_000;
 
-    event Handled(bytes32 blockHash);
+    event Handled(uint256 randao);
 
     function dispatchToSelf(
         IMailbox _mailbox,
@@ -47,14 +47,12 @@ contract TestSendReceiver is IMessageRecipient {
         );
     }
 
+    // for testing random failure of handle call for the agents
+    // if randao ends in 0, fail
     function handle(uint32, bytes32, bytes calldata) external payable override {
-        bytes32 blockHash = previousBlockHash();
-        bool isBlockHashEndIn0 = uint256(blockHash) % 16 == 0;
-        require(!isBlockHashEndIn0, "block hash ends in 0");
-        emit Handled(blockHash);
-    }
-
-    function previousBlockHash() internal view returns (bytes32) {
-        return blockhash(block.number - 1);
+        uint256 randao = block.prevrandao;
+        bool doesRandaoEndIn0 = randao % 16 == 0;
+        require(!doesRandaoEndIn0, "randao ends in 0");
+        emit Handled(randao);
     }
 }

solidity/test/test/TestSendReceiver.t.sol

@@ -0,0 +1,110 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+import {Test} from "forge-std/Test.sol";
+
+import {TypeCasts} from "../../contracts/libs/TypeCasts.sol";
+import {TestSendReceiver} from "../../contracts/test/TestSendReceiver.sol";
+import {TestMailbox} from "../../contracts/test/TestMailbox.sol";
+import {TestIsm} from "../../contracts/test/TestIsm.sol";
+import {TestInterchainGasPaymaster} from "../../contracts/test/TestInterchainGasPaymaster.sol";
+import {TestMerkleTreeHook} from "../../contracts/test/TestMerkleTreeHook.sol";
+
+contract TestSendReceiverTest is Test {
+    using TypeCasts for address;
+
+    uint32 internal constant TEST_ORIGIN_DOMAIN = 1;
+    uint32 internal constant TEST_DESTINATION_DOMAIN = 2;
+    bytes internal constant TEST_MESSAGE_CONTENT = bytes("Bonjour");
+    TestSendReceiver internal testSendReceiver;
+    TestInterchainGasPaymaster internal igp;
+    TestMailbox internal mailbox;
+    uint256 internal gasPayment;
+    bytes internal testMessage;
+
+    function setUp() public {
+        mailbox = new TestMailbox(TEST_ORIGIN_DOMAIN);
+        TestIsm ism = new TestIsm();
+        igp = new TestInterchainGasPaymaster();
+        TestMerkleTreeHook requiredHook = new TestMerkleTreeHook(
+            address(mailbox)
+        );
+        mailbox.initialize(
+            address(this),
+            address(ism),
+            address(igp),
+            address(requiredHook)
+        );
+        testSendReceiver = new TestSendReceiver();
+
+        gasPayment = mailbox.quoteDispatch(
+            TEST_DESTINATION_DOMAIN,
+            address(testSendReceiver).addressToBytes32(),
+            TEST_MESSAGE_CONTENT
+        );
+        testMessage = mailbox.buildOutboundMessage(
+            TEST_DESTINATION_DOMAIN,
+            address(testSendReceiver).addressToBytes32(),
+            TEST_MESSAGE_CONTENT
+        );
+    }
+
+    event Dispatch(
+        address indexed sender,
+        uint32 indexed destination,
+        bytes32 indexed recipient,
+        bytes message
+    );
+
+    function testDispatchToSelf() public {
+        vm.expectEmit(true, true, true, false, address(mailbox));
+        // sender address is the testSendReceiver which doesn't match sender
+        // in event (not in scope for test here - tested in Mailbox.t.sol)
+        emit Dispatch(
+            address(testSendReceiver),
+            TEST_DESTINATION_DOMAIN,
+            address(testSendReceiver).addressToBytes32(),
+            testMessage
+        );
+        testSendReceiver.dispatchToSelf{value: gasPayment}(
+            mailbox,
+            TEST_DESTINATION_DOMAIN,
+            TEST_MESSAGE_CONTENT
+        );
+    }
+
+    function testDispatchToSelf_withHook() public {
+        vm.expectEmit(true, true, true, false, address(mailbox));
+        // sender address is the testSendReceiver which doesn't match sender
+        // in event (not in scope for test here - tested in Mailbox.t.sol)
+        emit Dispatch(
+            address(testSendReceiver),
+            TEST_DESTINATION_DOMAIN,
+            address(testSendReceiver).addressToBytes32(),
+            testMessage
+        );
+        testSendReceiver.dispatchToSelf{value: gasPayment}(
+            mailbox,
+            TEST_DESTINATION_DOMAIN,
+            TEST_MESSAGE_CONTENT,
+            igp
+        );
+    }
+
+    event Handled(uint256 randao);
+
+    function testHandle(bytes32 randao) public {
+        vm.prevrandao(randao);
+        if (block.prevrandao % 16 == 0) {
+            vm.expectRevert("randao ends in 0");
+        } else {
+            vm.expectEmit(true, true, true, false, address(testSendReceiver));
+            emit Handled(block.prevrandao);
+        }
+        testSendReceiver.handle(
+            0,
+            address(testSendReceiver).addressToBytes32(),
+            "0x1234"
+        );
+    }
+}